web-dev-qa-db-ja.com

Robocopyを使用して、変更されたファイルのみをコピーしますか？

デプロイメント目的で変更されたファイルのみをWebサーバーにデプロイする簡単な方法を見つけようとしています。過去に、MSBuildを使用しました。MSBuildは、ターゲット上のファイルよりも新しいファイルのみをコピーするように指示できましたが、急いでいるため、MSBuildの新しいバージョンを把握しようとは思いません。

これにROBOCOPYを使用できますか？除外のオプションのリストは次のとおりです。

  • / XC ::変更されたファイルを除外します。
  • / XN ::新しいファイルを除外します。
  • / XO ::古いファイルを除外します。
  • / XX :: eXtraファイルとディレクトリを除外します。
  • / XL ::孤独なファイルとディレクトリを除外します。

除外するとはどういう意味ですか？コピーを除外するか、上書きを除外しますか？たとえば、私が書いた場合：

ROBOCOPY C：\ SourceFolder\ABC.dll D：\ DestinationFolder/XO

これは、同じ年齢のファイルではなく、新しいファイルのみをコピーしますか？

または、これを行うためのより良いツールはありますか？

asp.netmsbuildweb-deploymentrobocopy
22
Cyberherbalist

すべての質問に答えるには：

これにROBOCOPYを使用できますか？

はい、RCは要件に適合している必要があります（シンプル、必要なものだけをコピーしてください）

除外するとはどういう意味ですか？

コピーを除外します-RCはそれを呼び出しますスキップ

/XOオプションは、同じ年齢のファイルではなく、新しいファイルのみをコピーしますか？

はい、RCは新しいファイルのみをコピーします。同じ年齢のファイルはスキップされます。

（正しいコマンドはrobocopy C:\SourceFolder D:\DestinationFolder ABC.dll /XO）

たぶんあなたの場合は/MIRオプションが役立つ場合があります。一般に、RCは単一のファイルではなく、ディレクトリとディレクトリツリーを対象としています。

35
Filburt

Robocopyを使用して、アーカイブフラグ付きのファイルをコピーし、属性をリセットできます。/Mコマンドラインを使用します。これは、バックアップスクリプトであり、いくつかの余分なトリックがあります。

このスクリプトには NirCmd ツールが必要で、マウスを動かし続けてマシンがスリープ状態にならないようにします。スクリプトは、ロックスクリプトを使用して、バックアップスクリプトが完了し、mousemove.batスクリプトが閉じられたことを通知します。この部分は省略できます。

もう1つは 7-Zip 4GBファイルより小さいvirtualboxファイルを分割するためのツールです。宛先フォルダーはまだFAT32なので、これは必須です。 NTFSディスクを使用する必要がありますが、バックアップディスクはまだ変換していません。

backup-robocopy.bat

@REM https://technet.Microsoft.com/en-us/library/cc733145.aspx
@REM http://www.skonet.com/articles_archive/robocopy_job_template.aspx

set basedir=%~dp0
del /Q %basedir%backup-robocopy-log.txt

set dt=%date%_%time:~0,8%
echo "%dt% robocopy started" > %basedir%backup-robocopy-lock.txt
start "Keep system awake" /MIN /LOW  cmd.exe /C %basedir%backup-robocopy-movemouse.bat

set dest=E:\backup

call :BACKUP "Program Files\MariaDB 5.5\data"
call :BACKUP "projects"
call :BACKUP "Users\Myname"

:SPLIT
@REM Split +4GB file to multiple files to support FAT32 destination disk,
@REM splitted files must be stored outside of the robocopy destination folder.
set srcfile=C:\Users\Myname\VirtualBox VMs\Ubuntu\Ubuntu.vdi
set dstfile=%dest%\Users\Myname\VirtualBox VMs\Ubuntu\Ubuntu.vdi
set dstfile2=%dest%\non-robocopy\Users\Myname\VirtualBox VMs\Ubuntu\Ubuntu.vdi
IF NOT EXIST "%dstfile%" (
  IF NOT EXIST "%dstfile2%.7z.001" attrib +A "%srcfile%"
  dir /b /aa "%srcfile%" && (
    del /Q "%dstfile2%.7z.*"
    c:\apps\commands\7za.exe -mx0 -v4000m u "%dstfile2%.7z"  "%srcfile%"
    attrib -A "%srcfile%"
    @set dt=%date%_%time:~0,8%
    @echo %dt% Splitted %srcfile% >> %basedir%backup-robocopy-log.txt
  )
)

del /Q %basedir%backup-robocopy-lock.txt
GOTO :END


:BACKUP
TITLE Backup %~1
robocopy.exe "c:\%~1" "%dest%\%~1" /JOB:%basedir%backup-robocopy-job.rcj
GOTO :EOF


:END
@set dt=%date%_%time:~0,8%
@echo %dt% robocopy completed >> %basedir%backup-robocopy-log.txt
@echo %dt% robocopy completed
@pause

backup-robocopy-job.rcj

:: Robocopy Job Parameters
:: robocopy.exe "c:\projects" "E:\backup\projects" /JOB:backup-robocopy-job.rcj


:: Source Directory (this is given in command line)
::/SD:c:\examplefolder

:: Destination Directory (this is given in command line)
::/DD:E:\backup\examplefolder

:: Include files matching these names
/IF
    *.*

/M      :: copy only files with the Archive attribute and reset it.
/XJD    :: eXclude Junction points for Directories.

:: Exclude Directories
/XD
    C:\projects\bak
    C:\projects\old
    C:\project\Tomcat\logs
    C:\project\Tomcat\work
    C:\Users\Myname\.Eclipse
    C:\Users\Myname\.m2
    C:\Users\Myname\.thumbnails
    C:\Users\Myname\AppData
    C:\Users\Myname\Favorites
    C:\Users\Myname\Links
    C:\Users\Myname\Saved Games
    C:\Users\Myname\Searches

:: Exclude files matching these names
/XF 
    C:\Users\Myname\ntuser.dat  
    *.~bpl

:: Exclude files with any of the given Attributes set
:: S=System, H=Hidden
/XA:SH      

:: Copy options
/S          :: copy Subdirectories, but not empty ones.
/E          :: copy subdirectories, including Empty ones.
/COPY:DAT   :: what to COPY for files (default is /COPY:DAT).
/DCOPY:T    :: COPY Directory Timestamps.
/PURGE      :: delete dest files/dirs that no longer exist in source.

:: Retry Options
/R:0        :: number of Retries on failed copies: default 1 million.
/W:1        :: Wait time between retries: default is 30 seconds.

:: Logging Options (LOG+ append)
/NDL        :: No Directory List - don't log directory names.
/NP         :: No Progress - don't display percentage copied.
/TEE        :: output to console window, as well as the log file.
/LOG+:c:\apps\commands\backup-robocopy-log.txt :: append to logfile

backup-robocopy-movemouse.bat

@echo off
@REM Move mouse to prevent maching from sleeping 
@rem while running a backup script

echo Keep system awake while robocopy is running,
echo this script moves a mouse once in a while.

set basedir=%~dp0
set IDX=0

:LOOP
IF NOT EXIST "%basedir%backup-robocopy-lock.txt" GOTO :EOF
SET /A IDX=%IDX% + 1
IF "%IDX%"=="240" (
  SET IDX=0
  echo Move mouse to keep system awake
  c:\apps\commands\nircmdc.exe sendmouse move 5 5
  c:\apps\commands\nircmdc.exe sendmouse move -5 -5
)
c:\apps\commands\nircmdc.exe wait 1000
GOTO :LOOP
0
Whome