web-dev-qa-db-ja.com

環境変数をENDLOCALで存続させる

一連の中間変数を介して変数を計算するバッチファイルがあります。

@echo off
setlocal

set base=compute directory
set pkg=compute sub-directory
set scripts=%base%\%pkg%\Scripts

endlocal

%scripts%\activate.bat

最後の行のスクリプトは、scripts環境変数を破壊するendlocalの後にあるため呼び出されませんが、使用する他の環境変数の束を設定することが目的であるため、endlocalの後にある必要があります。ユーザーによる。

永続的な環境変数を設定することを目的としているが、一時的な環境変数によって場所が決定されるスクリプトを呼び出すにはどうすればよいですか？

Endlocalの前に一時バッチファイルを作成し、endlocalの後に呼び出すことができることはわかっています。これは、他に何も明らかにならない場合に実行しますが、クリンジに値しない解決策があるかどうかを知りたいです。

batch-fileenvironment-variables
26
Marcelo Cantos

ENDLOCAL & SET VAR=%TEMPVAR%パターンは古典的です。しかし、それが理想的ではない状況もあります。

TEMPVARの内容がわからない場合、値に<>&または|などの特殊文字が含まれていると、問題が発生する可能性があります。通常、SET "VAR=%TEMPVAR%"のような引用符を使用することでこれを防ぐことができますが、特殊文字があり、値がすでに引用符で囲まれている場合、問題が発生する可能性があります。

特殊文字が気になる場合は、FOR式がENDLOCALバリアを越えて値を転送するための優れた選択肢です。遅延拡張は、ENDLOCALの前に有効にし、ENDLOCALの後で無効にする必要があります。

setlocal enableDelayedExpansion
set "TEMPVAR=This & "that ^& the other thing"
for /f "delims=" %%A in (""!TEMPVAR!"") do endlocal & set "VAR=%%~A"

制限：

  • ENDLOCALの後で遅延拡張が有効になっている場合、TEMPVARに!が含まれていると、最終値が破損します。

  • lineFeed文字を含む値は転送できません

複数の値を返す必要があり、どちらの値にも表示できない文字がわかっている場合は、適切なFOR/Fオプションを使用するだけです。たとえば、値に|を含めることができないことがわかっている場合：

setlocal enableDelayedExpansion
set "temp1=val1"
set "temp2=val2"
for /f "tokens=1,2 delims=|" %%A in (""!temp1!"|"!temp2!"") do (
   endLocal
   set "var1=%%~A"
   set "var2=%%~B"
)

複数の値を返す必要があり、文字セットに制限がない場合は、ネストされたFOR/Fループを使用します。

setlocal enableDelayedExpansion
set "temp1=val1"
set "temp2=val2"
for /f "delims=" %%A in (""!temp1!"") do (
  for /f "delims=" %%B in (""!temp2!"") do (
    endlocal
    set "var1=%%~A"
    set "var2=%%~B"
  )
)

間違いなくチェックしてください jebの答え すべての状況ですべての可能な値に対して機能する安全で防弾のテクニックを確認してください。

2017-08-21-新しい関数RETURN.BAT
DosTipsユーザーjebと協力して開発しました RETURN.BATと呼ばれるバッチユーティリティ スクリプトを終了するか、ルーチンを呼び出して、ENDLOCAL全体で1つ以上の変数を返すために使用できますバリア。とてもかっこいい ：-）

以下はバージョン3.0のコードです。私はおそらくこのコードを最新の状態に保つことはないでしょう。リンクをたどって最新バージョンを入手し、使用例を確認することをお勧めします。

RETURN.BAT

::RETURN.BAT Version 3.0
@if "%~2" equ "" (goto :return.special) else goto :return
:::
:::call RETURN  ValueVar  ReturnVar  [ErrorCode]
:::  Used by batch functions to EXIT /B and safely return any value across the
:::  ENDLOCAL barrier.
:::    ValueVar  = The name of the local variable containing the return value.
:::    ReturnVar = The name of the variable to receive the return value.
:::    ErrorCode = The returned ERRORLEVEL, defaults to 0 if not specified.
:::
:::call RETURN "ValueVar1 ValueVar2 ..." "ReturnVar1 ReturnVar2 ..." [ErrorCode]
:::  Same as before, except the first and second arugments are quoted and space
:::  delimited lists of variable names.
:::
:::  Note that the total length of all assignments (variable names and values)
:::  must be less then 3.8k bytes. No checks are performed to verify that all
:::  assignments fit within the limit. Variable names must not contain space,
:::  tab, comma, semicolon, caret, asterisk, question mark, or exclamation point.
:::
:::call RETURN  init
:::  Defines return.LF and return.CR variables. Not required, but should be
:::  called once at the top of your script to improve performance of RETURN.
:::
:::return /?
:::  Displays this help
:::
:::return /V
:::  Displays the version of RETURN.BAT
:::
:::
:::RETURN.BAT was written by Dave Benham and DosTips user jeb, and was originally
:::posted within the folloing DosTips thread:
:::  http://www.dostips.com/forum/viewtopic.php?f=3&t=6496
:::
::==============================================================================
::  If the code below is copied within a script, then the :return.special code
::  can be removed, and your script can use the following calls:
::
::    call :return   ValueVar  ReturnVar  [ErrorCode]
::
::    call :return.init
::

:return  ValueVar  ReturnVar  [ErrorCode]
:: Safely returns any value(s) across the ENDLOCAL barrier. Default ErrorCode is 0
setlocal enableDelayedExpansion
if not defined return.LF call :return.init
if not defined return.CR call :return.init
set "return.normalCmd="
set "return.delayedCmd="
set "return.vars=%~2"
for %%a in (%~1) do for /f "tokens=1*" %%b in ("!return.vars!") do (
  set "return.normal=!%%a!"
  if defined return.normal (
    set "return.normal=!return.normal:%%=%%3!"
    set "return.normal=!return.normal:"=%%4!"
    for %%C in ("!return.LF!") do set "return.normal=!return.normal:%%~C=%%~1!"
    for %%C in ("!return.CR!") do set "return.normal=!return.normal:%%~C=%%2!"
    set "return.delayed=!return.normal:^=^^^^!"
  ) else set "return.delayed="
  if defined return.delayed call :return.setDelayed
  set "return.normalCmd=!return.normalCmd!&set "%%b=!return.normal!"^!"
  set "return.delayedCmd=!return.delayedCmd!&set "%%b=!return.delayed!"^!"
  set "return.vars=%%c"
)
set "err=%~3"
if not defined err set "err=0"
for %%1 in ("!return.LF!") do for /f "tokens=1-3" %%2 in (^"!return.CR! %% "") do (
  (goto) 2>nul
  (goto) 2>nul
  if "^!^" equ "^!" (%return.delayedCmd:~1%) else %return.normalCmd:~1%
  if %err% equ 0 (call ) else if %err% equ 1 (call) else cmd /c exit %err%
)

:return.setDelayed
set "return.delayed=%return.delayed:!=^^^!%" !
exit /b

:return.special
@if /i "%~1" equ "init" goto return.init
@if "%~1" equ "/?" (
  for /f "tokens=* delims=:" %%A in ('findstr "^:::" "%~f0"') do @echo(%%A
  exit /b 0
)
@if /i "%~1" equ "/V" (
  for /f "tokens=* delims=:" %%A in ('findstr /rc:"^::RETURN.BAT Version" "%~f0"') do @echo %%A
  exit /b 0
)
@>&2 echo ERROR: Invalid call to RETURN.BAT
@exit /b 1


:return.init  -  Initializes the return.LF and return.CR variables
set ^"return.LF=^

^" The empty line above is critical - DO NOT REMOVE
for /f %%C in ('copy /z "%~f0" nul') do set "return.CR=%%C"
exit /b 0
23
dbenham
@ECHO OFF  
SETLOCAL  

REM Keep in mind that BAR in the next statement could be anything, including %1, etc.  
SET FOO=BAR  

ENDLOCAL && SET FOO=%FOO%
13
mistachkin

Dbenhamの answer は、 "normal"文字列の良い解決策ですが、遅延拡張が有効になっていると、感嘆符!で失敗します。 ENDLOCAL（dbenhamもこれを言った）。

ただし、埋め込み改行などのトリッキーなコンテンツでは常に失敗します。
FOR/Fはコンテンツを複数の行に分割するため。
これは奇妙な振る舞いになり、endlocalは（改行ごとに）複数回実行されるため、コードは防弾ではありません。

防弾ソリューションは存在しますが、少し面倒です:-)
マクロバージョンが存在します SO：感嘆符を保存しています... 、使用するのは簡単ですが、読んでください...

または、コードブロックを使用して、関数に貼り付けることもできます。
Dbenhamと私はこのテクニックをスレッドで開発しました Re：新しい関数:: chr、：asc、：asciiMap 、
このテクニックの説明もあります

@echo off
setlocal EnableDelayedExpansion
cls
for /f %%a in ('copy /Z "%~dpf0" nul') do set "CR=%%a"
set LF=^


rem TWO Empty lines are neccessary
set "original=zero*? %%~A%%~B%%~C%%~L!LF!one&line!LF!two with exclam^! !LF!three with "quotes^&"&"!LF!four with ^^^^ ^| ^< ^> ( ) ^& ^^^! ^"!LF!xxxxxwith CR!CR!five !LF!six with ^"^"Q ^"^"L still six "

setlocal DisableDelayedExpansion
call :lfTest result original

setlocal EnableDelayedExpansion
echo The result with disabled delayed expansion is:
if !original! == !result! (echo OK) ELSE echo !result!

call :lfTest result original
echo The result with enabled delayed expansion is:
if !original! == !result! (echo OK) ELSE echo !result!
echo ------------------
echo !original!

goto :eof

::::::::::::::::::::
:lfTest
setlocal
set "NotDelayedFlag=!"
echo(
if defined NotDelayedFlag (echo lfTest was called with Delayed Expansion DISABLED) else echo lfTest was called with Delayed Expansion ENABLED
setlocal EnableDelayedExpansion
set "var=!%~2!"

rem echo the input is:
rem echo !var!
echo(

rem ** Prepare for return
set "var=!var:%%=%%~1!"
set "var=!var:"=%%~2!"
for %%a in ("!LF!") do set "var=!var:%%~a=%%~L!"
for %%a in ("!CR!") do set "var=!var:%%~a=%%~3!"

rem ** It is neccessary to use two IF's else the %var% expansion doesn't work as expected
if not defined NotDelayedFlag set "var=!var:^=^^^^!"
if not defined NotDelayedFlag set "var=%var:!=^^^!%" !

set "replace=%% """ !CR!!CR!"
for %%L in ("!LF!") do (
   for /F "tokens=1,2,3" %%1 in ("!replace!") DO (
     ENDLOCAL
     ENDLOCAL
     set "%~1=%var%" !
     @echo off
      goto :eof
   )
)
exit /b
8
jeb

私もこれに貢献し、配列のような変数のセットを渡す方法を説明したいと思います。

@echo off
rem clean up array in current environment:
set "ARRAY[0]=" & set "ARRAY[1]=" & set "ARRAY[2]=" & set "ARRAY[3]="
rem begin environment localisation block here:
setlocal EnableExtensions
rem define an array:
set "ARRAY[0]=1" & set "ARRAY[1]=2" & set "ARRAY[2]=4" & set "ARRAY[3]=8"
rem `set ARRAY` returns all variables starting with `ARRAY`:
for /F "tokens=1,* delims==" %%V in ('set ARRAY') do (
    if defined %%V (
        rem end environment localisation block once only:
        endlocal
    )
    rem re-assign the array, `for` variables transport it:
    set "%%V=%%W"
)
rem this is just for prove:
for /L %%I in (0,1,3) do (
    call echo %%ARRAY[%%I]%%
)
exit /B

最初の配列要素は、実際に定義されているsetlocalブロック内のif definedによってクエリされるため、コードは機能します。したがって、endlocalは1回だけ実行されます。連続するすべてのループ反復で、setlocalブロックはすでに終了しているため、if definedは[〜＃〜] false [〜＃〜]と評価されます。

これは、少なくとも1つの配列要素が割り当てられているという事実、または実際には、ARRAY/setlocalブロック内に名前がendlocalで始まる変数が少なくとも1つ定義されているという事実に依存しています。そこに何も存在しない場合、endlocalは実行されません。 setlocalブロックの外側では、そのような変数を定義する必要はありません。定義しないと、if definedは[〜＃〜] true [〜＃〜]と評価され、複数回実行されるため、endlocalが実行されます。複数回。

この制限を克服するために、次のようにフラグのような変数を使用できます。

  • setlocalコマンドの前に、フラグ変数、たとえばARR_FLAGをクリアします。set "ARR_FLAG=";
  • setlocal/endlocalブロック内でフラグ変数を定義します。つまり、空でない値を割り当てます（for /Fループの直前が望ましい）：set "ARR_FLAG=###";
  • if definedコマンドラインを次のように変更します。if defined ARR_FLAG (;
  • 次に、オプションで次のことを行うこともできます：
    • for /Fオプション文字列を"delims="に変更します。
    • for /Fループのsetコマンドラインを次のように変更します。set "%%V";
2
aschipfl

複数の変数を生き残るために：「クラシック」を選択した場合
ENDLOCAL & SET VAR=%TEMPVAR%ここの他の回答で時々言及されています（そして、いくつかの回答に示されている欠点が解決されているか、問題ではないことに満足しています）、複数の変数を実行できることに注意してください、la ENDLOCAL & SET var1=%local1% & SET var2=%local2%。

以下のリンク先のサイト以外では、単一の変数で示されている「トリック」しか見たことがなく、私のように、単一の変数に対してのみ「機能する」と誤って想定している人もいるため、これを共有します。

ドキュメント： https://ss64.com/nt/endlocal.html

1
MicrosoftShouldBeKickedInNuts

次のようなもの（私はそれをテストしていません）：

@echo off 
setlocal 

set base=compute directory 
set pkg=compute sub-directory 
set scripts=%base%\%pkg%\Scripts 

pushd %scripts%

endlocal 

call .\activate.bat 
popd

上記は機能しないので（Marceloのコメントを参照）、おそらく次のようにします。

set uniquePrefix_base=compute directory 
set uniquePrefix_pkg=compute sub-directory 
set uniquePrefix_scripts=%uniquePrefix_base%\%uniquePrefix_pkg%\Scripts 
set uniquePrefix_base=
set uniquePrefix_pkg=

call %uniquePrefix_scripts%\activate.bat
set uniquePrefix_scripts=

ここで、uniquePrefix_は、環境内で「ほぼ確実に」一意になるように選択されています。

Batファイルへのエントリで、「uniquePrefix _...」環境変数が期待どおりにエントリで未定義であることをテストすることもできます。そうでない場合は、エラーで終了できます。

一般的な解決策としてBATをTEMPディレクトリにコピーするのは好きではありません。これは、（a）呼び出し元が1を超える競合状態が発生する可能性があり、（b）一般的な場合、BATファイルがその場所に相対的なパス（例：％〜dp0 ..\somedir\somefile.dat）。

次の醜い解決策は（b）を解決します：

setlocal

set scripts=...whatever...
echo %scripts%>"%TEMP%\%~n0.dat"

endlocal

for /f "tokens=*" %%i in ('type "%TEMP%\%~n0.dat"') do call %%i\activate.bat
del "%TEMP%\%~n0.dat"
1
Joe

私自身の質問に答えるために（他の答えが明らかにならない場合、そして私がすでに知っているものの繰り返しを避けるために）...

endlocalを呼び出す前に、ターゲットバッチファイルを呼び出すコマンドを含む一時バッチファイルを作成し、endlocalの後に呼び出して削除します。

echo %scripts%\activate.bat > %TEMP%\activate.bat

endlocal

call %TEMP%\activate.bat
del %TEMP%\activate.bat

これはとても醜いので、恥ずかしそうに頭を下げたいです。より良い答えは大歓迎です。

0
Marcelo Cantos