web-dev-qa-db-ja.com

CMDファイルの最後の10行を表示するCMD.EXEバッチスクリプト

Txtファイルの最後の10行をエコーまたは入力する方法はありますか?

変更を追跡できるように、管理者に何をしているのかを示すためにサーバー変更ログスクリプトを実行しています。私は、スクリプトに最近の10エントリ程度を表示して、最近何が起こっているのかを理解しようとしています。以下に示すように、最後の行を処理するスクリプトを見つけましたが、最後の10行を表示するために何を変更するかわかりません。脚本:

@echo off
setLocal EnableDelayedExpansion
for /f "tokens=* delims= " %%a in (c:\log09.txt) do (
set var=%%a
)
echo !var!

ログファイルの例:

06/02/2009, 12:22,Remote=Workstation-9,Local=,
mdb,bouncing box after updates,CAS-08754,
=================
07/02/2009, 2:38,Remote=,Local=SERVER1,
mdb,just finished ghosting c drive,CAS-08776,
=================
07/02/2009, 3:09,Remote=,Local=SERVER1,
mdb,audit of server,CAS-08776,

何かご意見は?スクリプトはうまく機能します。画面にパイプを追加する必要があるだけです。

17
Matt Ball

うまくいけば、これはジョエルの目を救うでしょう:)

@echo OFF

:: Get the number of lines in the file
set LINES=0
for /f "delims==" %%I in (data.txt) do (
    set /a LINES=LINES+1
)

:: Print the last 10 lines (suggestion to use more courtsey of dmityugov)
set /a LINES=LINES-10
more +%LINES% < data.txt
18
Patrick Cuff

この回答は、既存の回答の最良の機能を組み合わせ、いくつかの工夫を加えています。

解決策は、tailコマンドの単純なバッチ実装です。

最初の引数はファイル名です(パス情報が含まれる可能性があります-パスの一部にスペースやその他の問題のある文字が含まれている場合は、必ず引用符で囲んでください)。

2番目の引数は、印刷する行数です。

最後に、標準のMOREオプションのいずれかを追加できます:/ E/C/P/S/Tn。 (詳細については、MORE /?を参照してください)。

さらに、/ N(一時停止なし)オプションを指定して、出力を一時停止せずに継続的に印刷できます。

このソリューションでは、最初にFINDを使用して行数をすばやくカウントします。ファイルは、FIND出力でのファイル名の印刷を排除するために、ファイル名引数を使用する代わりにリダイレクトされた入力を介して渡されます。

スキップする行数はSET/Aで計算されますが、0未満の場合は0にリセットされます。

最後に、MOREを使用して、不要な行をスキップした後、目的の行を印刷します。 MOREは、出力がファイルにリダイレクトされるか、別のコマンドにパイプされない限り、各画面に相当する行の後で一時停止します。/Nオプションは、すべての行に一致する正規表現を使用して、MORE出力をFINDSTRにパイプすることにより、一時停止を回避します。 FINDは長い行を切り捨てるため、FINDではなくFINDSTRを使用することが重要です。

:: tail.bat File Num [/N|/E|/C|/P|/S|/Tn]...
::
::   Prints the last Num lines of text file File.
::
::   The output will pause after filling the screen unless the /N option
::   is specified
::
::   The standard MORE options /E /C /P /S /Tn can be specified.
::   See MORE /? for more information
::
@echo OFF
setlocal
set file=%1
set "cnt=%~2"
shift /1
shift /1
set "options="
set "noPause="
:parseOptions
if "%~1" neq "" (
  if /i "%~1" equ "/N" (set noPause=^| findstr "^") else set options=%options% %~1
  shift /1
  goto :parseOptions
)
for /f %%N in ('find /c /v "" ^<%file%') do set skip=%%N
set /a "skip-=%cnt%"
if %skip% lss 0 set skip=0
more +%skip% %options% %file% %noPause%
12
dbenham

おそらく、tailの適切な実装を見つける必要があります。しかし、CMDバッチファイルの使用を本当に強く主張し、妨害されていないNTマシンで実行したい場合、これは機能します。

@echo off
setLocal EnableDelayedExpansion
for /f "tokens=* delims= " %%a in (c:\tmp\foo.txt) do (
set var9=!var8!
set var8=!var7!
set var7=!var6!
set var6=!var5!
set var5=!var4!
set var4=!var3!
set var3=!var2!
set var2=!var1!
set var1=!var!
set var=%%a
)
echo !var9!
echo !var8!
echo !var7!
echo !var6!
echo !var5!
echo !var4!
echo !var3!
echo !var2!
echo !var1!
echo !var!
10
Joel Spolsky

このページで見つけたすべての回答を試した後、15539行のファイルで作業した回答はありませんでした。

しかし、私は答え here がうまく機能することを発見しました。便宜上、この投稿にコピーしました。

@echo off
for /f %%i in ('find /v /c "" ^< C:\path\to\textfile.txt') do set /a lines=%%i
set /a startLine=%lines% - 10
more /e +%startLine% C:\path\to\textfile.txt

このコードは、「C:\ path\to\textfile.txt」ファイルの最後の10行を印刷します。

クレジットはOP @Peter Mortensenに送られます

4
Randy Rakestraw

Tailコマンドのいくつかのウィンドウ実装があります。それはまさにあなたが望むものでなければなりません。

これは特に良いようです: http://malektips.com/xp_dos_0001.html

リアルタイム監視からファイルの最後のx行までの範囲です。

編集:含まれているリンクがパッケージへのリンクであることに気付きましたが、動作するはずですが、さらにいくつかのバージョンがあります:

http://www.lostinthebox.com/viewtopic.php?f=5&t=3801http://sourceforge.net/projects/tailforwin32

4
Phil

ファイルが大きすぎる場合、行数を取得するのに時間がかかりすぎる可能性があります。別の方法として、findを使用してnowhere文字列を渡します。

$find /v /c "%%$%!" yourtextfile.txt

これはこのような出力になります

$---------- yourtextfile.txt: 140

次に、このように使用して出力を解析できます

$for /f "tokens=3" %i in ('find /v /c "%%$%!" tt.txt') do set countoflines=%i

次に、合計行から10行を引くことができます

4
Hassan

単一のPowerShellコマンドを使用:

powershell -nologo "& "Get-Content -Path c:\logFile.log -Tail 10"

powershell 3.0以降に適用されます

3
Eyal

「TAILを使うべきだ」という回答に同意します。ただし、Windowsではデフォルトでは提供されません。 " Windows 2003 Resource Kit "は、XP/W2003以降で動作します。

サーバーにインストールしたくない場合は、リソースキットを別のマシンにインストールして、TAIL.EXEのみをサーバーにコピーできます。使い方はとても簡単です。

C:\> TAIL -10 myfile.txt
1
PollusB

ここ '指定された範囲内のファイルの行を表示できる純粋なバッチで記述されたユーティリティです。最後の行を表示するには使用(ここでは、スクリプトの名前はtailhead.batです):

call tailhead.bat -file "file.txt" -begin -10
1
npocmaka

Txtファイルの最後の10行をエコーまたは入力する方法はありますか?

次の3行のスクリプトは、入力ファイルの最後のn行をリストします。 nおよびファイル名/パスが入力引数として渡されます。

# Script last.txt
var str file, content ; var int n, count
cat $file > $content ; set count = { len -e $content } - $n
stex -e ("["+makestr(int($count))) $content

スクリプトはバイタスクリプトです。使用するには、ビットスクリプトを http://www.biterscripting.com からダウンロードし、このスクリプトをC:\ Scripts\last.txtとして保存し、ビットスクリプトを開始して、次のコマンドを入力します。

script last.txt file("c:\log09.txt") n(10)

上記は、ファイルc:\ log09.txtの最後の10行をリストします。同じファイルの最後の20行をリストするには、次のコマンドを使用します。

script last.txt file("c:\log09.txt") n(20)

別のファイルC:\ folder1\somefile.logから最後の30行をリストするには、次のコマンドを使用します。

script last.txt file("C:\folder1\somefile.log") n(30)

スクリプトはかなり一般的な方法で記述したため、さまざまな方法で使用できます。別のスクリプト/バッチ言語に自由に翻訳してください。

0
P M