C ++メンバー関数からObjective-Cメソッドを呼び出していますか？
_C++_クラスのメンバー関数を問題なく呼び出すクラス（EAGLView）があります。今、問題は、その_C++_クラスで_objective-C_ function[context renderbufferStorage:GL_RENDERBUFFER fromDrawable:(CAEAGLLayer*)self.layer];を呼び出す必要があることです。これは_C++_構文では実行できません。
私はこの_Objective-C_呼び出しを最初の場所でC++クラスを呼び出した同じ_Objective-C_クラスにラップすることができましたが、その後、何らかの方法でそのメソッドを_C++_から呼び出す必要があり、わかりませんどうやるか。
EAGLViewオブジェクトへのポインターをC++メンバー関数に渡して、_EAGLView.h_クラスヘッダーに "_C++_"を含めようとしましたが、3999エラーが発生しました。
だから..これはどうすればいいですか？例は、ニースです。これを行う純粋なCの例を見つけました。
C++とObjective-Cを慎重に組み合わせて使用できます。いくつかの警告がありますが、一般的に言えば、それらは混在する可能性があります。それらを別々にしたい場合は、Objective-Cオブジェクトに非Objective-Cコードから使用可能なCスタイルのインターフェイスを与える標準のCラッパー関数を設定できます（ファイルのより良い名前を選択し、これらの名前を選択しました冗長性のため）：
MyObject-C-Interface.h
#ifndef __MYOBJECT_C_INTERFACE_H__
#define __MYOBJECT_C_INTERFACE_H__
// This is the C "trampoline" function that will be used
// to invoke a specific Objective-C method FROM C++
int MyObjectDoSomethingWith (void *myObjectInstance, void *parameter);
#endif
MyObject.h
#import "MyObject-C-Interface.h"
// An Objective-C class that needs to be accessed from C++
@interface MyObject : NSObject
{
int someVar;
}
// The Objective-C member function you want to call from C++
- (int) doSomethingWith:(void *) aParameter;
@end
MyObject.mm
#import "MyObject.h"
@implementation MyObject
// C "trampoline" function to invoke Objective-C method
int MyObjectDoSomethingWith (void *self, void *aParameter)
{
// Call the Objective-C method using Objective-C syntax
return [(id) self doSomethingWith:aParameter];
}
- (int) doSomethingWith:(void *) aParameter
{
// The Objective-C function you wanted to call from C++.
// do work here..
return 21 ; // half of 42
}
@end
MyCPPClass.cpp
#include "MyCPPClass.h"
#include "MyObject-C-Interface.h"
int MyCPPClass::someMethod (void *objectiveCObject, void *aParameter)
{
// To invoke an Objective-C method from C++, use
// the C trampoline function
return MyObjectDoSomethingWith (objectiveCObject, aParameter);
}
ラッパー関数は、目的と同じ.mファイルにある必要はありません -Cクラスですが、に存在するファイルは、Objective-Cコードとしてコンパイルする必要があります。ラッパー関数を宣言するヘッダーは、CPPコードとObjective-Cコードの両方に含める必要があります。
（注：Objective-C実装ファイルに拡張子「.m」が与えられている場合、Xcodeでリンクされません。「。mm」拡張子は、Objective-CとC++の組み合わせ（Objective-C++）を期待するようXcodeに指示します。 ）
PIMPLイディオム を使用して、オブジェクト指向の方法で上記を実装できます。実装はわずかに異なります。つまり、ラッパークラス（ "MyObject-C-Interface.h"で宣言）を、MyClassのインスタンスへの（プライベート）voidポインターを持つクラス内に配置します。
MyObject-C-Interface.h（PIMPL）
#ifndef __MYOBJECT_C_INTERFACE_H__
#define __MYOBJECT_C_INTERFACE_H__
class MyClassImpl
{
public:
MyClassImpl ( void );
~MyClassImpl( void );
void init( void );
int doSomethingWith( void * aParameter );
void logMyMessage( char * aCStr );
private:
void * self;
};
#endif
ラッパーメソッドは、MyClassのインスタンスへのvoidポインターをもはや必要としないことに注意してください。現在、MyClassImplのプライベートメンバーです。 initメソッドは、MyClassインスタンスをインスタンス化するために使用されます。
MyObject.h（PIMPL）
#import "MyObject-C-Interface.h"
@interface MyObject : NSObject
{
int someVar;
}
- (int) doSomethingWith:(void *) aParameter;
- (void) logMyMessage:(char *) aCStr;
@end
MyObject.mm（PIMPL）
#import "MyObject.h"
@implementation MyObject
MyClassImpl::MyClassImpl( void )
: self( NULL )
{ }
MyClassImpl::~MyClassImpl( void )
{
[(id)self dealloc];
}
void MyClassImpl::init( void )
{
self = [[MyObject alloc] init];
}
int MyClassImpl::doSomethingWith( void *aParameter )
{
return [(id)self doSomethingWith:aParameter];
}
void MyClassImpl::logMyMessage( char *aCStr )
{
[(id)self doLogMessage:aCStr];
}
- (int) doSomethingWith:(void *) aParameter
{
int result;
// ... some code to calculate the result
return result;
}
- (void) logMyMessage:(char *) aCStr
{
NSLog( aCStr );
}
@end
MyClassは、MyClassImpl :: initの呼び出しでインスタンス化されることに注意してください。 MyClassImplのコンストラクターでMyClassをインスタンス化することもできますが、それは一般に良い考えではありません。 MyClassインスタンスは、MyClassImplのデストラクタから破壊されます。 Cスタイルの実装と同様に、ラッパーメソッドは単にMyClassのそれぞれのメソッドに従います。
MyCPPClass.h（PIMPL）
#ifndef __MYCPP_CLASS_H__
#define __MYCPP_CLASS_H__
class MyClassImpl;
class MyCPPClass
{
enum { cANSWER_TO_LIFE_THE_UNIVERSE_AND_EVERYTHING = 42 };
public:
MyCPPClass ( void );
~MyCPPClass( void );
void init( void );
void doSomethingWithMyClass( void );
private:
MyClassImpl * _impl;
int _myValue;
};
#endif
MyCPPClass.cpp（PIMPL）
#include "MyCPPClass.h"
#include "MyObject-C-Interface.h"
MyCPPClass::MyCPPClass( void )
: _impl ( NULL )
{ }
void MyCPPClass::init( void )
{
_impl = new MyClassImpl();
}
MyCPPClass::~MyCPPClass( void )
{
if ( _impl ) { delete _impl; _impl = NULL; }
}
void MyCPPClass::doSomethingWithMyClass( void )
{
int result = _impl->doSomethingWith( _myValue );
if ( result == cANSWER_TO_LIFE_THE_UNIVERSE_AND_EVERYTHING )
{
_impl->logMyMessage( "Hello, Arthur!" );
}
else
{
_impl->logMyMessage( "Don't worry." );
}
}
これで、MyClassImplのプライベート実装を介してMyClassの呼び出しにアクセスできます。このアプローチは、ポータブルアプリケーションを開発している場合に有利です。 MyClassの実装を他のプラットフォーム固有の実装と単純に入れ替えることができますが、正直なところ、これがより良い実装であるかどうかは好みとニーズの問題です。
コードをObjective-C++としてコンパイルできます。最も簡単な方法は、.cppを.mmに名前変更することです。 EAGLView.h（C++コンパイラがObjective-C固有のキーワードを理解していなかったため、非常に多くのエラーが発生していました）を含めると、適切にコンパイルされ、Objective- CとC++を好きなように。
最も簡単な解決策は、XcodeにすべてをObjective C++としてコンパイルするよう指示することです。
Objective C++のソースをコンパイルするためのプロジェクトまたはターゲット設定を設定し、再コンパイルします。
次に、どこでもC++またはObjective Cを使用できます。次に例を示します。
void CPPObject::Function( ObjectiveCObject* context, NSView* view )
{
[context renderbufferStorage:GL_RENDERBUFFER fromDrawable:(CAEAGLLayer*)view.layer]
}
これは、すべてのソースファイルの名前を.cppまたは.mから.mmに変更するのと同じ効果があります。
これには2つの小さな欠点があります。clangはC++ソースコードを分析できません。一部の比較的奇妙なCコードはC++でコンパイルされません。
ステップ1
Objective Cファイル（.mファイル）とそれに対応するヘッダーファイルを作成します。
//ヘッダーファイル（「ObjCFunc.h」と呼びます）
#ifndef test2_ObjCFunc_h
#define test2_ObjCFunc_h
@interface myClass :NSObject
-(void)hello:(int)num1;
@end
#endif
//対応するObjective Cファイル（「ObjCFunc.m」と呼びます）
#import <Foundation/Foundation.h>
#include "ObjCFunc.h"
@implementation myClass
//Your Objective C code here....
-(void)hello:(int)num1
{
NSLog(@"Hello!!!!!!");
}
@end
ステップ2
次に、作成したばかりのObjective C関数を呼び出すc ++関数を実装します。そのため、.mmファイルを定義し、それに対応するヘッダーファイル（「.mm」ファイルを使用します。これは、ファイル内でObjective CとC++の両方のコーディングを使用できるためです）
//ヘッダーファイル（「ObjCCall.h」と呼びます）
#ifndef __test2__ObjCCall__
#define __test2__ObjCCall__
#include <stdio.h>
class ObjCCall
{
public:
static void objectiveC_Call(); //We define a static method to call the function directly using the class_name
};
#endif /* defined(__test2__ObjCCall__) */
//対応するObjective C++ファイル（「ObjCCall.mm」と呼びます）
#include "ObjCCall.h"
#include "ObjCFunc.h"
void ObjCCall::objectiveC_Call()
{
//Objective C code calling.....
myClass *obj=[[myClass alloc]init]; //Allocating the new object for the Objective C class we created
[obj hello:(100)]; //Calling the function we defined
}
ステップ
C++関数の呼び出し（実際にObjective Cメソッドを呼び出します）
#ifndef __HELLOWORLD_SCENE_H__
#define __HELLOWORLD_SCENE_H__
#include "cocos2d.h"
#include "ObjCCall.h"
class HelloWorld : public cocos2d::Layer
{
public:
// there's no 'id' in cpp, so we recommend returning the class instance pointer
static cocos2d::Scene* createScene();
// Here's a difference. Method 'init' in cocos2d-x returns bool, instead of returning 'id' in cocos2d-iphone
virtual bool init();
// a selector callback
void menuCloseCallback(cocos2d::Ref* pSender);
void ObCCall(); //definition
// implement the "static create()" method manually
CREATE_FUNC(HelloWorld);
};
#endif // __HELLOWORLD_SCENE_H__
//最終的なコール
#include "HelloWorldScene.h"
#include "ObjCCall.h"
USING_NS_CC;
Scene* HelloWorld::createScene()
{
// 'scene' is an autorelease object
auto scene = Scene::create();
// 'layer' is an autorelease object
auto layer = HelloWorld::create();
// add layer as a child to scene
scene->addChild(layer);
// return the scene
return scene;
}
// on "init" you need to initialize your instance
bool HelloWorld::init()
{
//////////////////////////////
// 1. super init first
if ( !Layer::init() )
{
return false;
}
Size visibleSize = Director::getInstance()->getVisibleSize();
Vec2 Origin = Director::getInstance()->getVisibleOrigin();
/////////////////////////////
// 2. add a menu item with "X" image, which is clicked to quit the program
// you may modify it.
// add a "close" icon to exit the progress. it's an autorelease object
auto closeItem = MenuItemImage::create(
"CloseNormal.png",
"CloseSelected.png",
CC_CALLBACK_1(HelloWorld::menuCloseCallback, this));
closeItem->setPosition(Vec2(Origin.x + visibleSize.width - closeItem->getContentSize().width/2 ,
Origin.y + closeItem->getContentSize().height/2));
// create menu, it's an autorelease object
auto menu = Menu::create(closeItem, NULL);
menu->setPosition(Vec2::ZERO);
this->addChild(menu, 1);
/////////////////////////////
// 3. add your codes below...
// add a label shows "Hello World"
// create and initialize a label
auto label = Label::createWithTTF("Hello World", "fonts/Marker Felt.ttf", 24);
// position the label on the center of the screen
label->setPosition(Vec2(Origin.x + visibleSize.width/2,
Origin.y + visibleSize.height - label- >getContentSize().height));
// add the label as a child to this layer
this->addChild(label, 1);
// add "HelloWorld" splash screen"
auto Sprite = Sprite::create("HelloWorld.png");
// position the Sprite on the center of the screen
Sprite->setPosition(Vec2(visibleSize.width/2 + Origin.x, visibleSize.height/2 + Origin.y));
// add the Sprite as a child to this layer
this->addChild(Sprite, 0);
this->ObCCall(); //first call
return true;
}
void HelloWorld::ObCCall() //Definition
{
ObjCCall::objectiveC_Call(); //Final Call
}
void HelloWorld::menuCloseCallback(Ref* pSender)
{
#if (CC_TARGET_PLATFORM == CC_PLATFORM_WP8) || (CC_TARGET_PLATFORM == CC_PLATFORM_WINRT)
MessageBox("You pressed the close button. Windows Store Apps do not implement a close button.","Alert");
return;
#endif
Director::getInstance()->end();
#if (CC_TARGET_PLATFORM == CC_PLATFORM_IOS)
exit(0);
#endif
}
これがうまくいくことを願っています！
C++ファイルをObjective-C++として扱う必要があります。 foo.cppの名前をfoo.mmに変更することにより、Xcodeでこれを行うことができます（.mmはobj-c ++拡張機能です）。その後、他の人が言ったように、標準のobj-cメッセージング構文が機能するでしょう。
また、Objective-Cランタイムを呼び出してメソッドを呼び出すことができます。
特にプロジェクトがクロスプラットフォームの場合、.cppの名前を.mmに変更することはお勧めできません。この場合、xcodeプロジェクトの場合、TextEditを介してxcodeプロジェクトファイルを開き、ファイルに含まれる文字列を見つけました。
/* OnlineManager.cpp */ = {isa = PBXFileReference; fileEncoding = 4; lastKnownFileType = sourcecode.cpp.cpp; path = OnlineManager.cpp; sourceTree = "<group>"; };
そして、ファイルタイプをsourcecode.cpp.cppからsourcecode.cpp.objcppに変更します
/* OnlineManager.cpp */ = {isa = PBXFileReference; fileEncoding = 4; lastKnownFileType = **sourcecode.cpp.objcpp**; path = OnlineManager.cpp; sourceTree = "<group>"; };
.cppの名前を.mmに変更するのと同じです。
上記の@DawidDrozdの答えは素晴らしいです。
1点追加します。 Clangコンパイラの最近のバージョンは、自分のコードを使用しようとする場合、「ブリッジキャスト」が必要であることを訴えます。
これは合理的なようです：トランポリンを使用すると潜在的なバグが発生します：Objective-Cクラスは参照カウントされるため、アドレスをvoid *として渡すと、コールバックがまだある間にクラスがガベージコレクトされた場合にハングするポインタを持つリスクがありますアクティブ。
解決策1）Cocoaは、おそらくObjective-Cオブジェクトの参照カウントに1を加算および減算するCFBridgingRetainおよびCFBridgingReleaseマクロ関数を提供します。したがって、保持するのと同じ回数だけリリースするために、複数のコールバックに注意する必要があります。
// C++ Module
#include <functional>
void cppFnRequiringCallback(std::function<void(void)> callback) {
callback();
}
//Objective-C Module
#import "CppFnRequiringCallback.h"
@interface MyObj : NSObject
- (void) callCppFunction;
- (void) myCallbackFn;
@end
void cppTrampoline(const void *caller) {
id callerObjC = CFBridgingRelease(caller);
[callerObjC myCallbackFn];
}
@implementation MyObj
- (void) callCppFunction {
auto callback = [self]() {
const void *caller = CFBridgingRetain(self);
cppTrampoline(caller);
};
cppFnRequiringCallback(callback);
}
- (void) myCallbackFn {
NSLog(@"Received callback.");
}
@end
解決策2）別の方法は、追加の安全性なしで、弱参照と同等のものを使用することです（つまり、保持カウントを変更しない）。
Objective-C言語は、これを行う__bridgeキャスト修飾子を提供します（CFBridgingRetainおよびCFBridgingReleaseは、それぞれObjective-C言語の構成__bridge_retainedおよびreleaseに対する薄いCocoaラッパーのようですが、Cocoaには__bridgeに相当するものはないようです）。
必要な変更は次のとおりです。
void cppTrampoline(void *caller) {
id callerObjC = (__bridge id)caller;
[callerObjC myCallbackFn];
}
- (void) callCppFunction {
auto callback = [self]() {
void *caller = (__bridge void *)self;
cppTrampoline(caller);
};
cppFunctionRequiringCallback(callback);
}