web-dev-qa-db-ja.com

CMakeでのプラ​​ットフォームの検出

boost::asioからいくつかの機能を追加しました。これにより、コンパイラの「警告」が発生します。

_WIN32_WINNTまたは_WIN32_WINDOWSを適切に定義してください。

その問題は here で対処されました。 WindowsでビルドしているときにCMakeに検出させ、適切な定義またはコマンドライン引数を作成したいのですが。

c++cmakeboost-asio
21
2NinerRomeo

これが簡単な解決策です。

macro(get_WIN32_WINNT version)
    if (WIN32 AND CMAKE_SYSTEM_VERSION)
        set(ver ${CMAKE_SYSTEM_VERSION})
        string(REPLACE "." "" ver ${ver})
        string(REGEX REPLACE "([0-9])" "0\\1" ver ${ver})

        set(${version} "0x${ver}")
    endif()
endmacro()

get_WIN32_WINNT(ver)
add_definitions(-D_WIN32_WINNT=${ver})
22
KneLL

CMakeLists.txtファイル内で、次のことができます。

IF (WIN32)
  # set stuff for windows
ELSE()
  # set stuff for other systems
ENDIF()
35
karlphillip

これはKneLLの回答の拡張バージョンで、Windows 10もチェックしています。

if(WIN32)
    macro(get_WIN32_WINNT version)
        if(CMAKE_SYSTEM_VERSION)
            set(ver ${CMAKE_SYSTEM_VERSION})
            string(REGEX MATCH "^([0-9]+).([0-9])" ver ${ver})
            string(REGEX MATCH "^([0-9]+)" verMajor ${ver})
            # Check for Windows 10, b/c we'll need to convert to hex 'A'.
            if("${verMajor}" MATCHES "10")
                set(verMajor "A")
                string(REGEX REPLACE "^([0-9]+)" ${verMajor} ver ${ver})
            endif()
            # Remove all remaining '.' characters.
            string(REPLACE "." "" ver ${ver})
            # Prepend each digit with a zero.
            string(REGEX REPLACE "([0-9A-Z])" "0\\1" ver ${ver})
            set(${version} "0x${ver}")
        endif()
    endmacro()

    get_WIN32_WINNT(ver)
    add_definitions(-D_WIN32_WINNT=${ver})
endif()
10
squareskittles

Karlphilipが指摘したように、プラットフォームの検出にはif(WIN32)を使用できます。

プリプロセッサ定義をアプリケーションに渡すには、いくつかの可能性があります。

  • CMakeの configure_file によって前処理される構成ヘッダーを使用します。このアプローチには、すべての_#define_ sが実際にはビルド環境ではなくコードの一部であるという利点があります。欠点は、CMakeによる（自動）前処理ステップが必要なことです。
  • add_definitions を使用します。これにより、プロジェクト内のすべてのソースファイルにプリプロセッサフ​​ラグが追加されるため、より迅速でダーティなアプローチになります。

  • COMPILE_DEFINITIONS プロパティを使用します。これにより、ファイルごと（さらには構成ごと）で定義を細かく制御できます。set_property(SOURCE ${YOUR_SOURCE_FILES} APPEND PROPERTY COMPILE_DEFINITIONS YOUR_FLAG1 YOUR_FLAG2)

    最近のCMakeバージョン（2.8.12以降）では、より便利な _target_compile_definitions_ コマンドを使用することもできます。

私は通常後者を好みますが、それは主に個人的な好みの問題です。

5
ComicSansMS

KneLLsの改善されたバージョンの答え：

macro(get_WIN32_WINNT version)
    if (WIN32 AND CMAKE_SYSTEM_VERSION)
        set(ver ${CMAKE_SYSTEM_VERSION})
        string(REGEX REPLACE "^([0-9])[.]([0-9]).*" "0\\10\\2" ver ${ver})
        set(${version} "0x${ver}")
    endif()
endmacro()

get_WIN32_WINNT(ver)
add_definitions(-D_WIN32_WINNT=${ver})

私の場合、KneLLsバージョンは機能しませんでした。CMAKE_SYSTEM_VERSIONは6.3.9600であり、${ver}=0x060306090000

ただし、このバージョンはWindows 10以降では失敗します。最初の数値が9より大きいかどうかを確認し、それを正しい16進数値に変換する必要があります。

1
Twonky