web-dev-qa-db-ja.com

ソースツリーからバイナリツリーにディレクトリをコピーする方法は？

ソースツリーからバイナリツリーにディレクトリをコピーしています。例：wwwをbinフォルダーにコピーする方法。

work
├─bin
└─src
    ├─doing
    │  └─www
    ├─include
    └─lib

ありがとう。

ccopycmake
56
Jiang Bian

CMake 2.8では、 file(COPY ...) コマンドを使用します。

古いCMakeバージョンでは、このマクロは1つのディレクトリから別のディレクトリにファイルをコピーします。コピーしたファイルの変数を置き換えたくない場合は、configure_file @ONLY引数を変更します。

# Copy files from source directory to destination directory, substituting any
# variables.  Create destination directory if it does not exist.

macro(configure_files srcDir destDir)
    message(STATUS "Configuring directory ${destDir}")
    make_directory(${destDir})

    file(GLOB templateFiles RELATIVE ${srcDir} ${srcDir}/*)
    foreach(templateFile ${templateFiles})
        set(srcTemplatePath ${srcDir}/${templateFile})
        if(NOT IS_DIRECTORY ${srcTemplatePath})
            message(STATUS "Configuring file ${templateFile}")
            configure_file(
                    ${srcTemplatePath}
                    ${destDir}/${templateFile}
                    @ONLY)
        endif(NOT IS_DIRECTORY ${srcTemplatePath})
    endforeach(templateFile)
endmacro(configure_files)
34
Chin Huang

configureコマンドは、cmakeの実行時にのみファイルをコピーします。別のオプションは、新しいターゲットを作成し、custom_commandオプションを使用することです。私が使用しているものは次のとおりです（複数回実行する場合は、add_custom_target行を呼び出しごとに一意にします）。

macro(copy_files GLOBPAT DESTINATION)
  file(GLOB COPY_FILES
    RELATIVE ${CMAKE_CURRENT_SOURCE_DIR}
    ${GLOBPAT})
  add_custom_target(copy ALL
    COMMENT "Copying files: ${GLOBPAT}")

  foreach(FILENAME ${COPY_FILES})
    set(SRC "${CMAKE_CURRENT_SOURCE_DIR}/${FILENAME}")
    set(DST "${DESTINATION}/${FILENAME}")

    add_custom_command(
      TARGET copy
      COMMAND ${CMAKE_COMMAND} -E copy ${SRC} ${DST}
      )
  endforeach(FILENAME)
endmacro(copy_files)
26
Seth Johnson

誰も言及していないのでcmake -E copy_directoryカスタムターゲットとして、ここに私が使用したものがあります。

add_custom_target(copy-runtime-files ALL
    COMMAND cmake -E copy_directory ${CMAKE_SOURCE_DIR}/runtime-files-dir ${CMAKE_BINARY_DIR}/runtime-files-dir
    DEPENDS ${MY_TARGET})
18
juzzlin

Execute_processを使用して、cmake -Eを呼び出します。ディープコピーが必要な場合は、copy_directoryコマンド。さらに良いのは、create_symlinkコマンドでsymlink（プラットフォームがサポートしている場合）を作成できることです。後者は次のように実現できます。

execute_process(COMMAND ${CMAKE_COMMAND} -E create_symlink ${CMAKE_SOURCE_DIR}/path/to/www
                                                           ${CMAKE_BINARY_DIR}/path/to/www)

From： http://www.cmake.org/pipermail/cmake/2009-March/028299.html

15
Jiang Bian

感謝！これは、add_custom_targetとadd_custom_commandの束を使用するのに非常に役立つアドバイスです。プロジェクトのあらゆる場所で使用する次の関数を作成しました。インストールルールも指定します。主にインターフェイスヘッダーファイルをエクスポートするために使用します。

#
# export file: copy it to the build tree on every build invocation and add rule for installation
#
function    (cm_export_file FILE DEST)
  if    (NOT TARGET export-files)
    add_custom_target(export-files ALL COMMENT "Exporting files into build tree")
  endif (NOT TARGET export-files)
  get_filename_component(FILENAME "${FILE}" NAME)
  add_custom_command(TARGET export-files COMMAND ${CMAKE_COMMAND} -E copy_if_different "${CMAKE_CURRENT_SOURCE_DIR}/${FILE}" "${CMAKE_CURRENT_BINARY_DIR}/${DEST}/${FILENAME}")
  install(FILES "${FILE}" DESTINATION "${DEST}")
endfunction (cm_export_file)

使用方法は次のとおりです。

cm_export_file("API/someHeader0.hpp" "include/API/")
cm_export_file("API/someHeader1.hpp" "include/API/")
2
prokher

セス・ジョンソンからの回答に基づいて、それは私がより便利にするために書いたものです。

# Always define the target
add_custom_target(copy_resources ALL COMMENT "Copying resources…")

# Copy single files
macro(add_files_to_environment files)
    add_custom_command(TARGET copy_resources POST_BUILD
        COMMAND ${CMAKE_COMMAND} -E copy ${ARGV} ${CMAKE_CURRENT_BINARY_DIR})
endmacro()

# Copy full directories
macro(add_directory_to_environment distant local_name)
    file(GLOB_RECURSE DistantFiles
        RELATIVE ${distant}
        ${distant}/*)
    foreach(Filename ${DistantFiles})
        set(SRC "${distant}/${Filename}")
        set(DST "${CURRENT_BUILD_DIR}/${local_name}/${Filename}")
        add_custom_command(TARGET copy_resources POST_BUILD
            COMMAND ${CMAKE_COMMAND} -E copy ${SRC} ${DST})

        message(STATUS "file ${Filename}")
    endforeach(Filename)
endmacro()

編集：それは本当に期待どおりに動作しません。これは問題なく動作します。

# Copy single files
macro(resource_files files)
    foreach(file ${files})
        message(STATUS "Copying resource ${file}")
        file(COPY ${file} DESTINATION ${Work_Directory})
    endforeach()
endmacro()

# Copy full directories
macro(resource_dirs dirs)
    foreach(dir ${dirs})
        # Replace / at the end of the path (copy dir content VS copy dir)
        string(REGEX REPLACE "/+$" "" dirclean "${dir}")
        message(STATUS "Copying resource ${dirclean}")
        file(COPY ${dirclean} DESTINATION ${Work_Directory})
    endforeach()
endmacro()
1
Salamandar