web-dev-qa-db-ja.com

CMakeの下の複数のディレクトリ

私は現在、再帰的なmakeとautotoolsを使用していますが、次のようなプロジェクトのためにCMakeに移行したいと考えています。

lx/ (project root)
    src/
        lx.c (contains main method)
        conf.c
        util/
            str.c
            str.h
            etc.c
            etc.h
        server/
            server.c
            server.h
            request.c
            request.h
        js/
            js.c
            js.h
            interp.c
            interp.h
    bin/
        lx (executable)

これについてどうすればいいですか?

37
Aaron Yodaiken

Lx/srcディレクトリよりも高いソースがない場合、lx/CMakeLists.txtファイルは必要ありません。ある場合は、次のようになります。

cmake_minimum_required(VERSION 2.8 FATAL_ERROR)
project(lx)

add_subdirectory(src)
add_subdirectory(dir1)
add_subdirectory(dir2)

# And possibly other commands dealing with things
# directly in the "lx" directory

...ここで、サブディレクトリはライブラリ依存関係の順序で追加されます。何にも依存しないライブラリを最初に追加し、次にそれらに依存するライブラリを追加する必要があります。

lx/src/CMakeLists.txt

cmake_minimum_required(VERSION 2.8 FATAL_ERROR)
project(lx_exe)

add_subdirectory(util)
add_subdirectory(js)
add_subdirectory(server)

set(lx_source_files conf.c lx.c)
add_executable(lx ${lx_source_files})

target_link_libraries(lx server)
  # also transitively gets the "js" and "util" dependencies

lx/src/util/CMakeLists.txt

set(util_source_files
  etc.c
  etc.h
  str.c
  str.h
)
add_library(util ${util_source_files})

lx/src/js/CMakeLists.txt

set(js_source_files
  interp.c
  interp.h
  js.c
  js.h
)
add_library(js ${js_source_files})

target_link_libraries(js util)

lx/src/server/CMakeLists.txt

set(server_source_files
  request.c
  request.h
  server.c
  server.h
)
add_library(server ${server_source_files})

target_link_libraries(server js)
  # also transitively gets the "util" dependency

次に、コマンドプロンプトで:

mkdir lx/bin
cd lx/bin

cmake ..
  # or "cmake ../src" if the top level
  # CMakeLists.txt is in lx/src

make

デフォルトでは、lx実行可能ファイルは、この正確なレイアウトを使用して「lx/bin/src」ディレクトリに配置されます。 RUNTIME_OUTPUT_DIRECTORYターゲットプロパティとset_propertyコマンドを使用して、最終的にどのディレクトリになるかを制御できます。

http://www.cmake.org/cmake/help/cmake-2-8-docs.html#prop_tgt:RUNTIME_OUTPUT_DIRECTORY

http://www.cmake.org/cmake/help/cmake-2-8-docs.html#command:set_property

Libがadd_libraryを介してCMakeターゲットとして構築されている場合はCMakeターゲット名で、そうでない場合はライブラリファイルへのフルパスでtarget_link_libraries libsを参照します。

「cmake --help-command target_link_libraries」の出力、またはその他のcmakeコマンド、およびここにあるcmakeコマンドの完全なオンラインドキュメントも参照してください。

http://www.cmake.org/cmake/help/cmake-2-8-docs.html#section_Commands

http://www.cmake.org/cmake/help/cmake-2-8-docs.html#command:target_link_libraries

74
DLRdave