web-dev-qa-db-ja.com

FireMonkeyクロスプラットフォームアプリケーションのデフォルトブラウザでURLを開く方法は？

通常、私は以下を使用します：ShellExecute(0, 'OPEN', PChar(edtURL.Text), '', '', SW_SHOWNORMAL);

すべてのプラットフォーム（Windows and OSX）で、どのようにして同じ動作（デフォルトのブラウザーでリンクを開く）ができますか？

delphibrowserdelphi-xe2firemonkey
28
Whiler

FireMonkeyディスカッションフォーラムで、NSWorkspace.URLForApplicationToOpenURLに関する質問にこのコードを見つけました。

uses
  Posix.Stdlib;
....
  _system(PAnsiChar('open ' + ACommand));

（私はテストしていません）

更新：PosixはWindowsでは使用できないため、すべてのプラットフォームで同じOS呼び出しを使用するソリューションを作成することはできません。そのようなコードを、いくつかのIFDEF POSIXなどがある中央の「XPlatform」ユニットに移動することをお勧めします。

13
mjn

mjn の答えについては、以下の単元を書いてみました。 Windowsでのテストは成功しましたが、このプラットフォームでテストするOSXがありません。誰かがそれが機能することを確認できたら、私は感謝します。

unit fOpen;

interface

uses
{$IFDEF MSWINDOWS}
  Winapi.ShellAPI, Winapi.Windows;
{$ENDIF MSWINDOWS}
{$IFDEF POSIX}
  Posix.Stdlib;
{$ENDIF POSIX}

type
  TMisc = class
    class procedure Open(sCommand: string);
  end;

implementation

class procedure TMisc.Open(sCommand: string);
begin
{$IFDEF MSWINDOWS}
  ShellExecute(0, 'OPEN', PChar(sCommand), '', '', SW_SHOWNORMAL);
{$ENDIF MSWINDOWS}
{$IFDEF POSIX}
  _system(PAnsiChar('open ' + AnsiString(sCommand)));
{$ENDIF POSIX}
end;

end.

そして私はそれをこのように呼びます：

TMisc.Open('https://stackoverflow.com/questions/7443264/how-to-open-an-url-with-the-default-browser-with-firemonkey-cross-platform-applic');
18
Whiler

すべてのプラットフォーム（Windows、macOs、iOS、Android）で、私が書いたユニットを使用できます 私のブログ

unit u_urlOpen;

interface

uses
  System.SysUtils, System.Types, System.UITypes, System.Classes,
  System.Variants,
{$IF Defined(IOS)}
  macapi.helpers, iOSapi.Foundation, FMX.helpers.iOS;
{$ELSEIF Defined(Android)}
Androidapi.JNI.GraphicsContentViewText,
  Androidapi.JNI.Net,
   Androidapi.JNI.App,
  Androidapi.helpers;
{$ELSEIF Defined(MACOS)}
Posix.Stdlib;
{$ELSEIF Defined(MSWINDOWS)}
Winapi.ShellAPI, Winapi.Windows;
{$ENDIF}

type
  tUrlOpen = class
    class procedure Open(URL: string);
  end;

implementation

class procedure tUrlOpen.Open(URL: string);
{$IF Defined(Android)}
var
  Intent: JIntent;
{$ENDIF}
begin
{$IF Defined(Android)}
  Intent := TJIntent.Create;
  Intent.setAction(TJIntent.JavaClass.ACTION_VIEW);
  Intent.setData(StrToJURI(URL));
  tandroidhelper.Activity.startActivity(Intent);
  // SharedActivity.startActivity(Intent);
{$ELSEIF Defined(MSWINDOWS)}
  ShellExecute(0, 'OPEN', PWideChar(URL), nil, nil, SW_SHOWNORMAL);
{$ELSEIF Defined(IOS)}
  SharedApplication.OpenURL(StrToNSUrl(URL));
{$ELSEIF Defined(MACOS)}
  _system(PAnsiChar('open ' + AnsiString(URL)));
{$ENDIF}
end;

end.
6
Patrick PREMARTIN

正常にテストされたXE2 C++コード（Windows 7 64およびOSX Lion）、マイナーな改善。ありがとう、Whirr、痛みは終わりました:)

#include <fmx.h>
// ---------------------------------------------------------------------------
#ifdef _WIN32
#include <shellapi.h>
#endif// Windows
#ifdef TARGET_OS_MAC
#include <Posix.Stdlib.hpp>
#endif // Mac

void OpenCommand(String _sCommand) {
    #ifdef _Windows
    String open = "open";
    ShellExecute(0, open.w_str(), _sCommand.c_str(), NULL, NULL, SW_SHOWNORMAL);
    #endif // Windows

    #ifdef TARGET_OS_MAC
    system(AnsiString("open " + AnsiString(_sCommand)).c_str());
    #endif // Mac
}
3
Tuomas Kayhko

そして今、C++バージョン（テストされていないOSxコード、_POSIX #defについても不明）：

#ifdef _Windows
#include <Winapi.Windows.hpp>
#endif // _Windows
#ifdef _POSIX
#include <Posix.Stdlib.h>
#endif // _POSIX

void OpenCommand(String _sCommand)
{
    #ifdef _Windows
    ShellExecute(0, _T("open"), _sCommand.c_str(), _T(""), _T(""), SW_SHOWNORMAL);
    #endif // _Windows
    #ifdef _POSIX
    _system(AnsiString("open " + AnsiString(_sCommand)).c_str());
    #endif // _POSIX
}
1
Rhys Drummond

@NicoBluが述べたように、受け入れられたソリューションは、 '＆'が最初に発生した後にURLを切り捨てるようです。以下は切り捨てなしで私のために働くものです：

uses Macapi.AppKit, Macapi.Foundation, Macapi.Helpers;

// ...

procedure OpenLinkInDefaultBrowser(const Link: string);
  var URL : NSURL;
      Workspace : NSWorkspace;
begin
  URL := TNSURL.Wrap(TNSURL.OCClass.URLWithString(StrToNSStr(Link)));
  Workspace := TNSWorkspace.Wrap(TNSWorkspace.OCClass.sharedWorkspace);
  Workspace.openURL(URL);
end;
1
DNR
_system(PAnsiChar('open ' + AnsiString(sCommand)));

uRL文字列（sCommand）にアンパサンド文字（&）が含まれている場合、機能しません。クエリ文字列で多くの引数を指定する必要があります。

Defに送信されたURL OSX（Safari）のブラウザーは、&が最初に発生したときに切り捨てられます。

0
NicoBlu
LEncodedString : String;

begin
    LEncodedString := TIdURI.URLEncode('http://www.malcolmgroves.com');
    sharedApplication.openURL(StringToNSURL(LEncodedString));
end;
0
Maxime Bonin