web-dev-qa-db-ja.com

xmlファイルからデータを読み取り、それをデルファイ言語でテキストボックスに表示する方法

私はdelphi言語に不慣れですが、ここに疑問があります。Vehicle.xmlというxmlファイルがあります。

こんな感じ

<data>
<vehicle>
    <type>Car</type>
    <model>2005</model>
    <number>1568</number>
</vehicle>
<vehicle>
    <type>Car</type>
    <model>2009</model>
    <number>1598</number>
</vehicle>
</data>

私のDelphiフォームには、次の3つのテキストボックスが含まれています。

  • txtType
  • txtModel
  • txtnumber

ページの読み込み中に、次のようなテキストボックスにvehicle.xmlの内容を表示したいと思います。

  • txtType = Car
  • txtModel = 2005
  • txtNumber = "1568"
9
Banana

Delphi独自のTXMLDocumentコンポーネントを見てください。次に例を示します。

uses
  ..., XMLIntf, XMLDoc;

procedure TForm1.FormCreate(Sender: TObject);
var
  Vehicle: IXMLNode;
begin
  XMLDocument1.FileName :='vehicle.xml';
  XMLDocument1.Active := True;
  try
    Vehicle := XMLDocument.DocumentElement;
    txtType.Text := Vehicle.ChildNodes['type'].Text;
    txtModel.Text := Vehicle.ChildNodes['model'].Text;
    txtnumber.Text  := Vehicle.ChildNodes['number'].Text;
  finally
    XMLDocument1.Active := False;
  end;
end;

または、IXMLDocumentインターフェースを直接使用します(TXMLDocumentが実装します)。

uses
  ..., XMLIntf, XMLDoc;

procedure TForm1.FormCreate(Sender: TObject);
var
  Doc: IXMLDocument;
  Vehicle: IXMLNode;
begin
  Doc := LoadXMLDocument('vehicle.xml');
  Vehicle := Doc.DocumentElement;
  txtType.Text := Vehicle.ChildNodes['type'].Text;
  txtModel.Text := Vehicle.ChildNodes['model'].Text;
  txtnumber.Text := Vehicle.ChildNodes['number'].Text;
end;

更新:質問のXMLが変更され、vehicle要素がdata要素内にラップされ、複数のvehicle要素が含まれるようになりました。 。したがって、上記のコードはそれに応じて調整する必要があります。例:

uses
  ..., XMLIntf, XMLDoc;

procedure TForm1.FormCreate(Sender: TObject);
var
  Doc: IXMLDocument;
  Data: IXMLNode;
  Node: IXMLNode;
  I: Integer;
begin
  Doc := LoadXMLDocument('vehicle.xml');
  Data := Doc.DocumentElement;
  for I := 0 to Data.ChildNodes.Count-1 do
  begin
    Node := Data.ChildNodes[I];
    // if all of the child nodes will always be 'vehicle' only
    // then this check can be removed...
    if Node.LocalName = 'vehicle' then
    begin
      // use Node.ChildNodes['type'], Node.ChildNodes['model'],
      // and Node.ChildNodes['number'] as needed...
    end;
  end;
end;
12
Remy Lebeau

ユニットMSXML(またはその他のXMLパーサー)を使用してXMLファイルを読み取ることができます。

XMLファイルを表すツリー構造を提供します。ここで、車両は最上位ノードであり、他の3つは子ノードです。

各ノードには、値を取得するために使用できるtextプロパティがあります。これをフォームのテキストボックスに割り当てることができます。

コードサンプル:

uses
  ActiveX,
  MSXML;

procedure TForm1.ReadFromXML(const AFilename: string);
var
  doc : IXMLDOMDocument;
  node : IXMLDomNode;

begin
  CoInitialize; // Needs to be called once before using CoDOMDocument.Create;
  if not FileExists(AFileName) then 
    Exit; // Add proper Error handling.

  doc := CoDOMDocument.Create;
  doc.load(AFileName);

  if (doc.documentElement = nil) or (doc.documentElement.nodeName <> 'vehicle') then
    Exit; // Add proper Error handling.

  node := doc.documentElement.firstChild;
  while node<>nil do begin
    if node.nodeName = 'model' then
      txtModel.Text := node.text;
    if node.nodeName = 'number' then
      txtNumber.Text := node.text;
    if node.nodeName = 'type' then
      txtType.Text := node.text;
    node := node.nextSibling;
  end;
end;
5
Toon Krijthe