web-dev-qa-db-ja.com

Emacsのウィンドウのサイズを設定するにはどうすればよいですか?

私はemacsを開始している画面のサイズを検出し、それに応じて開始するウィンドウのサイズと位置を調整しようとしています(emacs-speakのフレームだと思います)。 .emacsを設定して、画面の左上近くの左上隅に「かなり大きな」ウィンドウが常に表示されるようにします。

私はこれがbigの一般的な場合を求めていると思うので、少し絞り込むために最も興味があるのはGNU Emacs 22 on Windows and(Debian) Linux。

101
Tom Dunham

解像度に応じてサイズを変更する場合は、次のようなことができます(特定のニーズに応じて優先幅と解像度を調整します):

(defun set-frame-size-according-to-resolution ()
  (interactive)
  (if window-system
  (progn
    ;; use 120 char wide window for largeish displays
    ;; and smaller 80 column windows for smaller displays
    ;; pick whatever numbers make sense for you
    (if (> (x-display-pixel-width) 1280)
           (add-to-list 'default-frame-alist (cons 'width 120))
           (add-to-list 'default-frame-alist (cons 'width 80)))
    ;; for the height, subtract a couple hundred pixels
    ;; from the screen height (for panels, menubars and
    ;; whatnot), then divide by the height of a char to
    ;; get the height we want
    (add-to-list 'default-frame-alist 
         (cons 'height (/ (- (x-display-pixel-height) 200)
                             (frame-char-height)))))))

(set-frame-size-according-to-resolution)

Window-systemはemacsの新しいバージョンでは廃止されることに注意してください。適切な代替は(display-graphic-p)この回答 質問の emacsが端末モードにあることを検出する方法 を参照してください。

87
Bryan Oakley

私は私の.emacs

(if (window-system)
  (set-frame-height (selected-frame) 60))

また、関数set-frame-sizeset-frame-position、およびset-frame-width。つかいます C-h f(別名M-x describe-function)詳細なドキュメントを表示します。

現在のウィンドウ環境でフレームの最大の高さ/幅を計算する方法があるかどうかはわかりません。

48
Chris Conway

から取得: http://www.gnu.org/software/emacs/windows/old/faq4.html

(setq default-frame-alist
      '((top . 200) (left . 400)
        (width . 80) (height . 40)
        (cursor-color . "white")
        (cursor-type . box)
        (foreground-color . "yellow")
        (background-color . "black")
        (font . "-*-Courier-normal-r-*-*-13-*-*-*-c-*-iso8859-1")))

(setq initial-frame-alist '((top . 10) (left . 30)))

最初の設定は、開始時にポップアップする最初のフレームを含むすべてのemacsフレームに適用されます。 2番目の設定は、追加の属性を最初のフレームに追加します。これは、emacsを開始する元のフレームを知っているといい場合があるためです。

21
Justin

X-Window環境でこれを行う最も簡単な方法は、 Xリソース を使用することです。 .Xdefaultsの関連部分は次のようになります。

Emacs.geometry: 80x70

ディスプレイの左上隅に強制的に追加するには、+ 0 + 0位置座標で接尾辞を付ける必要があります。 (私がそれをしない理由は、時々新しいフレームを生成し、前のフレームとまったく同じ場所に表示されると物事が混乱するためです)

マニュアルによると、 この手法はMS Windowsでも機能します 、レジストリにキー/値のペアとしてリソースを保存します。私はそれをテストしたことがありません。それは素晴らしいかもしれませんが、単にファイルを編集するよりもはるかに不便かもしれません。

17
JB.

次のコードを.emacsに追加してみてください

(add-to-list 'default-frame-alist '(height . 24))

(add-to-list 'default-frame-alist '(width . 80)) 
16
norbux

Emacsを起動するときに-geometryパラメーターを使用することもできます:emacs -geometry 80x60+20+30は、幅80文字、高さ60行、左上隅が背景の左上隅から20ピクセル右、30ピクセル下のウィンドウを提供します。

12
Graeme Perrow

Ubuntuで:

(defun toggle-fullscreen ()
  (interactive)
  (x-send-client-message nil 0 nil "_NET_WM_STATE" 32
                 '(2 "_NET_WM_STATE_MAXIMIZED_VERT" 0))
  (x-send-client-message nil 0 nil "_NET_WM_STATE" 32
                 '(2 "_NET_WM_STATE_MAXIMIZED_HORZ" 0))
)
(toggle-fullscreen)
7
ftravers

Windowsでは、この関数を使用してemacsフレームを最大化できます。

(defun w32-maximize-frame ()
  "Maximize the current frame"
  (interactive)
  (w32-send-sys-command 61488))
5
Jérôme Radix
(setq initial-frame-alist
        (append '((width . 263) (height . 112) (top . -5) (left . 5) (font . "4.System VIO"))
                initial-frame-alist))

(setq default-frame-alist
        (append '((width . 263) (height . 112) (top . -5) (left . 5) (font . "4.System VIO"))
                default-frame-alist))
1
Peter Miehle
(defun set-frame-size-according-to-resolution ()
  (interactive)
  (if window-system
  (progn
    ;; use 120 char wide window for largeish displays
    ;; and smaller 80 column windows for smaller displays
    ;; pick whatever numbers make sense for you
    (if (> (x-display-pixel-width) 1280)
           (add-to-list 'default-frame-alist (cons 'width 120))
           (add-to-list 'default-frame-alist (cons 'width 80)))
    ;; for the height, subtract a couple hundred pixels
    ;; from the screen height (for panels, menubars and
    ;; whatnot), then divide by the height of a char to
    ;; get the height we want
    (add-to-list 'default-frame-alist 
         (cons 'height (/ (- (x-display-pixel-height) 200)
                             (frame-char-height)))))))

(set-frame-size-according-to-resolution)

ブライアン・オークリーの設定が好きです。しかし、'heightはmy GNU Emacs 24.1.1。では正しく動作しません。

0
WisdomFusion