web-dev-qa-db-ja.com

Excelワークシートを名前で参照しますか？

ワークシートの名前を変数の文字列として保存しています。このワークシートで何らかの操作を実行するにはどうすればよいですか？

私はこのようなことをしますが：

nameOfWorkSheet = "test"
ActiveWorkbook.Worksheets(nameOfWorkSheet).someOperation()

これをどうやってやるの？

excelvbaworksheet
19
Jonson Bylvaklov

デモンストレーションする方法の使用、変数の使用、変数の使用など、いくつかのオプションがあります。

私の好みは以下のオプション4です。DimタイプWorksheetの変数。ワークシートを保存し、変数のメソッドを呼び出すか、関数に渡しますが、どのオプションでも機能します。

Sub Test()
  Dim SheetName As String
  Dim SearchText As String
  Dim FoundRange As Range

  SheetName = "test"      
  SearchText = "abc"

  ' 0. If you know the sheet is the ActiveSheet, you can use if directly.
  Set FoundRange = ActiveSheet.UsedRange.Find(What:=SearchText)
  ' Since I usually have a lot of Subs/Functions, I don't use this method often.
  ' If I do, I store it in a variable to make it easy to change in the future or
  ' to pass to functions, e.g.: Set MySheet = ActiveSheet
  ' If your methods need to work with multiple worksheets at the same time, using
  ' ActiveSheet probably isn't a good idea and you should just specify the sheets.

  ' 1. Using Sheets or Worksheets (Least efficient if repeating or calling multiple times)
  Set FoundRange = Sheets(SheetName).UsedRange.Find(What:=SearchText)
  Set FoundRange = Worksheets(SheetName).UsedRange.Find(What:=SearchText)

  ' 2. Using Named Sheet, i.e. Sheet1 (if Worksheet is named "Sheet1"). The
  ' sheet names use the title/name of the worksheet, however the name must
  ' be a valid VBA identifier (no spaces or special characters. Use the Object
  ' Browser to find the sheet names if it isn't obvious. (More efficient than #1)
  Set FoundRange = Sheet1.UsedRange.Find(What:=SearchText)

  ' 3. Using "With" (more efficient than #1)
  With Sheets(SheetName)
    Set FoundRange = .UsedRange.Find(What:=SearchText)
  End With
  ' or possibly...
  With Sheets(SheetName).UsedRange
    Set FoundRange = .Find(What:=SearchText)
  End With

  ' 4. Using Worksheet variable (more efficient than 1)
  Dim MySheet As Worksheet
  Set MySheet = Worksheets(SheetName)
  Set FoundRange = MySheet.UsedRange.Find(What:=SearchText)

  ' Calling a Function/Sub
  Test2 Sheets(SheetName) ' Option 1
  Test2 Sheet1 ' Option 2
  Test2 MySheet ' Option 4

End Sub

Sub Test2(TestSheet As Worksheet)
    Dim RowIndex As Long
    For RowIndex = 1 To TestSheet.UsedRange.Rows.Count
        If TestSheet.Cells(RowIndex, 1).Value = "SomeValue" Then
            ' Do something
        End If
    Next RowIndex
End Sub
12
Ryan

最善の方法は、Worksheet型の変数を作成し、VBAがActiveSheetを暗黙的に使用するたびにワークシートを割り当てて使用することです。

これにより、プログラムのサイズが大きくなったときに最終的に表示されるバグを回避できます。

たとえば、マクロが1つのシートでのみ機能する場合、Range("A1:C10").Sort Key1:=Range("A2")のようなものが適しています。しかし、最終的にマクロを展開して複数のシートで動作し、これが機能しないことを確認し、ShTest1.Range("A1:C10").Sort Key1:=Range("A2")...に調整して、まだ機能しないことを確認します。

正しい方法は次のとおりです。

Dim ShTest1 As Worksheet
Set ShTest1 = Sheets("Test1")
ShTest1.Range("A1:C10").Sort Key1:=ShTest1.Range("A2")
6
stenci

Ryanの答えを拡張するには、変数を宣言するときに（Dimを使用）、下の画像のようにVBEの予測テキスト機能を使用して少しチートできます。 screenshot of predictive text in VBE

そのリストに表示されている場合、そのタイプのオブジェクトを変数に割り当てることができます。ライアンが指摘したように、ワークシートだけでなく、チャート、範囲、ワークブック、シリーズなどもあります。

この変数を操作したいオブジェクトに等しく設定すると、Ryanがこの例で指摘したように、メソッドを呼び出したり、関数に渡したりすることができます。コレクションとオブジェクト（チャートまたはチャート、範囲または範囲など）に関しては、いくつかの障害が発生する可能性がありますが、試行錯誤を行うと確実に取得できます。

2
j boschiero