web-dev-qa-db-ja.com

Excelで範囲の各行をループする

これは、組み込み関数があると確信しているものの1つです（過去にも伝えられていたかもしれません）が、覚えておくために頭を掻いています。

Excel VBAを使用して複数列範囲の各行をループするにはどうすればよいですか？私が検索してきたすべてのチュートリアルは、1次元の範囲での作業についてのみ言及しているようです...

excelvbaexcel-vbaloopsexcel-2003
101
Margaret
Dim a As Range, b As Range

Set a = Selection

For Each b In a.Rows
    MsgBox b.Address
Next
137
Mike

このようなもの：

Dim rng As Range
Dim row As Range
Dim cell As Range

Set rng = Range("A1:C2")

For Each row In rng.Rows
  For Each cell in row.Cells
    'Do Something
  Next cell
Next row
134
David Andres

ループでは、次のようにR1C1参照メソッドを使用して、常にCellsクラスを使用することを好みます。

Cells(rr, col).Formula = ...

これにより、迅速かつ簡単にloop over over Range cells

Dim r As Long
Dim c As Long

c = GetTargetColumn() ' Or you could just set this manually, like: c = 1

With Sheet1 ' <-- You should always qualify a range with a sheet!

    For r = 1 To 10 ' Or 1 To (Ubound(MyListOfStuff) + 1)

        ' Here we're looping over all the cells in rows 1 to 10, in Column "c"
        .Cells(r, c).Value = MyListOfStuff(r)

        '---- or ----

        '...to easily copy from one place to another (even with an offset of rows and columns)
        .Cells(r, c).Value = Sheet2.Cells(r + 3, 17).Value


    Next r

End With
6
LimaNightHawk

これにつまずいて、自分の解決策を提案すると思いました。私は通常、マルチディメンション配列に範囲を割り当てる組み込み機能を使用するのが好きです（私もJSプログラマーだと思います）。

私はこのようなコードを頻繁に書いています：

Sub arrayBuilder()

myarray = Range("A1:D4")

'unlike most VBA Arrays, this array doesn't need to be declared and will be automatically dimensioned

For i = 1 To UBound(myarray)

    For j = 1 To UBound(myarray, 2)

    Debug.Print (myarray(i, j))

    Next j

Next i

End Sub

変数に範囲を割り当てることは、VBAでデータを操作する非常に強力な方法です。

6
tc_NYC