web-dev-qa-db-ja.com

VBAを使用してファイルが存在するかどうかを確認してください

Sub test()

thesentence = InputBox("Type the filename with full extension", "Raw Data File")

Range("A1").Value = thesentence

If Dir("thesentence") <> "" Then
    MsgBox "File exists."
Else
    MsgBox "File doesn't exist."
End If

End Sub

これで私が入力ボックスからテキスト値を拾うとき、それは働かない。ただし、If Dir()から"the sentence"を削除し、それをコード内の実際の名前に置き換えると、正常に機能します。誰かが手伝ってくれる？

excelvbaexcel-vba
76
Dinesh Goel

コードにDir("thesentence")が含まれていることに注意してください。これはDir(thesentence)である必要があります。

コードをこれに変更してください

Sub test()

thesentence = InputBox("Type the filename with full extension", "Raw Data File")

Range("A1").Value = thesentence

If Dir(thesentence) <> "" Then
    MsgBox "File exists."
Else
    MsgBox "File doesn't exist."
End If

End Sub
125
Cylian

ユーザーにファイルシステムからファイルを選択させるには、Office FileDialogオブジェクトを使用します。 VBプロジェクトまたはVBAエディタでMicrosoft Office Libraryへの参照を追加し、ヘルプを見てください。これは、人々に絶対パスを入力させるよりもはるかに優れています。

これはmsoFileDialogFilePickerを使用してユーザーが複数のファイルを選択できるようにする例です。 msoFileDialogOpenを使うこともできます。

'Note: this is Excel VBA code
Public Sub LogReader()
    Dim Pos As Long
    Dim Dialog As Office.FileDialog
    Set Dialog = Application.FileDialog(msoFileDialogFilePicker)

    With Dialog
        .AllowMultiSelect = True
        .ButtonName = "C&onvert"
        .Filters.Clear
        .Filters.Add "Log Files", "*.log", 1
        .Title = "Convert Logs to Excel Files"
        .InitialFileName = "C:\InitialPath\"
        .InitialView = msoFileDialogViewList

        If .Show Then
            For Pos = 1 To .SelectedItems.Count
                LogRead .SelectedItems.Item(Pos) ' process each file
            Next
        End If
    End With
End Sub

たくさんのオプションがありますので、あなたは可能なすべてを理解するために完全なヘルプファイルを見る必要があります。あなたは Office 2007 FileDialogオブジェクト （もちろん、あなたが使っているバージョンのための正しいヘルプを見つける必要があるでしょう）から始めることができます。

18
ErikE

@UberNubIsTrueからfileExistsへの修正：

Function fileExists(s_directory As String, s_fileName As String) As Boolean

  Dim obj_fso As Object, obj_dir As Object, obj_file As Object
  Dim ret As Boolean
   Set obj_fso = CreateObject("Scripting.FileSystemObject")
   Set obj_dir = obj_fso.GetFolder(s_directory)
   ret = False
   For Each obj_file In obj_dir.Files
     If obj_fso.fileExists(s_directory & "\" & s_fileName) = True Then
        ret = True
        Exit For
      End If
   Next

   Set obj_fso = Nothing
   Set obj_dir = Nothing
   fileExists = ret

 End Function

編集：短縮版

' Check if a file exists
Function fileExists(s_directory As String, s_fileName As String) As Boolean

    Dim obj_fso As Object

    Set obj_fso = CreateObject("Scripting.FileSystemObject")
    fileExists = obj_fso.fileExists(s_directory & "\" & s_fileName)

End Function
16
amackay11

それらのスピーチマークを取り除くだけです

Sub test()

Dim thesentence As String

thesentence = InputBox("Type the filename with full extension", "Raw Data File")

Range("A1").Value = thesentence

If Dir(thesentence) <> "" Then
    MsgBox "File exists."
Else
    MsgBox "File doesn't exist."
End If

End Sub

これは私が好きなものです：

Option Explicit

Enum IsFileOpenStatus
    ExistsAndClosedOrReadOnly = 0
    ExistsAndOpenSoBlocked = 1
    NotExists = 2
End Enum


Function IsFileReadOnlyOpen(FileName As String) As IsFileOpenStatus

With New FileSystemObject
    If Not .FileExists(FileName) Then
        IsFileReadOnlyOpen = 2  '  NotExists = 2
        Exit Function 'Or not - I don't know if you want to create the file or exit in that case.
    End If
End With

Dim iFilenum As Long
Dim iErr As Long
On Error Resume Next
    iFilenum = FreeFile()
    Open FileName For Input Lock Read As #iFilenum
    Close iFilenum
    iErr = Err
On Error GoTo 0

Select Case iErr
    Case 0: IsFileReadOnlyOpen = 0 'ExistsAndClosedOrReadOnly = 0
    Case 70: IsFileReadOnlyOpen = 1 'ExistsAndOpenSoBlocked = 1
    Case Else: IsFileReadOnlyOpen = 1 'Error iErr
End Select

End Function    'IsFileReadOnlyOpen
6
whytheq
Function FileExists(fullFileName As String) As Boolean
    FileExists = VBA.Len(VBA.Dir(fullFileName)) > 0
End Function

私のサイトでは、ほとんどうまく機能しています。空の文字列で ""呼び出すと、Dirは "connection.odc"を返します。あなたのみんながあなたの結果を共有することができれば素晴らしいでしょう。

とにかく、私はこれが好きです：

Function FileExists(fullFileName As String) As Boolean
  If fullFileName = "" Then
    FileExists = False
  Else
    FileExists = VBA.Len(VBA.Dir(fullFileName)) > 0
  End If
End Function
6
Joachim Brolin
Function FileExists(fullFileName As String) As Boolean
    FileExists = VBA.Len(VBA.Dir(fullFileName)) > 0
End Function
3
Ron Royston

あなたのコードの何が問題になっているのかはっきりしませんが、ファイルが存在するかどうかをチェックするためにオンラインで見つけたこの関数（コメント内のURL）を使用します。

Private Function File_Exists(ByVal sPathName As String, Optional Directory As Boolean) As Boolean
    'Code from internet: http://vbadud.blogspot.com/2007/04/vba-function-to-check-file-existence.html
    'Returns True if the passed sPathName exist
    'Otherwise returns False
    On Error Resume Next
    If sPathName <> "" Then

        If IsMissing(Directory) Or Directory = False Then

            File_Exists = (Dir$(sPathName) <> "")
        Else

            File_Exists = (Dir$(sPathName, vbDirectory) <> "")
        End If

    End If
End Function
3
Dan

ここの他の回答に基づいて、私はワンライナーを共有したいと思いますdirsとfilesで動作するはずです：

  • Len(Dir(path)) > 0 or Or Len(Dir(path, vbDirectory)) > 0  'version 1 - ... <> "" should be more inefficient generally
    • （ディレクトリに対してLen(Dir(path))だけが機能しませんでした（Excel 2010/Win7））
  • CreateObject("Scripting.FileSystemObject").FileExists(path)  'version 2 - could be faster sometimes, but only works for files (tested on Excel 2010/Win7)

PathExists(path)関数として：

Public Function PathExists(path As String) As Boolean
    PathExists = Len(Dir(path)) > 0 Or Len(Dir(path, vbDirectory)) > 0
End Function
0
Andreas Dietrich

非常に古い投稿ですが、修正を加えた後に役立ったので、共有したいと思いました。ディレクトリが存在するかどうかを確認する場合は、Dir関数にvbDirectory引数を追加します。それ以外の場合は、毎回0を返します。 （編集：これはロイの答えに応えたものだが、私は誤ってそれを通常の答えにした。）

Private Function FileExists(fullFileName As String) As Boolean
    FileExists = Len(Dir(fullFileName, vbDirectory)) > 0
End Function
0
Word Nerd