web-dev-qa-db-ja.com

BATCHスクリプトを使用して、ディレクトリにファイルの種類が存在するかどうかを確認します

こんにちはバッチファイルを作成して、特定のフォルダー内に任意の種類のファイルがあるかどうかを確認しようとしています。

これまでのところ、私は以下を試しました

if EXIST FOLDERNAME\\*.* ( echo Files Exist ) ELSE ( echo "Empty" )

次のようにtxtファイルなどのファイル拡張子を知っていれば、それを動作させることができます

if EXIST FOLDERNAME\\*.txt ( echo Files Exist ) ELSE ( echo "Empty" )

ご協力ありがとうございました

filebatch-filedirectory
30
psycho

フォルダーに少なくとも1つのファイルが含まれているかどうかを確認するには

>nul 2>nul dir /a-d "folderName\*" && (echo Files exist) || (echo No file found)

フォルダーまたはその子孫に少なくとも1つのファイルが含まれているかどうかを確認するには

>nul 2>nul dir /a-d /s "folderName\*" && (echo Files exist) || (echo No file found)

フォルダーに少なくとも1つのファイルまたはフォルダーが含まれているかどうかを確認します。
/aオプションは、隠しファイルとシステムファイル/フォルダーの検索を有効にします。

dir /b /a "folderName\*" | >nul findstr "^" && (echo Files and/or Folders exist) || (echo No File or Folder found)

フォルダーに少なくとも1つのフォルダーが含まれているかどうかを確認するには

dir /b /ad "folderName\*" | >nul findstr "^" && (echo Folders exist) || (echo No folder found)
41
dbenham

ディレクトリ内のファイルには、次のようなものを使用できます。

if exist *.csv echo "csv file found"

または

if not exist *.csv goto nofile
9
Maikel

これを使用できます

@echo off
for /F %%i in ('dir /b "c:\test directory\*.*"') do (
   echo Folder is NON empty
   goto :EOF
)
echo Folder is empty or does not exist

here から取得。

それはあなたが必要なことをするはずです。

6
Bali C