web-dev-qa-db-ja.com

gnuplotの線種

Gnuplotでさまざまな種類の線を描くにはどうすればよいですか？さまざまな色を描くようになりました。私のスクリプトはいくつかのファイルを結合しますが、それが行がダッシュではない理由だと思います。 4つのうち2つだけが破線です。ありがとうフェリペ

#!/usr/bin/gnuplot

set grid
set title 'Estado dos arquivos no BTRIM com peers de comportamento condicionado'
set xlabel 'Tempo discreto'
set ylabel 'Quantidade de arquivos'
set style line 1 lc rgb '#0060ad' lt 1 lw 2 pi -1 ps 1.0
set style line 2 lc rgb '#dd181f' lt 9 lw 2 pi -1 ps 1.0
set style line 3 lc rgb '#29c524' lt 6 lw 2 pi -1 ps 1.0
set style line 4 lc rgb '#7D72F9' lt 7 lw 2 pi -1 ps 1.0
set style line 5 lc rgb '#000000' lt 8 lw 2 pi -1 ps 1.0

set termoption dashed
#set pointintervalbox 0
#set boxwidth 0.1
#set style fill solid

plot '<paste ../00/StatisticNormal.txt ../01/StatisticNormal.txt ../02/StatisticNormal.txt  ../03/StatisticNormal.txt ../04/StatisticNormal.txt ../05/StatisticNormal.txt ../06/StatisticNormal.txt ../07/StatisticNormal.txt ../08/StatisticNormal.txt ../09/StatisticNormal.txt' smooth unique with line ls 1 title 'Normais', \
'<paste ../00/StatisticVogue.txt ../01/StatisticVogue.txt ../02/StatisticVogue.txt ../03/StatisticVogue.txt ../04/StatisticVogue.txt ../05/StatisticVogue.txt ../06/StatisticVogue.txt ../07/StatisticVogue.txt ../08/StatisticVogue.txt ../09/StatisticVogue.txt' smooth unique with line ls 2 title 'na Moda', \
'<paste ../00/StatisticPopular.txt ../01/StatisticPopular.txt ../02/StatisticPopular.txt ../03/StatisticPopular.txt ../04/StatisticPopular.txt ../05/StatisticPopular.txt ../06/StatisticPopular.txt ../07/StatisticPopular.txt ../08/StatisticPopular.txt ../09/StatisticPopular.txt' smooth unique with line ls 3 title 'Populares', \
'<paste ../00/StatisticRarity.txt ../01/StatisticRarity.txt ../02/StatisticRarity.txt ../03/StatisticRarity.txt ../04/StatisticRarity.txt ../05/StatisticRarity.txt ../06/StatisticRarity.txt ../07/StatisticRarity.txt ../08/StatisticRarity.txt ../09/StatisticRarity.txt' smooth unique with line ls 4 title 'Raros'

pause -1
gnuplot
53
Felipe

バージョン4.6まで

linestyleのダッシュタイプはlinetypeで指定されます。これは、linecolorで明示的に他の線を設定しない限り、線の色も選択します。

ただし、破線のサポートは、選択した端末によって異なります。

  1. png（libgdを使用）など、一部の端末は破線をサポートしていません
  2. pngcairoなどの他の端末は破線をサポートしていますが、デフォルトでは無効になっています。有効にするには、set termoption dashedまたはset terminal pngcairo dashed ...を使用します。
  3. 正確なダッシュパターンは端末によって異なります。定義されたlinetypeを表示するには、testコマンドを使用します。

ランニング

set terminal pngcairo dashed
set output 'test.png'
test
set output

与える：

enter image description here

一方、postscript端子には異なるダッシュパターンが表示されます。

set terminal postscript eps color colortext
set output 'test.eps'
test
set output

enter image description here

バージョン5.0

バージョン5.0以降、線種、ダッシュパターン、線の色に関連する次の変更が導入されました。

  • 新しいdashtypeパラメーターが導入されました。

    事前定義されたダッシュパターンを取得するには、たとえば.

    plot x dashtype 2

    次のようなカスタムダッシュパターンを指定することもできます。

    plot x dashtype (3,5,10,5),\
     2*x dashtype '.-_'

  • 端末オプションdashedおよびsolidは無視されます。デフォルトでは、すべての線は実線です。それらを破線に変更するには、例えば.

    set for [i=1:8] linetype i dashtype i

  • 線の色のデフォルトのセットが変更されました。 set colorsequence default|podo|classicを使用して、3つの異なるカラーセットから選択できます。

enter image description here

148
Christoph