web-dev-qa-db-ja.com

パラモーフィズムとは何ですか？

この古典的な論文 を読んで、私はパラモーフィズムに行き詰まっています。残念ながらこのセクションはかなり薄く、ウィキペディアのページには何も書かれていません。

私のHaskellの翻訳は：

para :: (a -> [a] -> b -> b) -> b -> [a] -> b
para f base = h
  where
    h []       =   base
    h (x:xs)   =   f x xs (h xs)

しかし、私はそれをしていません-私は型シグネチャや望ましい結果について直感を持っていません。

パラモーフィズムとは何ですか？実際に役立つ例は何ですか？

はい、私は thesequestions を見てきましたが、それらは準同型を直接カバーせず、参照として役立つ可能性がある resources のみを指します、しかし、学習教材としてではありません。

haskellrecursionfunctional-programminghigher-order-functions
94
Matt Fenwick

はい、それはparaです。カタモルフィズムと比較するか、foldr：

para  :: (a -> [a] -> b -> b) -> b -> [a] -> b
foldr :: (a ->        b -> b) -> b -> [a] -> b

para  c n (x : xs) = c x xs (para c n xs)
foldr c n (x : xs) = c x    (foldr c n xs)
para  c n []       = n
foldr c n []       = n

準同型（foldr）が「反復」であるのとは対照的に、準同型を「原始再帰」と呼ぶ人もいます。

foldrの2つのパラメーターには、入力データの再帰サブオブジェクトごとに再帰的に計算された値が与えられます（ここでは、リストの末尾です）。paraのパラメーターは、元のサブオブジェクトと計算された値の両方を取得しますそれから再帰的に。

paraで適切に表現される関数の例は、リストの適切なサフィックスのコレクションです。

suff :: [x] -> [[x]]
suff = para (\ x xs suffxs -> xs : suffxs) []

そのため

suff "suffix" = ["uffix", "ffix", "fix", "ix", "x", ""]

おそらくもっと簡単です

safeTail :: [x] -> Maybe [x]
safeTail = para (\ _ xs _ -> Just xs) Nothing

「cons」ブランチは、再帰的に計算された引数を無視し、末尾を返します。遅延評価では、再帰的な計算は行われず、テールは一定の時間で抽出されます。

foldrはparaを使用して非常に簡単に定義できます。 paraからfoldrを定義するのは少しトリッキーですが、それは確かに可能であり、誰でもそれがどのように行われるかを知っているはずです！

foldr c n =       para  (\ x  xs  t ->           c x    t)       n
para  c n = snd . foldr (\ x (xs, t) -> (x : xs, c x xs t)) ([], n)

paraをfoldrで定義するコツは、元のデータのcopyを再構築して、アクセスできるようにすることですオリジナルにアクセスできなかったとしても、各ステップでテールのコピーに。最後に、sndは入力のコピーを破棄し、出力値のみを提供します。あまり効率的ではありませんが、純粋な表現力に興味がある場合は、paraはfoldrにすぎません。このfoldrでエンコードされたバージョンのparaを使用すると、結局safeTailには線形の時間がかかり、末尾の要素が要素ごとにコピーされます。

つまり、それだけです：paraはfoldrのより便利なバージョンで、リストの末尾と、そこから計算された値にすぐにアクセスできます。

一般的なケースでは、ファンクターの再帰的な固定点として生成されたデータ型を操作する

data Fix f = In (f (Fix f))

あなたが持っている

cata :: Functor f => (f         t  -> t) -> Fix f -> t
para :: Functor f => (f (Fix f, t) -> t) -> Fix f -> t

cata phi (In ff) = phi (fmap (cata phi) ff)
para psi (In ff) = psi (fmap keepCopy   ff) where
  keepCopy x = (x, para psi x)

繰り返しになりますが、2つは相互に定義可能であり、paraはcataから同じ「コピーを作成する」トリックによって定義されます

para psi = snd . cata (\ fxt -> (In (fmap fst fxt), psi fxt))

繰り返しますが、paraはcataと同じように表現力がありますが、入力のサブ構造に簡単にアクセスする必要がある場合はより便利です。

編集：別のいい例を思い出しました。

Fix TreeFによって与えられる二分探索木を考えます。

data TreeF sub = Leaf | Node sub Integer sub

そして、バイナリ検索ツリーの挿入を最初にcataとして定義し、次にparaとして定義してみてください。 paraバージョンの方がはるかに簡単です。各ノードでは、1つのサブツリーに挿入する必要がありますが、もう1つのサブツリーはそのままにします。

109
pigworker