web-dev-qa-db-ja.com

Haskellのパターンマッチング文字列プレフィックス

文字「Z」で始まる文字列に一致する関数の特別なケースを作成するとします。次のようなことを行うことで、パターンマッチングを使用して簡単にそれを行うことができます。

myfunc ('Z' : restOfString) = -- do something special
myfunc s = -- do the default case here

しかし、より長いプレフィックスを持つ文字列を照合したい場合はどうなりますか? 「トースター」という単語で始まる文字列に特別なケースが必要だとします。そのような文字列に一致するパターンを書くための最良の方法は何ですか?

24
Nick
myfunc ('t':'o':'a':'s':'t':'e':'r' : restOfString) = ...

通常のパターンマッチを使用しても機能しますが、プレフィックス文字列が長くなると面倒になります。

{-# LANGUAGE PatternGuards #-}
import Data.List
myFunc string | Just restOfString <- stripPrefix "toaster" string =
    -- do something special
myFunc string = -- do the default case here

パターンマッチの代わりにライブラリ関数を使用すると、読み取りと書き込みが少し簡単になります。

{-# LANGUAGE ViewPatterns #-}
import Data.List
myFunc (stripPrefix "toaster" -> Just restOfString) = -- do something special
myFunc string = -- do the default case here

GHC 6.10構文拡張により、この使用法はさらに自然になります。


もちろん、後者の2つは完全に同等であり、砂糖をまったく使用せずに(乱雑に)実行できます。

import Data.List
myFunc string =
    if restIsJust
      then -- do something special
      else -- do the default case here
  where
    (restIsJust, restOfString) =
        case stripPrefix "toaster" string of
            Just something -> (True, something)
            Nothing -> (False, undefined)

ただし、これらの構文拡張は、私たちの生活を楽にすることを目的としています。

35
ephemient
import Data.List

myFunc str | "toaster" `isPrefixOf` str = something restOfString
           | otherwise = somethingElse
    where Just restOfString = stripPrefix "toaster" str
8
newacct

分割ライブラリ http://hackage.haskell.org/packages/archive/split/0.1.1/doc/html/Data-List-Split.html 文字列を文字列で分割するための多くの関数があります、プレフィックスマッチングを含む。あなたはそこで何か役に立つものを見つけるかもしれません。

5
Don Stewart
myFunc str =
  case stripPrefix "toaster" str of
     Just restOfString -> something restOfString
     Nothing -> somethingElse

これが、stripPrefixがMaybe型を返す理由です。

3
PO8
myfunc ('t' : 'o' : 'a' : 's' : 't' : 'e' : 'r' : restOfString)

私の知る限り、それ以上の簡潔な構文はありません。

もちろん、文字列がガード句のトースターで始まるのか、関数本体内のifで始まるのかを確認することもできます。

3
sepp2k