web-dev-qa-db-ja.com

バッチファイル：（現時点では予期していなかった

このエラーが発生しています：

（この時点では予想外でした

エラーは、aの値を受け入れた後に発生します。このような問題を引き起こす可能性のあるヌル値を確認しましたが、失敗しました。

echo off
cls
title ~USB Wizard~
echo What do you want to do?
echo 1.Enable/Disable USB Storage Devices.
echo 2.Enable/Disable Writing Data onto USB Storage.
echo 3.~Yet to come~.

set "a=%globalparam1%"
goto :aCheck
:aPrompt
set /p "a=Enter Choice: "
:aCheck
if "%a%"=="" goto :aPrompt
echo %a%

IF %a%==2 (
title USB WRITE LOCK
echo What do you want to do?
echo 1.Apply USB Write Protection
echo 2.Remove USB Write Protection
::param1
set "param1=%globalparam2%"
goto :param1Check
:param1Prompt
set /p "param1=Enter Choice: "
:param1Check
if "%param1%"=="" goto :param1Prompt

if %param1%==1 (
REG ADD HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\StorageDevicePolicies\ /v WriteProtect /t REG_DWORD /d 00000001 
echo USB Write is Locked!
)
if %param1%==2 (
REG ADD HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\StorageDevicePolicies\ /v WriteProtect /t REG_DWORD /d 00000000
echo USB Write is Unlocked! 
)
)
pause
if-statementbatch-filecmd
12
user2540289

param1ステートメントが評価される場合、遅延展開のないスコープ変数であるため、paramは常にnullです。

括弧を使用すると、それらの括弧内のすべてのコマンドと変数が展開されます。そして、その時点では、param1にはifステートメントを無効にする値がありません。遅延展開を使用する場合、変数はコマンドが実際に呼び出されたときにのみ展開されます。

また、if not definedコマンドは、変数が設定されているかどうかを判別します。

@echo off
setlocal EnableExtensions EnableDelayedExpansion
cls
title ~USB Wizard~
echo What do you want to do?
echo 1.Enable/Disable USB Storage Devices.
echo 2.Enable/Disable Writing Data onto USB Storage.
echo 3.~Yet to come~.

set "a=%globalparam1%"
goto :aCheck
:aPrompt
set /p "a=Enter Choice: "
:aCheck
if not defined a goto :aPrompt
echo %a%

IF "%a%"=="2" (
    title USB WRITE LOCK
    echo What do you want to do?
    echo 1.Apply USB Write Protection
    echo 2.Remove USB Write Protection

    ::param1
    set "param1=%globalparam2%"
    goto :param1Check
    :param1Prompt
    set /p "param1=Enter Choice: "
    :param1Check
    if not defined param1 goto :param1Prompt
    echo !param1!

    if "!param1!"=="1" (
        REG ADD HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\StorageDevicePolicies\ /v WriteProtect /t REG_DWORD /d 00000001 
        echo USB Write is Locked!
    )
    if "!param1!"=="2" (
        REG ADD HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\StorageDevicePolicies\ /v WriteProtect /t REG_DWORD /d 00000000
        echo USB Write is Unlocked! 
    )
)
pause
endlocal
25
David Ruhmann

まあ。いくつかの小さな問題...

他の人が指摘したように、空/スペースを含むエントリから保護するために引用し、！delayed_expansion！施設。

留意すべきその他の2つの事項：

最初、 set/pは、ユーザー入力値を変数に割り当てます。これはニュースではありませんが、enterを押すと変数がUNCHANGEDのままになります-変​​数に長さゼロの文字列が割り当てられません（したがって、環境から変数を削除します）。 ：

 set "var="
 set /p var=

もちろん、enterを使用して既存の値を繰り返したくない場合です。
別の便利な形式は

 set "var=default"
 set /p var=

または

 set "var=default"
 set /p "var=[%var%]"

（デフォルト値でプロンプトが表示されます; !var! delayedexpansionを使用したブロックステートメントの場合）

2番目の問題は、一部のWindowsバージョンでは（W7はこの問題を「修正」するように見えますが）ラベル-:: comment（これは壊れたラベルです）すべての「ブロック」を終了します-つまり、括弧で囲まれた複合ステートメント）

9
Magoo

3つのifステートメントすべてに二重引用符が必要です。例：

IF "%a%"=="2" (

@echo OFF &SETLOCAL ENABLEDELAYEDEXPANSION
cls
title ~USB Wizard~
echo What do you want to do?
echo 1.Enable/Disable USB Storage Devices.
echo 2.Enable/Disable Writing Data onto USB Storage.
echo 3.~Yet to come~.


set "a=%globalparam1%"
goto :aCheck
:aPrompt
set /p "a=Enter Choice: "
:aCheck
if "%a%"=="" goto :aPrompt
echo %a%

IF "%a%"=="2" (
    title USB WRITE LOCK
    echo What do you want to do?
    echo 1.Apply USB Write Protection
    echo 2.Remove USB Write Protection
    ::param1
    set "param1=%globalparam2%"
    goto :param1Check
    :param1Prompt
    set /p "param1=Enter Choice: "
    :param1Check
    if "!param1!"=="" goto :param1Prompt

    if "!param1!"=="1" (
         REG ADD HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\StorageDevicePolicies\ /v WriteProtect /t REG_DWORD /d 00000001
         USB Write is Locked!
    )
    if "!param1!"=="2" (
         REG ADD HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\StorageDevicePolicies\ /v WriteProtect /t REG_DWORD /d 00000000
         USB Write is Unlocked!
    )
)
pause
4
Endoro