web-dev-qa-db-ja.com

Prologでファイルを1行ずつ読む

プレーンテキストファイルを読み、各行に述語を適用したいと思います（述語には出力を行うwriteが含まれています）。どうすればいいですか？

ioprologswi-prologdcg
18
Igor Marvinsky

SWI-Prologでは、最もクリーンな解決策は、「行」が何であるかを説明するDCGを記述してから、各行の述語を呼び出すことです。 library（pio）を使用して、DCGをファイルに適用します。

[〜＃〜] edit [〜＃〜]：要求に応じて、次のことを検討してください。

_:- use_module(library(pio)).

lines([])           --> call(eos), !.
lines([Line|Lines]) --> line(Line), lines(Lines).

eos([], []).

line([])     --> ( "\n" ; call(eos) ), !.
line([L|Ls]) --> [L], line(Ls).
_

使用例：?- phrase_from_file(lines(Ls), 'your_file.txt').

14
mat

readを使用してストリームを読み取ることができます。構文エラーがないことを確認するために、at_end_of_streamを呼び出すことを忘れないでください。

例：

readFile.pl

main :-
    open('myFile.txt', read, Str),
    read_file(Str,Lines),
    close(Str),
    write(Lines), nl.

read_file(Stream,[]) :-
    at_end_of_stream(Stream).

read_file(Stream,[X|L]) :-
    \+ at_end_of_stream(Stream),
    read(Stream,X),
    read_file(Stream,L).

myFile.txt

'line 0'.
'line 1'.
'line 2'.
'line 3'.
'line 4'.
'line 5'.
'line 6'.
'line 7'.
'line 8'.
'line 9'.

したがって、mainを呼び出すことにより、出力を受け取ります。

?- main.
[line 0,line 1,line 2,line 3,line 4,line 5,line 6,line 7,line 8,line 9]
true

mainを設定するだけです。ここでの出力は、もちろんwriteを使用した例です。リクエストに一致するように構成します。

この原則はあなたの質問に答えるために適用できると思います。幸運を。

21
Ishq

ファイルから未解釈のプレーンテキスト行を取得するために、パフォーマンスソリューションでは、より多くの可能性とより合理的なものがあります。

SWI-プロローグ：

read_line(S, X) :- 
   read_line_to_codes(S, L), 
   read_line2(L, X).

read_line2(end_of_file, _) :- !, fail.
read_line2(L, X) :-
   atom_codes(X, L).

Jekejekeプロローグ：

:- use_module(library(stream/console)).

655行のファイルを読み取るタイミングは次のとおりです。

test :-
   open('<path>', read, Stream),
   test(Stream),
   close(Stream).

test(Stream) :-
   read_line(Stream, _), !,
   test(Stream).
test(_).

SWI-プロローグ：

̀?- time((between(1,100,_), test, fail; true)).
% 328,300 inferences, 0.125 CPU in 0.143 seconds (88% CPU, 2626400 Lips)
true.

Jekejekeプロローグ：

?- time((between(1,100,_), test, fail; true)).
% Up 121 ms, GC 2 ms, Thread Cpu 94 ms (Current 05/07/19 17:19:05)
Yes

atom）ではなく文字列を読み取るSWI-Prologソリューションの方が速いと思いますが、上記ではatomとatom読み取り。

0
Mostowski Collapse