web-dev-qa-db-ja.com

Windowsでqemuを使用して仮想Linuxを実行する

WindowsでQemu 1.3を使用して、Windows 7のUSBスティックでlubuntuを実行しようとしています。USBスティックにQemuをダウンロードして解凍した後、qemu.io.exeをクリックすると、

qemu-io.exe>

ダウンロードしたLinuxの.isoファイルを起動するにはどうすればよいですか？基本的に聞こえますが、QemuのWebサイトからはわかりません。

linuxvirtualizationqemu
15
user61629

Qemuマニュアル から始めるのが良いでしょう。これは、次に何をすべきかを理解するのに役立ちます。これは、qemuに何をすべきか、そして正確にそれを行う方法を指示することです。

3
Xyon

管理者グループのメンバーではなく（非管理者）、Windows 7 Enterprise、64ビットでCentOS 7の最小バージョンを実行する方法を次に示します。

基本的な考え方は次のとおりです。

  1. Qemu for windowsをダウンロードして、どこにでも解凍します
  2. 実行するLinuxディストリビューションのISOイメージをダウンロードします。
  3. 仮想マシンのハードディスクになるファイルを作成します
  4. Qemuを実行し、CDイメージから起動します。
  5. OSをインストールする
  6. 今度はCDイメージなしで仮想マシンを再起動します。

ネットワーキングと豪華なグラフィックスを正しく理解するのは困難です。まだ苦労しています...

1。 QEMUをダウンロード

QEMUリンクページにあるプリコンパイル済みバイナリ を使用します。私は これにはバージョン2.8. を使用しました。

このバージョンを非管理者として「インストールするには」、コマンドプロンプトを開き、コマンドset __COMPAT_LAYER=RunAsInvokerを発行して、そのプロンプトからqemu-w64-setup-20170131.exeを実行します。 「マイドキュメント」など、書き込み権限のあるフォルダにインストールします。

2。 LinuxのISOイメージをダウンロードする

もう一度、あなた自身を助けてください。 CentOS 7の最小ディストリビューション を使用しました。ファイルの名前はCentOS-7-x86_64-Minimal-1611.isoです。

3。仮想ハードディスクを作成します

これにはバッチファイルを使用しました。以下をcreatevm.batという名前のファイルにコピーし、環境に合わせて変数を調整します。

@echo off
rem ==================================
rem Replace with your values
rem ==================================
set "QEMUDIR=%USERPROFILE%\Documents\Warez\qemu-2.8.0-win64"

rem ==================================
rem Safety net
rem ==================================
if not exist hda.img (
    rem CREATE a virtual hard disk 
    %QEMUDIR%\qemu-img.exe create hda.img 40G
) else (
    echo file hda.img already exist. Delete or move and try again.
    goto:eof
)

4。 QEMUを実行し、仮想CDから起動します

頻繁に使用する可能性があるため、これにはバッチを使用してください。以下をinstallvm.batにコピーします。

@echo off

rem ==================================
rem Replace with your values
rem ==================================
set "QEMUDIR=%USERPROFILE%\Documents\Warez\qemu-2.8.0-win64"
set "ISOFILE=CentOS-7-x86_64-Minimal-1611.iso"

rem ==================================
rem You can add a w suffix to this if 
rem you don't want a console
rem ==================================
set "QEMUBIN=qemu-system-x86_64.exe"

rem ==================================
rem Run the virtual machine
rem ==================================
start "QEMU" %QEMUDIR%\%QEMUBIN% -drive file=hda.img,index=0,media=disk,format=raw -cdrom %ISOFILE% -m 2G -L Bios -usbdevice mouse -usbdevice keyboard -boot menu=on -rtc base=localtime,clock=Host -parallel none -serial none -name centos -no-acpi -no-hpet -no-reboot

5。 OSをインストールします

GUIインストーラーで問題が発生しました。 CentOSのインストールを求められたら、 TAB キーを押して、その行の終わりのWord quietをWord textに置き換えます。

画面のインストール手順に従います。インストールが完了すると、仮想マシンが終了します。特に管理者以外のユーザーとして実行している場合は、かなり時間がかかることがあります。

6。 QEMUでLinuxイメージを実行します

このステップは、必要なときにVMを実行するために何度も何度も行うことです。次のコードをrunvm.batにコピーします。

@echo off

rem ==================================
rem Replace with your values
rem ==================================
set "QEMUDIR=%USERPROFILE%\Documents\Warez\qemu-2.8.0-win64"

rem ==================================
rem You can add a w suffix to this if 
rem you don't want a console
rem ==================================
set "QEMUBIN=qemu-system-x86_64.exe"

rem ==================================
rem Run the virtual machine
rem ==================================
start "QEMU" %QEMUDIR%\%QEMUBIN% -drive file=hda.img,index=0,media=disk,format=raw -m 2G -L Bios -usbdevice mouse -usbdevice keyboard -boot menu=on -rtc base=localtime,clock=Host -parallel none -serial none -name centos -no-acpi -no-hpet -no-reboot -device e1000,netdev=user.0 -netdev user,id=user.0,hostfwd=tcp::2222-:22

ローカルポートフォワードを追加しました。ssh/ PuTTYをlocalhost：2222に追加すると、VMのSSHデーモンに到達します。 Linuxのインストール方法に応じて、firewalldまたはiptablesmightがトラフィックをブロックすることに注意してください。

21
ixe013