web-dev-qa-db-ja.com

複数のWordファイルを検索して置換するにはどうすればよいですか？

多くのWord（.doc）ファイルで検索と置換を行う方法を探しています（プロセスの自動化を目的としています）。

これまでに見つけたソフトウェアでは、検索のみが可能で、置き換えはできません。

Wordでそれを行うにはどうすればよいですか？

microsoft-wordfind-and-replace
10
Tal Galili

VBA Find＆Replace （キャッシュリンク）を試すことができます。

VBA Find andReplace©は、単一のユーザー定義の「find」と「replace」変数のペア、またはユーザー定義の「find」と「replace」のリストを使用して、ドキュメント（またはドキュメントのコレクション）内の任意の場所でテキストを検索および置換する方法を提供しますペア。また、テキストを検索し、見つかったテキストをユーザー定義の「定型句」または「ビルディングブロック」エントリに置き換える方法も提供します。

7
Jay Wick

指定されたルートフォルダーの下の複数のフォルダーにある複数のMSWordファイルで複数の通常およびワイルドカードベースの置換を実行する目的で、次のVBAマクロを作成しました。これを使用するには、次の変数（定数）の内容を変更します。

  • rootPath：Word文書を含むフォルダーが置かれているルートフォルダー。
  • findTextsWildおよびreplaceTextsWild：ワイルドカードベースの検索および置換式の配列。
  • findTextsおよびreplaceTexts：通常の検索および置換式の配列。

あなたはそれが便利だと思うかもしれません:-)

Sub GlobalTextReplacement()
' Root under which all manuals are stored
Dim rootPath As String
rootPath = "c:\Data\Manuals\"

' Find and replace text for wildcard replacement. Performed first.
Dim findTextsWild() As Variant, replaceTextsWild() As Variant
findTextsWild = Array("[ ]{2;}", "[cC]onfiguration[/ ]@[pP]olicy [rR]epository", "[sS]ervlet[- ]@[fF]ilter")
replaceTextsWild = Array(" ", "Configuration/Policy Repository", "Servlet-Filter")

' Find and replace text for normal case insensitive replacement. Performed second.
Dim findTexts() As Variant, replaceTexts() As Variant
findTexts = Array("DirX Access", "Policy Repository", "User Repository", "Servlet", "servletfilter", "SAML assertion", "DirX Access Server", "DirX Access Manager", "Deployment Manager", "Policy Manager", "Client SDK", "^p ", " ^p")
replaceTexts = Array("DirX Access", "Policy Repository", "User Repository", "Servlet", "Servlet-Filter", "SAML assertion", "DirX Access Server", "DirX Access Manager", "Deployment Manager", "Policy Manager", "Client SDK", "^p", "^p")

' Main code
Application.ScreenUpdating = False

Dim dirNames(20) As String
Dim dirNamesCount As Integer
dirNamesCount = 0

Dim dirName As String
dirName = Dir$(rootPath & "*", vbDirectory)
Do Until LenB(dirName) = 0
    Dim dirPath As String
    dirPath = rootPath & dirName
    If ((GetAttr(dirPath) And vbDirectory) = vbDirectory) And (dirName <> ".") And (dirName <> "..") Then
        dirNamesCount = dirNamesCount + 1
        dirNames(dirNamesCount) = dirPath & "\"
    End If
    dirName = Dir$
Loop

Do While dirNamesCount > 0
    Dim fileName As String
    dirName = dirNames(dirNamesCount)
    dirNamesCount = dirNamesCount - 1
    fileName = Dir$(dirName & "*.doc", vbDirectory)
    Do Until LenB(fileName) = 0
        Dim filePath As String
        filePath = dirName & fileName
        fileName = Dir$

        Dim document As document
        Set document = Documents.Open(filePath)
        document.TrackRevisions = True

        document.Select

        Dim i As Integer, maxIndex As Integer
        maxIndex = UBound(findTextsWild)
        For i = LBound(findTextsWild) To maxIndex
            With Selection.Find
                .ClearFormatting
                .Replacement.ClearFormatting
                .Text = findTextsWild(i)
                .Replacement.Text = replaceTextsWild(i)
                .Execute Replace:=wdReplaceAll, Forward:=True, _
                    Wrap:=wdFindContinue, MatchWildcards:=True
            End With
        Next

        maxIndex = UBound(findTexts)
        For i = LBound(findTexts) To maxIndex
            With Selection.Find
                .ClearFormatting
                .Replacement.ClearFormatting
                .Text = findTexts(i)
                .Replacement.Text = replaceTexts(i)
                .Execute Replace:=wdReplaceAll, Forward:=True, _
                    Wrap:=wdFindContinue, MatchCase:=False, MatchWildcards:=False
            End With
        Next

        document.Save
        document.Close
    Loop
Loop

Application.ScreenUpdating = True
End Sub
0
Maxwell