パワーポイント：スライド名を手動で設定

Question

Context：C＃のPowerPointスライドにはSlide.Nameプロパティがあります（通常は任意の文字列値が含まれます）。私のC＃アプリケーションでは、このプロパティを使用してスライドを識別したいと思います（スライドの順序は信頼できません）。

質問：PowerPointアプリケーションでSlide.Nameプロパティを手動で設定するにはどうすればよいですか？

私の問題は次のようなものです：「 PowerPointスライド内のオブジェクトに名前を付ける方法は？ 」が、スライドレベルだけです。

どんな助けでもいただければ幸いです。

Answer 1

スライドの名前を編集できるPowerPointの組み込み機能はありません。スティーブが述べたように、VBAコードを使用してそれを行う必要があります。スライドnameは、スライドを追加しても変更されることはなく、PowerPointを閉じても同じままです。 VBAコードで設定されたスライド名は永続的です。現在選択されているスライドの名前を簡単に表示し、名前を変更できるようにするために作成したコードを次に示します。

'------------------------------------------------------------------
' NameSlide()
'
' Renames the current slide so you can refer to this slide in
' VBA by name. This is not used as part of the application;
' it is for maintenance and for use only by developers of
' the PowerPoint presentation.
'
' 1. In Normal view, click on the slide you wish to rename
' 2. ALT+F11 to VB Editor
' 3. F5 to run this subroutine
'------------------------------------------------------------------
Sub NameSlide()
    Dim curName As String
    curName = Application.ActiveWindow.View.Slide.name

    Dim newName As String
retry:
    newName = InputBox("Enter the new name for slide '" + curName + "', or press Cancel to keep existing name.", "Rename slide")
    If Trim(newName) = "" Then Exit Sub

    Dim s As Slide

    ' check if this slide name already exists
    On Error GoTo SlideNotFound
    Set s = ActivePresentation.Slides(newName)
    On Error GoTo 0

    MsgBox "Slide with this name already exists!"
    GoTo retry

    Exit Sub

SlideNotFound:
    On Error GoTo 0
    Application.ActiveWindow.View.Slide.name = newName
    MsgBox "Slide renamed to '" + newName + "'."

End Sub

Answer 2

スライド名を手動で設定することはできませんが、少しのコードで簡単に設定できます。 VBAでは、たとえば次のようになります。

Sub NameThatSlide()
  ActivePresentation.Slides(1).Name = "Whatever You Like Here"
End Sub

Answer 3

スライドの名前は手動またはVBAで変更できます。方法がわかれば、いくつかの興味深い可能性への扉が開かれます。これを以下のコードで示します。

スライドの名前を手動で変更します。この機能はVBAエディターの[プロパティ]ペインに表示されませんが、コーディングは必要ありません。

1. 開発者リボンが表示されていない場合は、有効にします。ファイル> オプション> リボンのカスタマイズ>チェック開発者メインタブ。

2. Developerリボンから、Visual Basicメニュー項目をクリックして、Visual BasicEditorを開きます。

3. Ctrl + Rキーを押して、プロジェクトエクスプローラーペインに移動します。

4. 展開 "Microsoft PowerPointオブジェクト"

5. スライドをクリックして選択します。

6. F4キーを押して、[プロパティ]ペインに移動します。

7. （Name）アイテムを編集し、Enterを押して名前の変更を適用します。

スライド名の変更は、VBAプロジェクトエクスプローラーペインにすぐには表示されない場合があります。 [プロパティ]ペインで名前が正しい限り、名前は正常に変更されました。

このVBAコードもトリックを実行します（スライド番号1を非表示にします）。

ActivePresentation.Slides(1).SlideShowTransition.Hidden = msoTrue

このコードブロックは、スライド名を管理するいくつかの方法をカバーし、主な質問に答えます。

Option Explicit

Public Function RenameSlide(oldName As String, newName As String)
' RenameSlide finds slide oldName and renames it to newName.
' Arguements:
'   oldName: current (old) name of existing slide
'   newName: new name for slide.
'
    Dim tempBool As Boolean
    Dim sld As Slide
    Dim RetVal(0 To 1) As String

    ' Check if oldName can be found.
    If SlideExists(oldName) Then
        Set sld = Application.ActivePresentation.Slides(oldName)
    Else
        RetVal(0) = 1 'Error 1
        RetVal(1) = "Error 1: slide with name " & oldName & " not found. Aborting."
        Exit Function
    End If

    ' Check if this slide name newName already exists.
    If SlideExists(newName) Then
        RetVal(0) = 2 'Error 1
        RetVal(1) = "Error 2: slide with name " & newName & " already exists. Aborting."
        Exit Function
    End If

    ' Rename the slide
    'Application.ActivePresentation.Slides(oldName) = newName
    Application.ActivePresentation.Slides(oldName).Select
    Application.ActiveWindow.View.Slide.Name = newName 'current slide
    RetVal(0) = 0 'Success
    RetVal(1) = "Success: slide renamed from '" & oldName & "' to '" & newName & "'."

End Function

Public Sub SetSlideName()
' Prompt user for new name for active slide.
'
    Dim oldName As String
    Dim newName As String
    Dim sld As Slide
    Dim msg As String

    ' Get current name of active slide.
    oldName = Application.ActiveWindow.View.Slide.Name

    msg = "Enter the new name for slide '" + oldName + "'."
retry:
    newName = ""
    ' Prompt for new slide name. Loop until a name of at least 1 character is provided.
    Do While newName = ""
        newName = InputBox(msg, "Rename slide")
        newName = Trim(newName)
        If Len(newName) = 0 Then
            msg = "Try again.  You must enter a slide name to continue."
        ElseIf newName = oldName Or newName = Str(vbCancel) Then
            Exit Sub
        End If
    Loop

    ' If an existing slide already has name newName, then
    ' go back and Prompt user again.slide name already exists
    If SlideExists(newName) Then
        msg = "Slide with this name already exists!"
        GoTo retry
    End If

    ' Set the new slide name
    Application.ActiveWindow.View.Slide.Name = newName
    MsgBox "Slide renamed to '" + newName + "'."
End Sub

Public Function SlideExists(SlideName As String) As Boolean
    Dim RetVal As Boolean
    Dim sld

    ' Assume slide does not exist.
    SlideExists = False

    ' Try to find slide by name.
    ' If we error out, the slide does NOT exist.
    On Error GoTo NoSlide
    Set sld = ActivePresentation.Slides(SlideName)

    ' If we got this far, the slide DOES exist.
    SlideExists = True
    Exit Function

NoSlide:
    ' Error setting slide objects shows
    ' that slides does NOT exist.
    SlideExists = False
End Function

余談ですが、スライドの名前付けのトリックと小さなVBAを使用して、特定のスライドを印刷から選択的に削除します。マクロリストにデータを入力するために、VBAマクロをいくつか追加しました。任意のスライドから：開発者リボン>マクロ>マクロの選択>実行ボタン。このメソッドを使用して、PresentSlide、DontPresentSlide、PrintSlide、およびDontPrintSlideマクロを開始します。さまざまなスライドに適切なタグを付けたら、提示または印刷する前に、それぞれPrepToPresentSlidesまたはPrepToPrintSlidesマクロを実行します。

これらのマクロを少し試して、コメントを読んでください。私がコードを拡張的に書いたことがわかるので、必要に応じて簡単に変更できます。

以下のコードは、どのスライドとオブジェクトが印刷され、どれが画面に表示されるかを管理するのに役立ちます。これは、参照スライドを印刷したいがカバーしたくない場合に特に便利です。アニメーション付きのスライドがあるとさらに便利です。アニメーションは通常、印刷をうまく翻訳しません。そのため、アニメーションオブジェクトをまったく印刷しないことを選択します。実際、印刷のためだけに使用されるオブジェクトの代わりにコンテンツを追加することもできます（提示時に非表示になります）。ただし、これを行うことはめったにありません。代わりに、私は通常、アニメーションを印刷から非表示にするか、表示するスライドとアニメーション化されていないコピーを作成して印刷します。これらのマクロを使用すると、印刷用のスライドとオブジェクト、およびプレゼンテーション用のスライドとオブジェクトの組み合わせを簡単に管理できます。楽しんでいただければ幸いです。

Option Explicit

' DontPresentSlide - run macro while on a slide you wish to skip while presenting.
'                    The slide name will be appended with "NoPresent". You still
'                    need to run PrepToPresent before presenting to hide slide.
' PresentSlide - "NoPresent" will be removed from the slide. You still
'                need to run PrepToPresent before presenting to hide slide.
' PrepToPesentSlides() - Unhide slides and objects you want presented and
'                hide slides and objects you do NOT want presented.
' ShowNoPressnt() - show slides and shapes marked "NoPresent"
' HideNoPresent() - hide slides and shapes marked "NoPresent"

' DontPrintSlide - run macro while on a slide you wish to skip while presenting.
'                    The slide name will be appended with "NoPrint". You still
'                    need to run PrepToPresent before presenting to hide slide.
' PrintSlide - "NoPrint" will be removed from the slide. You still
'                need to run PrepToPresent before presenting to hide slide.
' PrepToPrintSlides() - Unhide slides and objects you want printed and
'                hide slides and objects you do NOT want printed.
' ShowNoPrint() - show slides and shapes marked "NoPrint"
' HideNoPrint() - hide slides and shapes marked "NoPrint"

' ShowHideSlides() - Hide or Unhide slides based on slide name.
' ShowHideShapes() - Hide or Unhide shapes based on shapes name.


Public Const cjaHide = False
Public Const cjaShow = True
Public Const cjaToggle = 2

Sub ShowHideSlides(NameContains As String _
                , Optional LMR As String = "R" _
                , Optional ShowSlide As Integer = False)
' Show or Hide slides based on slide name.
' Arguements:
'   NameContains (string):
'       slides with this string will be modified.
'   LMR (string): enter L, M or R to indicate
'       searching the Left, Middle or Right of
'       the slide name, respectively.
'   ShowSlide (integer):
'       Show: True (-1)
'       Hide: False (0)
'       Toggle: 2
'
' To show or hide slides manually:
'   Right-click the slide thumbnail, then click Hide Slide
' To rename slides,
'   Use this VBA: ActiveWindow.View.Slide.Name = "NewSlideName"
'   Or, edit the (Name) property in the VBA Properties window.
'
   Dim sldCurrent As Slide
   Dim found As Boolean
   found = False

   LMR = Trim(UCase(LMR))
   If LMR <> "L" And LMR <> "M" Then LMR = "R"
   'Loop through each slide in presentation.
   For Each sldCurrent In ActivePresentation.Slides
        'Match shape name left, right or middle as per LMR arguement.
        'ActiveWindow.View.Slide.Name or Slide.SlideNumber
        found = False
        If LMR = "R" And LCase(right(sldCurrent.Name, Len(NameContains))) = LCase(NameContains) Then
            found = True
        ElseIf LMR = "L" And LCase(left(sldCurrent.Name, Len(NameContains))) = LCase(NameContains) Then
            found = True
        ElseIf LMR = "M" And InStr(1, LCase(NameContains), LCase(sldCurrent.Name)) Then
            found = True
        End If
        'If match found, then set shape visibility per ShowShape arguement.
        If found Then
            If ShowSlide = True Then
                ActivePresentation.Slides(sldCurrent.SlideNumber).SlideShowTransition.Hidden = msoFalse
            ElseIf ShowSlide = False Then
                ActivePresentation.Slides(sldCurrent.SlideNumber).SlideShowTransition.Hidden = msoTrue
            Else
                ActivePresentation.Slides(sldCurrent.SlideNumber).SlideShowTransition.Hidden = Not ActivePresentation.Slides(sldCurrent.SlideNumber).SlideShowTransition.Hidden
            End If
        End If
    Next       'sldCurrent
End Sub

Sub ShowHideShapes(NameContains As String _
                , Optional LMR As String = "R" _
                , Optional ShowShape As Integer = False)
' Show or Hide shapes/objects based on object name.
' Arguements:
'   NameContains (string):
'       shapes with this string will be modified.
'   LMR (string): enter L, M or R to indicate
'       searching the Left, Middle or Right of
'       the slide name, respectively.
'   ShowSlide (integer):
'       Show: True (-1)
'       Hide: False (0)
'       Toggle: 2
'
' To show, hide and/or rename objects:
'    1. Turn on Selection Pane via: Home Ribbon >
'       Select > Selection Pane.
'    2. Double-click a shape name to rename it.
'    3. Click the eye icon to the far right to show/hide a shape.

   Dim shpCurrent As Shape
   Dim sldCurrent As Slide
   Dim found As Boolean
   found = False

   LMR = Trim(UCase(LMR))
   If LMR <> "L" And LMR <> "M" Then LMR = "R"
   'Loop through each slide in presentation.
   For Each sldCurrent In ActivePresentation.Slides
      With sldCurrent
          'Loop through each shape on current slide.
          For Each shpCurrent In .Shapes
            'Match shape name left, right or middle as per LMR arguement.
            found = False
            If LMR = "R" And right(shpCurrent.Name, Len(NameContains)) = NameContains Then
                found = True
            ElseIf LMR = "L" And left(shpCurrent.Name, Len(NameContains)) = NameContains Then
                found = True
            ElseIf LMR = "M" And InStr(1, NameContains, shpCurrent.Name) Then
                found = True
            End If
            'If match found, then set shape visibility per ShowShape arguement.
            If found Then
                If ShowShape = True Then
                    shpCurrent.Visible = True
                ElseIf ShowShape = False Then
                    shpCurrent.Visible = False
                Else
                    shpCurrent.Visible = Not shpCurrent.Visible
                End If
            End If
          Next 'sldCurrent
      End With 'sldCurrent
    Next       'sldCurrent

End Sub

Sub HideNoPrint()
' Hide slides and shapes you do NOT want printed.
'
' Run this macro to hide all slides and shapes that
' end with the string "NoPrint".

' Usage.  Assume you have slides that contain animations that
' make the printed slide difficult or impossible to read.
' Let's further suppose you plan to present certain slides
' but not print them.
'   1. Add the"NoPrint" suffix to any shapes that clutter
'      the printed page.
'   2. Add the "NoPrint" suffix to slides you don't want to
'      print.
'   3. Run this macro to hide shapes and slides.
'   4. Print the slides.
'   5. Optionally, run the ShowNoPrint() macro in preparation
'      for presenting the slides.
    ShowHideShapes "NoPrint", "R", False
    ShowHideSlides "NoPrint", "R", False
End Sub

Sub ShowNoPrint()
' Unhide slides and shapes that were hidden
' to prevent them from being printed in handouts.
'
    ShowHideShapes "NoPrint", "P", True
    ShowHideSlides "NoPrint", "P", True
End Sub

Sub HideNoPressent()
' Hide objects you do NOT want to present on screen.
'
' Run this macro to hide all slides and shapes that
' end with the string "NoPresent".
'
' Usage.  Assume you have slides that contain supporting material
' that you wish to provide as printed handouts but not show.
' You can manually hide those slides and objects of course. I
' prefer to use these macros.
'   1. Add the"NoPresent" suffix to any shapes that you want
'      to print to handouts but not show on-screen.
'   2. Add the "NoPresent" suffix to slides you want to
'      print but not display on screen, such as reference slides.
'   3. Run this macro to hide the "NoPresent" shapes and slides.
'   4. Present your slides.
'   5. Optionally, run the ShowNoPresent() macro in preparation
'      for printing the slides.
'
    ShowHideShapes "NoPressent", "R", False
    ShowHideSlides "NoPressent", "R", False
End Sub

Sub ShowNoPresent()
' Unhide objects that were hidden to prevent them from
' being presented on screen.
'
    ShowHideShapes "NoPressent", "P", True
    ShowHideSlides "NoPressent", "P", True
End Sub

Sub PrepToPrintSlides()
' Unhide objects you want printed and
' hide objects you do NOT want printed.
    ShowNoPresent
    HideNoPrint
End Sub

Sub PrepToPresentSlides()
' Unhide objects you want presented and
' hide objects you do NOT want presented.
    ShowNoPrint
    HideNoPresent
End Sub

Sub DontPresentSlide()
    Dim RetVal, sldName As String
    sldName = Application.ActiveWindow.View.Slide.Name
    If InStr(1, sldName, "NoPresent", vbBinaryCompare) = 0 Then
        RetVal = RenameSlide(sldName, sldName & "-NoPresent")
    End If
    HideNoPresent
End Sub

Sub PresentSlide()
    Dim RetVal, sldName As String, strStart As String, newName As String
    'Remove the NoPresent suffix from the current slide.

    'get slide name
    sldName = Application.ActiveWindow.View.Slide.Name
    'Unhide slide
    ActivePresentation.Slides(sldName).SlideShowTransition.Hidden = msoFalse
    'remove "-NoPresent" from slide name
    Do
        strStart = InStr(1, sldName, "-NoPresent")
        If InStr(1, sldName, "-NoPresent") Then
            newName = left(sldName, strStart - 1) & right(sldName, Len(sldName) - strStart - 9)
            RetVal = RenameSlide(sldName, newName)
        End If
        sldName = Application.ActiveWindow.View.Slide.Name
    Loop Until InStr(1, sldName, "-NoPresent") = 0
    'remove "NoPresent" from slide name
    Do
        strStart = InStr(1, sldName, "NoPresent")
        If InStr(1, sldName, "NoPresent") Then
            newName = left(sldName, strStart - 1) & right(sldName, Len(sldName) - strStart - 8)
            RetVal = RenameSlide(sldName, newName)
        End If
        sldName = Application.ActiveWindow.View.Slide.Name
    Loop Until InStr(1, sldName, "NoPresent") = 0

End Sub

Sub DontPrintSlide()
    Dim RetVal, sldName As String
    sldName = Application.ActiveWindow.View.Slide.Name
    If InStr(1, sldName, "NoPrint", vbBinaryCompare) = 0 Then
        RetVal = RenameSlide(sldName, sldName & "-NoPrint")
    End If
    HideNoPrint
End Sub

Sub PrintSlide()
    Dim RetVal, sldName As String, strStart As String, newName As String
    'Remove the NoPrint suffix from the current slide.

    'get slide name
    sldName = Application.ActiveWindow.View.Slide.Name
    'Unhide slide
    ActivePresentation.Slides(sldName).SlideShowTransition.Hidden = msoFalse
    'remove "-NoPrint" from slide name
    Do
        strStart = InStr(1, sldName, "-NoPrint")
        If InStr(1, sldName, "-NoPrint") Then
            newName = left(sldName, strStart - 1) & right(sldName, Len(sldName) - strStart - 7)
            RetVal = RenameSlide(sldName, newName)
        End If
        sldName = Application.ActiveWindow.View.Slide.Name
    Loop Until InStr(1, sldName, "-NoPrint") = 0
    'remove "NoPrint" from slide name
    Do
        strStart = InStr(1, sldName, "NoPrint")
        If InStr(1, sldName, "NoPrint") Then
            newName = left(sldName, strStart - 1) & right(sldName, Len(sldName) - strStart - 6)
            RetVal = RenameSlide(sldName, newName)
        End If
        sldName = Application.ActiveWindow.View.Slide.Name
    Loop Until InStr(1, sldName, "NoPrint") = 0
End Sub

Sub HideAllCovers()
' Run this macro to hide all Covers.
    ShowHideShapes "Cover", "L", False
End Sub

Sub ShowAllCovers()
' Run this macro to hide all Covers.
    ShowHideShapes "Cover", "L", True
End Sub

Sub HideAllAnswers()
' Run this macro to hide all Covers.
    ShowHideShapes "Answer", "L", False
End Sub

Sub ShowAllAnswers()
' Run this macro to hide all Covers.
    ShowHideShapes "Answer", "L", True
End Sub

Sub HideAllQuestions()
' Run this macro to hide all Covers.
    ShowHideShapes "Question", "L", False
End Sub

Sub ShowAllQuestions()
' Run this macro to hide all Covers.
    ShowHideShapes "Question", "L", True
End Sub

Sub ShowAll()
' Run this macro to hide all shapes (Covers and Answers).
    ShowAllQuestions
    ShowAllAnswers
    ShowAllCovers
    ShowNoPrint
End Sub

Sub HideAll()
' Run this macro to hide all shapes (Covers and Answers).
    HideAllQuestions
    HideAllAnswers
    HideAllCovers
    HideNoPrint
End Sub

Answer 4

私はVBAプログラマーではないため、これでSlide.Nameプロパティを設定できるかどうかはわかりませんが、PowerPoint 2010でスライドに名前を付ける最も簡単な方法は、アウトラインビューを使用することです。

作成したスライド上でマウスを左端に置くと、一種の垂直スライドソーターを右方向にドラッグできます。そのペインの上部に、スライドとアウトラインの2つのタブが表示されます。

アウトラインを選択すると、各スライドに番号が付けられ、スライドを並べ替えることができる灰色のグラブボタンが表示されます。その右側をクリックすると、「ホーム」など、好きな名前を入力できます。

メインビューペインで、スライドにHomeが刺繍されます。次に、そのままにしておくか、フォントの色を背景に変更するか、テキストをプレゼンテーションフレームの外に移動して非表示にします。

ところで、これらの名前はハイパーリンクで使用できます。

Answer 5

sub SplitFile（）関数を使用して、100を超えるスライドのデッキから個々のスライドを作成しました。すべてうまくいきました！しかし、各スライドのテキストボックスにタイトルがあると仮定して、ファイルの名前を自動的に変更するために使用するコードを誰かに教えてもらえますか？スライドのタイトルを、作成した新しい個別のスライドのファイル名にします。

オンラインで投稿した人のおかげで、個々のスライドを（個々のファイルとして）作成するために使用したコードは次のとおりです。

Sub SplitFile（）Dim lSlidesPerFile As Long Dim lTotalSlides As Long Dim oSourcePres As Presentation Dim otargetPres As Presentation Dim sFolder As String Dim sExt As String Dim sBaseName As String Dim lCounter As Long Dim lPresentationsCount As Long'Dimxに分割する数As Long Dim lWindowStart As Long Dim lWindowEnd As Long Dim sSplitPresName As String

On Error GoTo ErrorHandler

Set oSourcePres = ActivePresentation
If Not oSourcePres.Saved Then
    MsgBox "Please save your presentation then try again"
    Exit Sub
End If

lSlidesPerFile = CLng(InputBox("How many slides per file?", "Split Presentation"))
lTotalSlides = oSourcePres.Slides.Count
sFolder = ActivePresentation.Path & "\"
sExt = Mid$(ActivePresentation.Name, InStr(ActivePresentation.Name, ".") + 1)
sBaseName = Mid$(ActivePresentation.Name, 1, InStr(ActivePresentation.Name, ".") - 1)

If (lTotalSlides / lSlidesPerFile) - (lTotalSlides \ lSlidesPerFile) > 0 Then
    lPresentationsCount = lTotalSlides \ lSlidesPerFile + 1
Else
    lPresentationsCount = lTotalSlides \ lSlidesPerFile
End If

If Not lTotalSlides > lSlidesPerFile Then
    MsgBox "There are fewer than " & CStr(lSlidesPerFile) & " slides in this presentation."
    Exit Sub
End If

For lCounter = 1 To lPresentationsCount

    ' which slides will we leave in the presentation?
    lWindowEnd = lSlidesPerFile * lCounter
    If lWindowEnd > oSourcePres.Slides.Count Then
        ' odd number of leftover slides in last presentation
        lWindowEnd = oSourcePres.Slides.Count
        lWindowStart = ((oSourcePres.Slides.Count \ lSlidesPerFile) * lSlidesPerFile) + 1
    Else
        lWindowStart = lWindowEnd - lSlidesPerFile + 1
    End If

    ' Make a copy of the presentation and open it

    For Each oSlide In ActiveWindow.Presentation.Slides
strTitles = strTitles _
    & "Slide: " _
    & CStr(oSlide.SlideIndex) & vbCrLf _
    & oSlide.Shapes.Title.TextFrame.TextRange.Text _
    & vbCrLf & vbCrLf

次のoSlideOn Error GoTo ErrorHandler

intFileNum = FreeFile

sSplitPresName = sFolder＆sBaseName＆_ "_"＆CStr（lWindowStart）＆ "-"＆CStr（lWindowEnd）＆ "。" ＆sExt oSourcePres.SaveCopyAs sSplitPresName、ppSaveAsDefault Set otargetPres = Presentations.Open（sSplitPresName 、、、 True）

    With otargetPres
        For x = .Slides.Count To lWindowEnd + 1 Step -1
            .Slides(x).Delete
        Next
        For x = lWindowStart - 1 To 1 Step -1
            .Slides(x).Delete
        Next
        .Save
        .Close
    End With

Next    ' lpresentationscount

NormalExit：Exit Sub ErrorHandler：MsgBox "エラーが発生しました"再開NormalExitEnd Sub

Answer 6

「ファイル->オプション->リボンのカスタマイズ」で「開発者」タブを有効にします（詳細： https://www.addintools.com/documents/PowerPoint/where-is-developer-tab.html ）

[開発者]タブで、次の手順に従って、下の画像を参照してください（ポルトガル語で申し訳ありません）

• 開発者タブに入る
• ターゲットスライドを選択します
• スライドにアクティブXコントロール（ボタン、テキストボックスなど）がない場合は、[開発者]タブからダミーボタンを追加します。
• スライドでこのボタンを選択し、開発者タブで「プロパティ」をクリックします
• プロパティウィンドウの上部には、ボタンの代わりにスライドを選択できるコンボボックスがあります
• スライドを選択して、名前などのプログラミングプロパティを確認します