web-dev-qa-db-ja.com

レイキャスティングアルゴリズムを使用したボリュームレンダリング（glslを使用）

レイキャスティングアルゴリズムを使用してボリュームレンダリングを学習しています。 here で良いデモとtuturialを見つけました。しかし、問題は、nVidiaの代わりにATIグラフィックカードを使用しているため、デモでcgシェーダーを使用できないため、cgシェーダーをglslシェーダーに変更したいということです。 OpenGLのレッドブック（7版）を読みましたが、glslとcgに精通していません。デモのcgシェーダーをglslに変更するのを手伝ってくれる人はいますか？または、レイキャスティングを使用したボリュームレンダリングの最も単純なデモの資料はありますか（もちろんglslで）。 ここ はデモのcgシェーダーです。そしてそれは私の友人のnVidiaグラフィックカードで動作することができます。私が最も混乱しているのは、cgのエントリ部分をglslに変換する方法がわからないことです。例：

_struct vertex_fragment
 {
   float4 Position    : POSITION; // For the rasterizer
   float4 TexCoord    : TEXCOORD0; 
   float4 Color       : TEXCOORD1;
   float4 Pos         : TEXCOORD2;
 };
_

さらに、たとえば、画面を描画するときに2つのtexcoordを割り当てると、2つのテクスチャユニットを持つ2つのテクスチャオブジェクトをシェーダーにバインドするプログラムを作成できます。

glMultiTexCoord2f(GL_TEXTURE0, 1.0, 0.0);

glMultiTexCoord2f(GL_TEXTURE1, 1.0, 0.0);

デモでは、プログラムは2つのテクスチャ（_backface_buffer_の場合は2D、_volume texture_の場合は3D）にバインドしますが、glMultiTexCoord3f(GL_TEXTURE1, x, y, z);のようなテクスチャユニットは1つだけです_GL_TEXTURE1_単位はボリュームテクスチャ用ですが、どれ（テクスチャ単位）が_backface_buffer_用ですか？シェーダーでtextureobjをバインドするために私が知る限り、たとえば、バインドするテクスチャユニットを取得する必要があります。

_glLinkProgram(p);   
texloc = glGetUniformLocation(p, "tex");
volume_texloc = glGetUniformLocation(p, "volume_tex");
stepsizeloc = glGetUniformLocation(p, "stepsize");
glUseProgram(p);
glUniform1i(texloc, 0); 
glUniform1i(volume_texloc, 1); 
glUniform1f(stepsizeloc, stepsize);
  //When rendering an object with this program.
glActiveTexture(GL_TEXTURE0);
glBindTexture(GL_TEXTURE_2D, backface_buffer);
glActiveTexture(GL_TEXTURE1);
glBindTexture(GL_TEXTURE_3D, volume_texture);
_

プログラムは正常にコンパイルされ、リンクされています。しかし、3つの場所（texloc、volume_texloc、stepsizeloc）すべてのうち-1しか取得できませんでした。私はそれが最適化されるかもしれないことを知っています。誰かが私がcgシェーダーをglslシェーダーに変換するのを手伝ってくれる？

編集：glslを使用した最新のOpenGL API実装（C++ソースコード）に興味がある場合： Volume_Rendering_Using_GLSL

openglglsldemoraycastingvolume-rendering
18
toolchainX

問題が解決しました。 glslバージョン の デモ ：

頂点シェーダー

_void main()
{
    gl_Position = gl_ModelViewProjectionMatrix*gl_Vertex;
    //gl_FrontColor = gl_Color;
    gl_TexCoord[2] = gl_Position;
    gl_TexCoord[0] = gl_MultiTexCoord1;
    gl_TexCoord[1] = gl_Color;
}
_

フラグメントシェーダー

_uniform sampler2D tex;
uniform sampler3D volume_tex;
uniform float stepsize;

void main()
{
    vec2 texc = ((gl_TexCoord[2].xy/gl_TexCoord[2].w) + 1) / 2;
    vec4 start = gl_TexCoord[0];
    vec4 back_position = texture2D(tex, texc);
    vec3 dir = vec3(0.0);
    dir.x = back_position.x - start.x;
    dir.y = back_position.y - start.y;
    dir.z = back_position.z - start.z;
    float len = length(dir.xyz); // the length from front to back is calculated and used to terminate the ray
    vec3 norm_dir = normalize(dir);
    float delta = stepsize;
    vec3 delta_dir = norm_dir * delta;
    float delta_dir_len = length(delta_dir);
    vec3 vect = start.xyz;
    vec4 col_acc = vec4(0,0,0,0); // The dest color
    float alpha_acc = 0.0;                // The  dest alpha for blending
    float length_acc = 0.0;
    vec4 color_sample; // The src color 
    float alpha_sample; // The src alpha

    for(int i = 0; i < 450; i++)
    {
      color_sample = texture3D(volume_tex,vect);
      //  why multiply the stepsize?
      alpha_sample = color_sample.a*stepsize;
      // why multply 3?
      col_acc   += (1.0 - alpha_acc) * color_sample * alpha_sample*3 ;
      alpha_acc += alpha_sample;
      vect += delta_dir;
      length_acc += delta_dir_len;
      if(length_acc >= len || alpha_acc > 1.0) 
        break; // terminate if opacity > 1 or the ray is outside the volume
    }

    gl_FragColor =  col_acc;
}
_

cgの元の シェーダー を見た場合、cgとglslの違いはわずかです。デモをglslバージョンに変換するのに最も難しい部分は、次のようなopenglのcg関数です。

_param = cgGetNamedParameter(program, par); 
cgGLSetTextureParameter(param, tex); 
cgGLEnableTextureParameter(param);
_

テクスチャユニットとマルチテクスチャのアクティブ化（glActiveTextureを使用）と非アクティブ化のプロセスをカプセル化します。これは、固定パイプラインとプログラム可能なパイプラインを使用しているため、このデモでは非常に重要です。 Peter TriersGPUレイキャスティングチュートリアルのデモのmain.cppの関数void raycasting_pass()で変更されたキーセグメントは次のとおりです。

function raycasting_pass

_void raycasting_pass()
{
    // specify which texture to bind
    glFramebufferTexture2DEXT(GL_FRAMEBUFFER_EXT, GL_COLOR_ATTACHMENT0_EXT, 
        GL_TEXTURE_2D, final_image, 0);
    glClear(GL_COLOR_BUFFER_BIT | GL_DEPTH_BUFFER_BIT );
    glUseProgram(p);
    glUniform1f(stepsizeIndex, stepsize);
    glActiveTexture(GL_TEXTURE1);
    glEnable(GL_TEXTURE_3D);
    glBindTexture(GL_TEXTURE_3D, volume_texture);
    glUniform1i(volume_tex, 1); 
    glActiveTexture(GL_TEXTURE0);
    glEnable(GL_TEXTURE_2D);
    glBindTexture(GL_TEXTURE_2D, backface_buffer);
    glUniform1i(tex, 0); 

    glUseProgram(p);
    glEnable(GL_CULL_FACE);
    glCullFace(GL_BACK);
    drawQuads(1.0,1.0, 1.0);  // Draw a cube
    glDisable(GL_CULL_FACE);
    glUseProgram(0);
    // recover to use only one texture unit as for the fixed pipeline
    glActiveTexture(GL_TEXTURE1);
    glDisable(GL_TEXTURE_3D);
    glActiveTexture(GL_TEXTURE0);
}
_

それでおしまい。

15
toolchainX