web-dev-qa-db-ja.com

すべてのユーザーテーブルを削除する方法

Oracleのすべてのユーザーテーブルを削除するにはどうすればよいですか？

制約に問題があります。すべて無効にしても、それは不可能です。

oracleconstraintssql-drop
151
szaman
BEGIN
   FOR cur_rec IN (SELECT object_name, object_type
                     FROM user_objects
                    WHERE object_type IN
                             ('TABLE',
                              'VIEW',
                              'MATERIALIZED VIEW',
                              'PACKAGE',
                              'PROCEDURE',
                              'FUNCTION',
                              'SEQUENCE',
                              'SYNONYM',
                              'PACKAGE BODY'
                             ))
   LOOP
      BEGIN
         IF cur_rec.object_type = 'TABLE'
         THEN
            EXECUTE IMMEDIATE    'DROP '
                              || cur_rec.object_type
                              || ' "'
                              || cur_rec.object_name
                              || '" CASCADE CONSTRAINTS';
         ELSE
            EXECUTE IMMEDIATE    'DROP '
                              || cur_rec.object_type
                              || ' "'
                              || cur_rec.object_name
                              || '"';
         END IF;
      EXCEPTION
         WHEN OTHERS
         THEN
            DBMS_OUTPUT.put_line (   'FAILED: DROP '
                                  || cur_rec.object_type
                                  || ' "'
                                  || cur_rec.object_name
                                  || '"'
                                 );
      END;
   END LOOP;
END;
/
278
Henry Gao

これを行うための本当に簡単な方法が必要な場合..過去に使用したスクリプトを以下に示します。

select 'drop table '||table_name||' cascade constraints;' from user_tables;

これにより、スキーマ内のすべてのテーブルに対して一連のドロップコマンドが出力されます。このクエリの結果をスプールして実行します。

ソース： https://forums.Oracle.com/forums/thread.jspa?threadID=61409

同様に、テーブル以上をクリアしたい場合は、ニーズに合わせて以下を編集できます

select 'drop '||object_type||' '|| object_name || ';' from user_objects where object_type in ('VIEW','PACKAGE','SEQUENCE', 'PROCEDURE', 'FUNCTION', 'INDEX')
192
khylo

私のために働いた別の答えは（ http://snipt.net/Fotinakis/drop-all-tables-and-constraints-within-an-Oracle-schema/ への信用）

BEGIN

FOR c IN (SELECT table_name FROM user_tables) LOOP
EXECUTE IMMEDIATE ('DROP TABLE "' || c.table_name || '" CASCADE CONSTRAINTS');
END LOOP;

FOR s IN (SELECT sequence_name FROM user_sequences) LOOP
EXECUTE IMMEDIATE ('DROP SEQUENCE ' || s.sequence_name);
END LOOP;

END;

これは、実行後すぐに動作することに注意してください。 NOTは、どこかに貼り付ける必要があるスクリプトを生成します（他の回答と同様）。 DB上で直接実行されます。

44
kazanaki
begin
  for i in (select 'drop table '||table_name||' cascade constraints' tbl from user_tables) 
  loop
     execute immediate i.tbl;
  end loop;
end;
21
Md. Maksud Alam

最も簡単な方法は、cascadeコマンドでオブジェクトを所有しているユーザーを削除することです。

DROP USER username CASCADE
10
Brian

最も簡単な方法は、テーブルスペースを削除してから、バックアップしてテーブルスペースを構築することです。しかし、そうする必要はありません。これはヘンリーのものと似ていますが、GUIの結果セットでコピー/貼り付けを行うだけです。

SELECT
  'DROP'
  ,object_type
  ,object_name
  ,CASE(object_type)
     WHEN 'TABLE' THEN 'CASCADE CONSTRAINTS;'
     ELSE ';'
   END
 FROM user_objects
 WHERE
   object_type IN ('TABLE','VIEW','PACKAGE','PROCEDURE','FUNCTION','SEQUENCE')
6
TJR
SELECT 'DROP TABLE "' || TABLE_NAME || '" CASCADE CONSTRAINTS;' 
FROM user_tables;

user_tablesは、ユーザーのすべてのテーブルを含むシステムテーブルです。SELECT句は、スクリプトを実行できるすべてのテーブルに対してDROPステートメントを生成します

2
ANiket Chavan

Oracleのすべてのオブジェクトを削除するには：

1）ダイナミック

DECLARE
CURSOR IX IS
SELECT * FROM ALL_OBJECTS WHERE OBJECT_TYPE ='TABLE' 
AND OWNER='SCHEMA_NAME';
 CURSOR IY IS
 SELECT * FROM ALL_OBJECTS WHERE OBJECT_TYPE 
IN ('SEQUENCE',
'PROCEDURE',
'PACKAGE',
'FUNCTION',
'VIEW') AND  OWNER='SCHEMA_NAME';
 CURSOR IZ IS
 SELECT * FROM ALL_OBJECTS WHERE OBJECT_TYPE IN ('TYPE') AND  OWNER='SCHEMA_NAME';
BEGIN
 FOR X IN IX LOOP
   EXECUTE IMMEDIATE('DROP '||X.OBJECT_TYPE||' '||X.OBJECT_NAME|| ' CASCADE CONSTRAINT');
 END LOOP;
 FOR Y IN IY LOOP
   EXECUTE IMMEDIATE('DROP '||Y.OBJECT_TYPE||' '||Y.OBJECT_NAME);
 END LOOP;
 FOR Z IN IZ LOOP
   EXECUTE IMMEDIATE('DROP '||Z.OBJECT_TYPE||' '||Z.OBJECT_NAME||' FORCE ');
 END LOOP;
END;
/

2）静的

    SELECT 'DROP TABLE "' || TABLE_NAME || '" CASCADE CONSTRAINTS;' FROM user_tables
        union ALL
        select 'drop '||object_type||' '|| object_name || ';' from user_objects 
        where object_type in ('VIEW','PACKAGE','SEQUENCE', 'PROCEDURE', 'FUNCTION')
        union ALL
        SELECT 'drop '
        ||object_type
        ||' '
        || object_name
        || ' force;'
        FROM user_objects
        WHERE object_type IN ('TYPE');
1
Goyal Vicky