web-dev-qa-db-ja.com

Oracleストアドプロシージャから結果セットを取得する

ストアドプロシージャをSQLサーバーからOracleに変換する作業をしています。このストアドプロシージャは、直接の結果セットを提供します。 Management Studioなどでストアドプロシージャを呼び出すと、結果セットが直接取得されるということです。

Oracleに変換することにより、Oracleで結果セットが表示されないという問題に反対します

私はインターネットで検索し、ストアドプロシージャがREF CURSORを生成することを確認しましたが、それでも処理中に結果セットを取得するために小さなコードを書く問題を抱えています。

擬似コード：

ストアドプロシージャを呼び出してカーソルを取得する

誰か考え？

oraclestored-proceduresplsql
36
jwdehaan

SQL Plusの場合：

SQL> create procedure myproc (prc out sys_refcursor)
  2  is
  3  begin
  4     open prc for select * from emp;
  5  end;
  6  /

Procedure created.

SQL> var rc refcursor
SQL> execute myproc(:rc)

PL/SQL procedure successfully completed.

SQL> print rc

     EMPNO ENAME      JOB              MGR HIREDATE           SAL       COMM     DEPTNO
---------- ---------- --------- ---------- ----------- ---------- ---------- ----------
      7839 KING       PRESIDENT            17-NOV-1981       4999                    10
      7698 BLAKE      MANAGER         7839 01-MAY-1981       2849                    30
      7782 CLARKE     MANAGER         7839 09-JUN-1981       2449                    10
      7566 JONES      MANAGER         7839 02-APR-1981       2974                    20
      7788 SCOTT      ANALYST         7566 09-DEC-1982       2999                    20
      7902 FORD       ANALYST         7566 03-DEC-1981       2999                    20
      7369 SMITHY     CLERK           7902 17-DEC-1980       9988         11         20
      7499 ALLEN      SALESMAN        7698 20-FEB-1981       1599       3009         30
      7521 WARDS      SALESMAN        7698 22-FEB-1981       1249        551         30
      7654 MARTIN     SALESMAN        7698 28-SEP-1981       1249       1400         30
      7844 TURNER     SALESMAN        7698 08-SEP-1981       1499          0         30
      7876 ADAMS      CLERK           7788 12-JAN-1983       1099                    20
      7900 JAMES      CLERK           7698 03-DEC-1981        949                    30
      7934 MILLER     CLERK           7782 23-JAN-1982       1299                    10
      6668 Umberto    CLERK           7566 11-JUN-2009      19999          0         10
      9567 ALLBRIGHT  ANALYST         7788 02-JUN-2009      76999         24         10
64
Tony Andrews

OracleはSQLサーバーではありません。 SQL Developerで次を試してください

variable rc refcursor;
exec testproc(:rc2);
print rc2
4
softveda

私の解決策は、パイプライン化された関数を作成することでした。利点は、クエリを1行にできることです。

  • select * from table(yourfunction(param1, param2));
  • 結果を他のテーブルに結合したり、必要に応じてフィルタリングまたはソートできます。
  • 結果は通常のクエリ結果として表示されるため、簡単に操作できます。

関数を定義するには、次のようなことをする必要があります。

  -- Declare the record columns
  TYPE your_record IS RECORD(
     my_col1 VARCHAR2(50), 
     my_col2 varchar2(4000)
  );
  TYPE your_results IS TABLE OF your_record;

  -- Declare the function
  function yourfunction(a_Param1 varchar2, a_Param2 varchar2)
  return your_results pipelined is
    rt          your_results;
  begin
    -- Your query to load the table type
    select s.col1,s.col2
    bulk collect into rt
    from your_table s
    where lower(s.col1) like lower('%'||a_Param1||'%');

    -- Stuff the results into the pipeline..
    if rt.count > 0 then 
      for i in rt.FIRST .. rt.LAST loop 
        pipe row (rt(i)); 
      end loop; 
    end if;

    -- Add more results as you please....
    return;
  end find;

また、上記のように、結果を表示するために行うことは次のとおりです。

select * from table(yourfunction(param1, param2)) t order by t.my_col1;
2
AnthonyVO

こんにちは、私はこれがしばらく前に尋ねられたことを知っていますが、私はこれを理解したばかりで、他の誰かを助けるかもしれません。これがまさにあなたが探しているものかどうかはわかりませんが、これはストアドプロシージャを呼び出してSQL Developerを使用して出力を表示する方法です。
SQL Developerでプロシージャを表示しているときに、右クリックして[実行]を選択するか、Ctrl + F11を選択して[PL/SQLの実行]ウィンドウを表示します。これにより、変更が必要な入力パラメーターと出力パラメーターを含むテンプレートが作成されます。私のprocはsys_refcursorを返します。私にとってトリッキーな部分は、procによって返されるselect stmt/sys_refcursorとまったく同じである行タイプを宣言することでした。

DECLARE
  P_CAE_SEC_ID_N NUMBER;
  P_FM_SEC_CODE_C VARCHAR2(200);
  P_PAGE_INDEX NUMBER;
  P_PAGE_SIZE NUMBER;
  v_Return sys_refcursor;
  type t_row is record (CAE_SEC_ID NUMBER,FM_SEC_CODE VARCHAR2(7),rownum number, v_total_count number);
  v_rec t_row;

BEGIN
  P_CAE_SEC_ID_N := NULL;
  P_FM_SEC_CODE_C := NULL;
  P_PAGE_INDEX := 0;
  P_PAGE_SIZE := 25;

  CAE_FOF_SECURITY_PKG.GET_LIST_FOF_SECURITY(
    P_CAE_SEC_ID_N => P_CAE_SEC_ID_N,
    P_FM_SEC_CODE_C => P_FM_SEC_CODE_C,
    P_PAGE_INDEX => P_PAGE_INDEX,
    P_PAGE_SIZE => P_PAGE_SIZE,
    P_FOF_SEC_REFCUR => v_Return
  );
  -- Modify the code to output the variable
  -- DBMS_OUTPUT.PUT_LINE('P_FOF_SEC_REFCUR = ');
  loop
    fetch v_Return into v_rec;
    exit when v_Return%notfound;
    DBMS_OUTPUT.PUT_LINE('sec_id = ' || v_rec.CAE_SEC_ID || 'sec code = ' ||v_rec.FM_SEC_CODE);
  end loop;

END;
1
Ciaran Bruen

SQL Plusの場合：

SQL> var r refcursor
SQL> set autoprint on
SQL> exec :r := function_returning_refcursor();

最後の行をプロシージャ/関数の呼び出しに置き換えると、refcursorの内容が表示されます

1
stjohnroe