web-dev-qa-db-ja.com

CMDでファイルパスからフォルダパスを取得する方法

Cmdファイルを含むフォルダーへのパスが必要です。 ％0を使用すると、ファイル名を取得できます。しかし、フォルダ名を取得する方法は？

c：\ temp\test.cmd >> test.cmd

追伸私の現在のディレクトリ！=スクリプトのフォルダー。

pathcmd
136
Mike Chaliy

フォルダ名とドライブには、次を使用できます。

echo %~dp0

さまざまな修飾子を使用して、より多くの情報を取得できます。

%~I         - expands %I removing any surrounding quotes (")
%~fI        - expands %I to a fully qualified path name
%~dI        - expands %I to a drive letter only
%~pI        - expands %I to a path only
%~nI        - expands %I to a file name only
%~xI        - expands %I to a file extension only
%~sI        - expanded path contains short names only
%~aI        - expands %I to file attributes of file
%~tI        - expands %I to date/time of file
%~zI        - expands %I to size of file

The modifiers can be combined to get compound results:
%~dpI       - expands %I to a drive letter and path only
%~nxI       - expands %I to a file name and extension only
%~fsI       - expands %I to a full path name with short names only

これは、「for /？」からのコピーペーストです。プロンプトのコマンド。それが役に立てば幸い。

関連する

トップ10 DOSバッチのヒント（はい、DOSバッチ...） 表示 batchparams.bat （Gistとしてソースへのリンク）：

C:\Temp>batchparams.bat c:\windows\notepad.exe
%~1     =      c:\windows\notepad.exe
%~f1     =      c:\WINDOWS\NOTEPAD.EXE
%~d1     =      c:
%~p1     =      \WINDOWS\
%~n1     =      NOTEPAD
%~x1     =      .EXE
%~s1     =      c:\WINDOWS\NOTEPAD.EXE
%~a1     =      --a------
%~t1     =      08/25/2005 01:50 AM
%~z1     =      17920
%~$PATHATH:1     =
%~dp1     =      c:\WINDOWS\
%~nx1     =      NOTEPAD.EXE
%~dp$PATH:1     =      c:\WINDOWS\
%~ftza1     =      --a------ 08/25/2005 01:50 AM 17920 c:\WINDOWS\NOTEPAD.EXE
289
Wadih M.

受け入れられた答えは役に立ちますが、渡された値を使用していない場合にパスからファイル名を取得する方法はすぐにはわかりません。私はこのスレッドからこれを解決することができましたが、他の人がそれほど幸運でない場合は、次のようにします：

@echo off
setlocal enabledelayedexpansion enableextensions

set myPath=C:\Somewhere\Somewhere\SomeFile.txt
call :file_name_from_path result !myPath!
echo %result%
goto :eof

:file_name_from_path <resultVar> <pathVar>
(
    set "%~1=%~nx2"
    exit /b
)

:eof
endlocal

現在、:file_name_from_path関数は、引数で渡されるだけでなく、どこでも値を取得するために使用できます。引数を不定の順序でファイルに渡すことができる場合、またはパスがファイルにまったく渡されない場合、これは非常に役立ちます。

45
NightOwl888

これらを変数に割り当てるには、等号の前または後にスペースを追加しないでください。

set filepath=%~dp1
set filename=%~nx1

その後、問題はないはずです。

7
Frank

Wadihが受け入れた回答がうまくいかなかった場合は、echo %CD%を試してください

2
Naguib Ihab

同じディレクトリでZipファイルを抽出し、Zipファイルを削除するというループで同じ問題が発生しました。問題は、7zには出力フォルダーが必要なため、各ファイルのフォルダーパスを取得する必要があったことです。ここに私の解決策があります：

FOR /F "usebackq tokens=1" %%i IN (`DIR /S/B *.Zip` ) DO (
  7z.exe x %%i -aoa -o%%i\..
)

%% iは完全なファイル名パスで、％ii\..は単に親フォルダーを返します。

それが役に立てば幸い。

2
Gico

誰かが別の方法を望んでいる場合...

それがパスの最後のサブディレクトリである場合、このワンライナーを使用できます。

cd "c:\directory\subdirectory\filename.exe\..\.." && dir /ad /b /s

これにより、次が返されます。

c:\directory\subdirectory

....は前のディレクトリに戻ります。/adはディレクトリのみを表示します/ bは裸形式のリストです/ sはすべてのサブディレクトリを含みます。これは、印刷するディレクトリの完全パスを取得するために使用されます。

2
Mark

これはいくつかの編集された例のcmdと一緒にされました

@Echo off

Echo ********************************************************
Echo *  Zip Folder Backup using 7Zip                        *
Echo *  Usage: Source Folder, Destination Drive Letter      *
Echo *  Source Folder will be Zipped to Destination\Backups *
Echo ********************************************************
Echo off

set year=%date:~-4,4%
set month=%date:~-10,2%
set day=%date:~-7,2%
set hour=%time:~-11,2%
set hour=%hour: =0%
set min=%time:~-8,2%

SET /P src=Source Folder to Backup: 
SET source=%src%\*
call :file_name_from_path nam %src%
SET /P destination=Backup Drive Letter:
set zipfilename=%nam%.%year%.%month%.%day%.%hour%%min%.Zip
set dest="%destination%:\Backups\%zipfilename%"


set AppExePath="%ProgramFiles(x86)%\7-Zip\7z.exe"
if not exist %AppExePath% set AppExePath="%ProgramFiles%\7-Zip\7z.exe"

if not exist %AppExePath% goto notInstalled

echo Backing up %source% to %dest%

%AppExePath% a -r -tzip %dest% %source%

echo %source% backed up to %dest% is complete!

TIMEOUT 5

exit;

:file_name_from_path <resultVar> <pathVar>
(
    set "%~1=%~nx2"
    exit /b
)


:notInstalled

echo Can not find 7-Zip, please install it from:
echo  http://7-Zip.org/

:end
PAUSE
0
Steve Seymour