Perlを使用してパスワードを入力し、文字を「*」に置き換えるにはどうすればよいですか？
ユーザーにパスワードの入力を要求するPerlスクリプトがあります。ユーザーが入力する文字の代わりに「*」のみをエコーするにはどうすればよいですか？
私はWindowsXP/Vistaを使用しています。
Term :: ReadKeyで遊ぶことができます。これは非常に単純な例で、バックスペースと削除キーが検出されています。 Mac OS X 10.5でテストしましたが、 ReadKeyマニュアル によると、Windowsでも動作するはずです。 manual は、Windowsで非ブロッキング読み取り（ReadKey(-1)）を使用すると失敗することを示します。そのため、基本的にgetcであるReadKey（0）を使用しています（getcの詳細については libcマニュアル を参照してください）。
#!/usr/bin/Perl
use strict;
use warnings;
use Term::ReadKey;
my $key = 0;
my $password = "";
print "\nPlease input your password: ";
# Start reading the keys
ReadMode(4); #Disable the control keys
while(ord($key = ReadKey(0)) != 10)
# This will continue until the Enter key is pressed (decimal value of 10)
{
# For all value of ord($key) see http://www.asciitable.com/
if(ord($key) == 127 || ord($key) == 8) {
# DEL/Backspace was pressed
#1. Remove the last char from the password
chop($password);
#2 move the cursor back by one, print a blank character, move the cursor back by one
print "\b \b";
} elsif(ord($key) < 32) {
# Do nothing with these control characters
} else {
$password = $password.$key;
print "*(".ord($key).")";
}
}
ReadMode(0); #Reset the terminal once we are done
print "\n\nYour super secret password is: $password\n";
過去に私はこれに IO :: Prompt を使用しました。
use IO::Prompt;
my $password = Prompt('Password:', -e => '*');
print "$password\n";
パッケージを使用したくない場合... UNIXのみ
system('stty','-echo');
chop($password=<STDIN>);
system('stty','echo');
Term :: ReadKey または Win32 :: Console のいずれかを確認する必要があります。これらのモジュールを使用して、単一のキーストロークを読み取り、「*」などを出力できます。
Pierr-Lucのプログラムに基づいて、バックスラッシュの制御を追加しました。これでは、バックスラッシュを永遠に押し続けることはできません。
sub passwordDisplay() {
my $password = "";
# Start reading the keys
ReadMode(4); #Disable the control keys
my $count = 0;
while(ord($key = ReadKey(0)) != 10) {
# This will continue until the Enter key is pressed (decimal value of 10)
# For all value of ord($key) see http://www.asciitable.com/
if(ord($key) == 127 || ord($key) == 8) {
# DEL/Backspace was pressed
if ($count > 0) {
$count--;
#1. Remove the last char from the password
chop($password);
#2 move the cursor back by one, print a blank character, move the cursor back by one
print "\b \b";
}
}
elsif(ord($key) >= 32) {
$count++;
$password = $password.$key;
print "*";
}
}
ReadMode(0); #Reset the terminal once we are done
return $password;
}
pierr-Lucのプログラムを使用する
# Start reading the keys
ReadMode(4); #Disable the control keys
while(ord($key = ReadKey(0)) != '13' )
# This will continue until the Enter key is pressed (decimal value of 10)
{
# For all value of ord($key) see http://www.asciitable.com/
if(ord($key) == 127 || ord($key) == 8 && (length($password) > 0)) {
# DEL/Backspace was pressed
#1. Remove the last char from the password
chop($password);
#2 move the cursor back by one, print a blank character, move the cursor back by one
print "\b \b";
} elsif(ord($key) > 32) {
$password = $password.$key;
print "*";
}
}
ReadMode(0); #Reset the terminal once we are done