web-dev-qa-db-ja.com

Qtクイックコントロールでメッセージボックスを表示するにはどうすればよいですか？

Qtクイックコントロールを使用してQMLアプリケーションを作成する場合、QMessageBox::information()に相当するものは何ですか？

qtqmlqt-quickqtquick2
13
Timmmm

Qt 5.2には、MessageDialogがあります。

http://doc.qt.io/qt-5/qml-qtquick-dialogs-messagedialog.html

import QtQuick 2.2
import QtQuick.Dialogs 1.1

MessageDialog {
    id: messageDialog
    title: "May I have your attention please"
    text: "It's so cool that you are using Qt Quick."
    onAccepted: {
        console.log("And of course you could only agree.")
        Qt.quit()
    }
    Component.onCompleted: visible = true
}
12
Zmey

使用できます Popup QtQuick Controls 2で：

import QtQuick.Window 2.2
import QtQuick.Controls 2.0 // or import Qt.labs.controls 1.0

Window {
    id: window
    width: 400
    height: 400
    visible: true
Button {
    text: "Open"
    onClicked: popup.open()
}

Popup {
    id: popup
    x: 100
    y: 100
    width: 200
    height: 300
    modal: true
    focus: true
    closePolicy: Popup.CloseOnEscape | Popup.CloseOnPressOutsideParent
    }
}
6
sayyed mohsen zahraee

わかりました、これは仕事をします（ひどく）。 Windowオブジェクトをインポートします。

import QtQuick.Window 2.1

次に、これをメインウィンドウに追加します（または、別のファイルに配置することもできます）。

function showMessage(text, title)
{
    messageBox.text = text;
    messageBox.title = title;
    messageBox.visible = true;
}

Window {
    id: messageBox
    modality: Qt.ApplicationModal
    title: ""
    visible: false
    property alias text: messageBoxLabel.text
    color: parent.color
    minimumHeight: 100
    minimumWidth: 300
    Label {
        anchors.margins: 10
        anchors.top: parent.top
        anchors.left: parent.left
        anchors.right: parent.right
        anchors.bottom: messageBoxButton.top
        horizontalAlignment: Text.AlignHCenter
        wrapMode: Text.WordWrap
        id: messageBoxLabel
        text: ""
    }

    Button {
        anchors.margins: 10
        id: messageBoxButton
        anchors.bottom: parent.bottom
        anchors.horizontalCenter: parent.horizontalCenter
        text: "Ok"
        onClicked: messageBox.visible = false
    }
}

それに関する問題：

  1. テキストとボタンが重なるようにウィンドウを縮小することができます。
  2. 最小ウィンドウサイズは、テキストサイズから計算されるのではなく、ハードコードされています。
  3. テキストを選択することはできません。
  4. 少したわごとに見えます。
2
Timmmm

残念ながら、少なくともQt5.1.1の時点で出荷されているQtQuickControlsにはありません:(

QObjectラッパー を介してプロジェクトに追加する必要があります。

1
Reinstate Monica
// CenteredDialog.qml
import QtQml 2.2

import QtQuick 2.9
import QtQuick.Controls 2.2

Dialog {
    parent: ApplicationWindow.overlay

    x: (parent.width - width) / 2
    y: (parent.height - height) / 2

    focus: true
    modal: true

    property alias text: messageText.text

    Label {
        id: messageText

        verticalAlignment: Text.AlignVCenter
        horizontalAlignment: Text.AlignHCenter

        anchors.fill: parent
    }

    standardButtons: Dialog.Ok
}

どこかでCenteredDialog { id: centeredDialog }を宣言してから、イベントハンドラーで次のように呼び出すことができます。

 centeredDialog.title = qsTr("Error!")
 centeredDialog.text = qsTr("Access violation")
 centeredDialog.visible = true
0
Tomilov Anatoliy