web-dev-qa-db-ja.com

Groovy組み込みREST / HTTPクライアント？

GroovyにはREST/HTTPクライアントが組み込まれていると聞きました。私が見つけることができる唯一のライブラリは、 HttpBuilder 、これですか？

基本的に、ライブラリをインポートすることなく（可能な場合）、Groovyコード内からHTTP GETを実行する方法を探しています。しかし、このモジュールはコアGroovyの一部ではないようですので、ここに適切なライブラリがあるかどうかはわかりません。

restgroovyhttpbuilder
61
smeeb

ネイティブGroovy GETおよびPOST

// GET
def get = new URL("https://httpbin.org/get").openConnection();
def getRC = get.getResponseCode();
println(getRC);
if(getRC.equals(200)) {
    println(get.getInputStream().getText());
}

// POST
def post = new URL("https://httpbin.org/post").openConnection();
def message = '{"message":"this is a message"}'
post.setRequestMethod("POST")
post.setDoOutput(true)
post.setRequestProperty("Content-Type", "application/json")
post.getOutputStream().write(message.getBytes("UTF-8"));
def postRC = post.getResponseCode();
println(postRC);
if(postRC.equals(200)) {
    println(post.getInputStream().getText());
}
80
Jim Perris

ニーズが単純で、依存関係の追加を避けたい場合は、GroovyがJava.net.URLクラスに追加するgetText()メソッドを使用できる場合があります。

new URL("http://stackoverflow.com").getText()

// or

new URL("http://stackoverflow.com")
        .getText(connectTimeout: 5000, 
                readTimeout: 10000, 
                useCaches: true, 
                allowUserInteraction: false, 
                requestProperties: ['Connection': 'close'])

バイナリデータが返されることを期待している場合は、newInputStream()メソッドによって提供される同様の機能もあります。

56
John Wagenleitner

最も簡単なものは次のとおりです。

def html = "http://google.com".toURL().text
27
John

With（）などのGroovy機能、URLConnectionの改善、および単純化されたゲッター/セッターを利用できます。

GET：

String getResult = new URL('http://mytestsite/bloop').text

POST：

String postResult
((HttpURLConnection)new URL('http://mytestsite/bloop').openConnection()).with({
    requestMethod = 'POST'
    doOutput = true
    setRequestProperty('Content-Type', '...') // Set your content type.
    outputStream.withPrintWriter({printWriter ->
        printWriter.write('...') // Your post data. Could also use withWriter() if you don't want to write a String.
    })
    // Can check 'responseCode' here if you like.
    postResult = inputStream.text // Using 'inputStream.text' because 'content' will throw an exception when empty.
})

POSTは、responseCode、inputStream.text、またはgetHeaderField('...')など、HttpURLConnectionから値を読み取ろうとすると開始されます。

14
Daniel

HTTPBuilder です。とても使いやすい。

import groovyx.net.http.HTTPBuilder

def http = new HTTPBuilder('https://google.com')
def html = http.get(path : '/search', query : [q:'waffles'])

GETでコンテンツを取得するだけでなく、エラー処理や一般的に多くの機能が必要な場合に特に役立ちます。

12
Dakota Brown

Http-builderはGroovyモジュールではなく、 Apache http-client の外部APIであるとは思わないので、クラスをインポートして多数のAPIをダウンロードする必要があります。 Gradleまたは@Grabを使用して、jarと依存関係をダウンロードする方が適切です。

@Grab(group='org.codehaus.groovy.modules.http-builder', module='http-builder', version='0.7.1' )
import groovyx.net.http.*
import static groovyx.net.http.ContentType.*
import static groovyx.net.http.Method.*

注：CodeHausサイトがダウンしたため、JARは（ https://mvnrepository.com/artifact/org.codehaus.groovy.modules.http-builder/http-builder ）で見つけることができます

2
Will
import groovyx.net.http.HTTPBuilder;

public class HttpclassgetrRoles {
     static void main(String[] args){
         def baseUrl = new URL('http://test.city.com/api/Cirtxyz/GetUser')

         HttpURLConnection connection = (HttpURLConnection) baseUrl.openConnection();
         connection.addRequestProperty("Accept", "application/json")
         connection.with {
           doOutput = true
           requestMethod = 'GET'
           println content.text
         }

     }
}
0
SQA