web-dev-qa-db-ja.com

指定した場所でTSQLを使用してデータベースを作成する

指定された場所でTSQLスクリプトを使用してデータベースを作成するにはどうすればよいですか？たとえば、D:\temp\dbFolderにSQLサーバーデータベースを作成したいとします。これを行う方法？

sql-servertsql
16
Graviton

新しいデータベースを作成するときに、場所を指定します。例えば：

USE [master]
GO

    CREATE DATABASE [AdventureWorks] ON  PRIMARY 
    ( NAME = N'AdventureWorks_Data', FILENAME = N'C:\Program Files\Microsoft SQL Server\MSSQL.1\MSSQL\Data\AdventureWorks_Data.mdf' , SIZE = 167872KB , MAXSIZE = UNLIMITED, FILEGROWTH = 16384KB )
     LOG ON 
    ( NAME = N'AdventureWorks_Log', FILENAME = N'C:\Program Files\Microsoft SQL Server\MSSQL.1\MSSQL\Data\AdventureWorks_Log.ldf' , SIZE = 2048KB , MAXSIZE = 2048GB , FILEGROWTH = 16384KB )
    GO
39
Leah

SQL Server Booksから、データベースファイル名が明示的に定義されている例：

USE master
GO
CREATE DATABASE Sales
ON 
( NAME = Sales_dat,
   FILENAME = 'c:\program files\Microsoft sql server\mssql\data\saledat.mdf',
   SIZE = 10,
   MAXSIZE = 50,
   FILEGROWTH = 5 )
LOG ON
( NAME = 'Sales_log',
   FILENAME = 'c:\program files\Microsoft sql server\mssql\data\salelog.ldf',
   SIZE = 5MB,
   MAXSIZE = 25MB,
   FILEGROWTH = 5MB )
GO
11
boes
  1. ファイルシステムにフォルダを作成します：D：\ temp\dbFolder \

  2. スクリプトを実行します。

    USE master; 
GO 
CREATE DATABASE TestDB1  
ON      ( NAME = Sales_dat, FILENAME = 'D:\temp\dbFolder\TestDB1.mdf') 
LOG ON  ( NAME = Sales_log, FILENAME = 'D:\temp\dbFolder\TestDB1.ldf'); 
GO
3
landrew

前の例を拡張したStudioManagerでの変数の使用。

フォルダとサブフォルダを作成します。
例：ルートフォルダーE：\ MSSQL\DATAサブフォルダーE：\ MSSQL\DATA\DBおよびE：\ MSSQL\DATA\Logs。

MKDIR "E:\MSSQL\DATA\DB"
MKDIR "E:\MSSQL\DATA\Logs"

データベース名@DBNAME変数@Test_DB 'を' DesiredName_DB 'に変更します

上記で作成したフォルダに従って、ルートフォルダパス@ DataPath'E：\ MSSQL\DATA 'をに変更します。

StudioManagerで以下を実行します

DECLARE @DBNAME VARCHAR(MAX)
DECLARE @DataPath AS NVARCHAR(MAX)
DECLARE @sql VARCHAR(MAX)

SET @DBNAME = N'Test_DB'
SET @DataPath = N'E:\MSSQL\DATA'

SELECT @sql = 'USE MASTER'
EXEC (@sql)

SELECT @sql = 'CREATE DATABASE '+ quotename(@DBNAME) + ' 
ON 
PRIMARY
 ( 
 NAME = ''' + @DBNAME + '_DB'', 
 FILENAME = ''' + @DataPath + '\DB\' + @DBNAME + '.mdf'', 
 SIZE = 3136 KB , MAXSIZE = UNLIMITED, 
 FILEGROWTH = 1024 KB
 ) 
LOG ON
 (
 NAME = '''+ @DBNAME + '_Log'', 
 FILENAME = '''+ @DataPath + '\Logs\' + @DBNAME  + '_log.ldf'', 
 SIZE = 832KB , MAXSIZE =  2048 GB , FILEGROWTH = 10 %
 )'


EXEC (@sql)

または上記のテーマの別のバリエーション。

DECLARE @DBNAME VARCHAR(MAX)
DECLARE @DataFilePath AS NVARCHAR(MAX)
DECLARE @LogFilePath AS NVARCHAR(MAX)
DECLARE @sql VARCHAR(MAX)

SET @DBNAME = N'Test_DB'
SET @DataFilePath = N'E:\MSSQL\DATA\DB\'
SET @LogFilePath = N'E:\MSSQL\DATA\Logs\'

SELECT @sql = 'USE MASTER'
EXEC (@sql)

SELECT @sql = 'CREATE DATABASE '+ quotename(@DBNAME) + ' 
ON 
PRIMARY
 ( 
 NAME = ''' + @DBNAME + '_DB'', 
 FILENAME = ''' + @DataFilePath + @DBNAME + '.mdf'', 
 SIZE = 3136 KB , MAXSIZE = UNLIMITED, 
 FILEGROWTH = 1024 KB
 ) 
LOG ON
 (
 NAME = '''+ @DBNAME + '_Log'', 
 FILENAME = '''+ @LogFilePath+ @DBNAME  + '_log.ldf'', 
 SIZE = 832KB , MAXSIZE =  2048 GB , FILEGROWTH = 10 %
 )'


EXEC (@sql)
2
Brett Bieker

ファイルシステムにフォルダを作成します：D：\ temp\dbFolder \そして以下のスクリプトを実行します（「sa」ログインを試してください）

 USE master
CREATE DATABASE [faltu] ON  PRIMARY 
( NAME = N'faltu', FILENAME = N'D:\temp\dbFolder\faltu.mdf' , SIZE = 2048KB , FILEGROWTH = 1024KB )
 LOG ON 
( NAME = N'faltu_log', FILENAME = N'D:\temp\dbFolder\faltu_log.ldf' , SIZE = 1024KB , FILEGROWTH = 10%)
0
Avinash

このリンクを参照してください： CREATE DATABASE（Transact-SQL）

CREATE DATABASE [ADestinyDb] CONTAINMENT = NONE ON  PRIMARY 
( NAME = N'ADestinyDb', 
  FILENAME = N'D:\temp\dbFolder\ADestinyDb.mdf' , 
  SIZE = 3136 KB , MAXSIZE = UNLIMITED, 
  FILEGROWTH = 1024 KB )
LOG ON 
( NAME = N'ADestinyDb_log', 
  FILENAME = N'D:\temp\dbFolder\_log.ldf' , 
  SIZE = 832KB , MAXSIZE =  2048 GB , FILEGROWTH = 10 %)
0
Ardalan Shahgholi