web-dev-qa-db-ja.com

SQL Serverのすべてのデータベースのバックアップを取る

Microsoft SQL Server 2005 DBサーバーがあります。 DBサーバーには、約250のユーザーデータベースがあります。これらすべてのデータベースのバックアップを取る必要があります。手動でバックアップを取ると多くの時間がかかるので、250のデータベースすべてのバックアップを自動的に取るバッチスクリプトまたはDBスクリプトを探しています。誰かこれを手伝ってくれませんか？

sql-serversql-server-2005backup
13
user1493004

注：最初にD:ドライブにフォルダーを作成します。 （例：D:\User_DataBackup\）

ステップ1：以下の手順を作成します。

Create PROCEDURE [dbo].[UserDataBaseBackUp]
AS

BEGIN
SET NOCOUNT ON;

DECLARE @name VARCHAR(50) -- database name
DECLARE @path VARCHAR(256) -- path for backup files
DECLARE @fileName VARCHAR(256) -- filename for backup
DECLARE @fileDate VARCHAR(20) -- used for file name
SET @path = 'D:\User_DataBackup\' -- as same as your created folder' 
SELECT @fileDate = CONVERT(VARCHAR(20),GETDATE(),104)
DECLARE db_cursor CURSOR FOR
  SELECT name
  FROM MASTER.dbo.sysdatabases
  WHERE name NOT IN ('master','model','msdb','tempdb','ReportServer','ReportServerTempDB')
OPEN db_cursor
FETCH NEXT FROM db_cursor INTO @name
WHILE @@FETCH_STATUS = 0
BEGIN
  SET @fileName = @path + @name + '_' + @fileDate + '.BAK'
  BACKUP DATABASE @name TO DISK = @fileName
  FETCH NEXT FROM db_cursor INTO @name
END
CLOSE db_cursor
DEALLOCATE db_cursor
END

ステップ2：上記の手順を実行します。

 EXEC [UserDataBaseBackUp]

この手順をスケジュールすることもできます。この手順はテストされ、うまくいくと期待されます。

14
JP Chauhan

メンテナンスプランを作成する

SQL Serverには、スクリプトとジョブを作成するこの素晴らしい機能があります

  • ステップ1：
    Maintenance Plan _Managementの下

    Right Click on Management

  • ステップ2：
    プランに名前を付けてください

    Name the Plan

  • ステップ3：
    データベースバックアップタスクを選択

    Database Backup Task

  • ステップ4：
    タスクを構成し、データベース、フォルダの場所、バックアップの種類（完全、差分、トランザクションログ）接続などを選択します。

    Configure The Backup Task

  • ステップ5：
    ジョブスケジュールの構成

    Configure the Job Schedule

system-databasesとあなたのuser-databasesの別の計画を立てて、あらゆる種類の問題を回避することをお勧めします

役立つリンク：

11
AmmarR

SSMSで多くのデータベースを維持することは少し混乱するかもしれないという事実を知っていますが、それは簡単です。

Ola Hallengrenの保守スクリプト を使用する、より効果的な方法をお勧めします。とてもクールで効果的です。また、すべてのデータベースをバックアップするだけでなく、あらゆるタイプのメンテナンス手順を実行できます。

たとえば、次のようなコマンドを使用して、すべてのデータベースをバックアップし、圧縮して、選択した証明書で暗号化できます（これらはすべてオプションであり、暗号化と圧縮はSQL Server 2005では機能しませんが、SQL Server 2005では機能すると思いますOlaのスクリプトの柔軟性と強さを示す）：

EXECUTE dbo.DatabaseBackup @Databases = 'USER_DATABASES',
@Directory = 'C:\Backup',
@BackupType = 'FULL',
@Compress = 'Y',
@Encrypt = 'Y',
@EncryptionAlgorithm = 'AES_256',
@ServerCertificate = 'MyCertificate'
8
Sina Hassanpour

JPによる回答に取り組んで、宛先ディレクトリを渡すためのパラメーターを追加しました（そしておそらくオプションをさらに追加します）。

Create PROCEDURE [dbo].[UserDataBaseBackUp] (
  @OutputDir varchar(255)
) AS
BEGIN
    SET NOCOUNT ON;

    DECLARE @name VARCHAR(50) -- database name
    DECLARE @path VARCHAR(256) -- path for backup files
    DECLARE @fileName VARCHAR(256) -- filename for backup
    DECLARE @fileDate VARCHAR(20) -- used for file name
    SET @path = @OutputDir
    SELECT @fileDate = CONVERT(VARCHAR(20),GETDATE(),104)
    PRINT 'Starting Backups'
    DECLARE db_cursor CURSOR FOR
        SELECT name FROM MASTER.dbo.sysdatabases
            WHERE name NOT IN ('master','model','msdb','tempdb','ReportServer','ReportServerTempDB')
        OPEN db_cursor
            FETCH NEXT FROM db_cursor INTO @name
            WHILE @@FETCH_STATUS = 0 BEGIN
                SET @fileName = @path + @name + '_' + @fileDate + '.BAK'
                    PRINT 'Starting Backup For ' + @name
                    BACKUP DATABASE @name TO DISK = @fileName WITH FORMAT
                FETCH NEXT FROM db_cursor INTO @name
            END
        CLOSE db_cursor
    DEALLOCATE db_cursor
    PRINT 'Backups Finished'
END
GO

それで：

EXEC UserDataBaseBackUp @OutputDir = 'F:\Backups\SQL Databases\'
2
Jerry Dodge

次のようにSELECTステートメントまたはCURSORを使用できます。

DECLARE @PathForBackUp VARCHAR(255)
SET @PathForBackUp = 'F:\Backup\User DB\'

SELECT 'BACKUP DATABASE [' + name + '] TO  DISK = N''' + @PathForBackUp + '' + name + '.bak''
WITH NOFORMAT, NOINIT,  NAME = N''' + name + '_FullBackUp'', SKIP, NOREWIND, NOUNLOAD, COMPRESSION,  STATS = 5'
FROM sys.databases
WHERE database_id > 4

OR

DECLARE @DBName VARCHAR(255)  
DECLARE @PathForBackUp VARCHAR(255) 
DECLARE @FileName VARCHAR(255)  
DECLARE @DateFile VARCHAR(255)
DECLARE @SQL NVARCHAR(2048) 
SET @PathForBackUp = 'F:\Backup\User DB\'  
SET @DateFile = REPLACE(REPLACE(CONVERT(VARCHAR(20),GETDATE(),120) ,' ','T'), ':','') 

DECLARE BACKUPING CURSOR FOR   
SELECT name  
FROM master.dbo.sysdatabases WHERE dbid > 4 

OPEN BACKUPING    
FETCH NEXT FROM BACKUPING INTO @DBName    
WHILE @@FETCH_STATUS = 0    

BEGIN    
        SET @FileName = @PathForBackUp + @DBName + '_' + @DateFile + '.BAK'  
    SET @SQL = 'BACKUP DATABASE '+@DBName+ ' TO DISK = '''+@FileName+''' WITH COMPRESSION ' 
    PRINT @SQL 
    EXECUTE sp_executesql @sql   
    FETCH NEXT FROM BACKUPING INTO @DBName  

END    

CLOSE BACKUPING    
DEALLOCATE BACKUPING
1
Filip Holub