web-dev-qa-db-ja.com

Windows用のSVNフック

少しグーグルしてみたところ、Windows用のSVNフックのリソースが実際にはないことがわかりました。だから私はそれを一元化するためにここでウィキを始めると思いました。

貢献する場合は、必ず次のことを示してください。

  1. フックの名前
  2. スクリプトの機能
  3. 実際のスクリプト

注：壮大なスクリプトを投稿することは役に立たないと思います。

svnrepositorysvn-hooks
35
Greg Dean

空のコメントでコミットを防ぐ

  1. 事前コミット
  2. 空のコメントでコミットを防ぎます

ソース：

"c:\Program Files\Subversion\bin\svnlook.exe" log -t %2 %1 | FindStr [a-zA-Z0-9]
IF %ERRORLEVEL% EQU 0 GOTO OK
echo "Commit Comments are Required" >&2
exit 1
:OK
exit 0
11
Greg Dean

Svn :: log以外のリビジョン小道具への編集を防ぎます

  1. pre-revprop-change.bat
  2. Svn :: log以外のリビジョンプロパティへの編集を防ぎます
@ECHO OFF
:: Set all parameters. Even though most are not used, in case you want to add
:: changes that allow, for example, editing of the author or addition of log messages.
set repository=%1
set revision=%2
set userName=%3
set propertyName=%4
set action=%5

:: Only allow the log message to be changed, but not author, etc.
if /I not "%propertyName%" == "svn:log" goto ERROR_PROPNAME

:: Only allow modification of a log message, not addition or deletion.
if /I not "%action%" == "M" goto ERROR_ACTION

:: Make sure that the new svn:log message is not empty.
set bIsEmpty=true
for /f "tokens=*" %%g in ('find /V ""') do (
set bIsEmpty=false
)
if "%bIsEmpty%" == "true" goto ERROR_EMPTY

goto :eof

:ERROR_EMPTY
echo Empty svn:log messages are not allowed. >&2
goto ERROR_EXIT

:ERROR_PROPNAME
echo Only changes to svn:log messages are allowed. >&2
goto ERROR_EXIT

:ERROR_ACTION
echo Only modifications to svn:log revision properties are allowed. >&2
goto ERROR_EXIT

:ERROR_EXIT
exit /b 1
8
Greg Dean

*更新：TwitterはOAuthを優先してユーザー名/パスワード認証を廃止したため、これは機能しなくなりました。 *

コミット情報をTwitterに公開

  1. フックの名前=コミット後
  2. スクリプトの機能=リビジョン、作成者、およびコミットメッセージをTwitterに公開します

使用上の注意：

  • twitterUsernameとtwitterPasswordを実際のTwitterに置き換えます
  • これはVisualSVNに対してテストされており、それを機能させる唯一の方法は、すべてをハードコードされたパスc：\ hook\post-commitにダンプすることでした。 VisualSVNが読み取り/書き込みアクセスできる任意のパスに変更できます。
  • Wgetをインストールする必要があります。インストーラーをダウンロードできます ここ
  • コメントと改善を歓迎します。これはWindowsでの私の最初のSVNフックであり、私のGAWDはそれが苦痛でした。

実際のスクリプト

echo status= > c:\hook\post-commit\msg.txt
echo Rev#%2 by >> c:\hook\post-commit\msg.txt
"%VISUALSVN_SERVER%\bin\svnlook.exe" author -r %2 %1 >> c:\hook\post-commit\msg.txt
"%VISUALSVN_SERVER%\bin\svnlook.exe" log -r %2 %1 >> c:\hook\post-commit\msg.txt
"c:\Program Files (x86)\GnuWin32\bin\wget.exe" --user=twitterUsername --password=twitterPassword --post-file=c:\hook\post-commit\msg.txt --append-output=c:\hook\post-commit\log.txt --output-document=c:\hook\post-commit\download.txt --delete-after http://Twitter.com/statuses/update.xml
6
Portman

私はJavaでコード化されたsubHookerを使うのが好きです。コミット前後のフック機能を提供します。

コミット前：

  • コミットメッセージの要件、または最小の長さ、あるいはその両方を強制します（またはしない）
  • コミットメッセージでRegEX式の要件を適用できます。これは、バックログまたは欠陥番号を要求する（または要求しない）場合に適しています。

コミット後：

  • HTMLまたはプレーンテキストの電子メールメッセージを送信する
    • プレーンメッセージとhtmlメッセージの両方がテンプレートシステムを使用します
    • 差分をオンまたはオフにできます
    • チェンジセットをオンまたはオフにできます
  • ローカリゼーションをサポート
  • 標準化されたロギングをサポートします。

あなたはグーグルコード@ http://code.google.com/p/subhooker/ でそれを見つけることができます

それは無料です、そしてはい、私は著者です、私は数年前からSubversionを実行しています、私はそれをとても愛しています。それが私がこれをコミュニティに貢献している理由です。

4
John

一般的な「怠惰な」コミットメッセージをチェックします

  1. フックの名前= pre-commit
  2. スクリプトの機能=空白行または「。」を確認します。ライン。また、唯一のコメントとして許可されていない単語のファイルを確認してください。

実際のスクリプト

rem Make sure that the log message contains some text.
set REPOS=%1
set TXN=%2

"C:\Program Files\Subversion\bin\SVNlook.exe" log -t %TXN% %REPOS% | FindStr [a-zA-Z0-9]
IF %ERRORLEVEL% EQU 0 GOTO OK
echo Your commit has been blocked because you didn't provide a log message  1>&2
echo Please write a log message describing the purpose of your changes and 1>&2
echo then try committing again. -- Thank you 1>&2 
exit 1

:OK
rem Check if comment is in list of reserved words to not be used..

"C:\Program Files\Subversion\bin\SVNlook.exe" log -t %TXN% %REPOS% >comment
setlocal enabledelayedexpansion
Set SEPARATOR=
set COMMENT=
for /f "delims=" %%a in (comment) do (  
    set currentline=%%a
    set COMMENT=!COMMENT!%SEPARATOR%!currentline!
)

FIND "%COMMENT%" "C:\Program Files\Subversion\excludedwords.txt">Null
If %ERRORLEVEL% EQU 1 goto OK2

:Fail
echo Your commit has been blocked because the single Word comment you provided is not allowed 1>&2
echo Line is -%COMMENT%- 1>&2
echo Please write a proper log message describing the purpose of your changes and 1>&2
echo then try committing again. -- Thank you 1>&2 
exit 1


:OK2
rem Check that the author of this commit has the rights to perform
rem the commit on the files and directories being modified.
rem commit-access-control.pl "$REPOS" "$TXN" commit-access-control.cfg || exit 1

rem All checks passed, so allow the commit.
exit 0

除外された単語ファイルのサンプル：更新更新更新。更新しました。修正修正修正。修正。 .。 ..。 。 。 。ソート済みソート済み。ソート済みソート済み。

などなどなどなど

4
NickMon

WindowsでSubversionを使用している.NET開発者向けに、Phil Haackが CaptainHook について投稿しました。

CaptainHookは、.NETを使用してSubversionフックを作成するためのシンプルなプラグインフレームワークです。

プロジェクトは Source Forge でホストされています

3
tarn

Svn :: log以外のリビジョン小道具への編集を防ぐ

  1. pre-revprop-change.bat
  2. Svn :: log（代替バージョン）以外のリビジョンプロパティへの編集を防止します

ソース：

rem Only allow log messages to be changed.
if "%4" == "svn:log" exit 0
echo Property '%4' cannot be changed >&2
exit 1
3
M4N

このフックは、特定のブランチへのコミットを防ぎます

（branch-16Eこの場合）：

setlocal

rem Subversion sends through the path to the repository and transaction id  
set REPOS=%1
set TXN=%2

rem Committing to a branch is not allowed
svnlook changed -t %TXN% %REPOS% | findstr "\/branch-16E"
if %errorlevel% EQU 0 goto errb else exit 0

:errb
echo. 1>&2
echo This branch was closed. If you want to commit here contact your administrator. 1>&2
exit 1
1
MasterPJ

C＃を使用してフックのリポジトリを開始しました。私の最初のフックは、RSSフィードにチェックイン通知を送信するためのものでした。 SubversionRss 現在、Twitterフィードにチェックイン通知を送信するための1つのコミット後フックに取り組んでいます。

1
Hector Sosa Jr