web-dev-qa-db-ja.com

Windowsバッチ用のヒアドキュメント？

UNIXシェルのヒアドキュメントと同様の方法で複数行の文字列をバッチで指定する方法はありますか？似たようなもの：

cat <<EOF > out.txt
bla
bla
..
EOF

アイデアは、テンプレートファイルからカスタマイズされたファイルを作成することです。

templatesbatch-fileheredoc
30
Amro

私の知る限りではありません。

私が知っている最も近いものは

> out.txt (
    @echo.bla
    @echo.bla
    ...
)

（@は、コマンドシェル自体が実行中のコマンドを出力しないようにします。echo.は、スペースで行を開始できます。）

28
ephemient

別のアプローチがあります。

@echo off

:: ######################################################
:: ## Heredoc syntax:                                  ##
:: ## call :heredoc uniqueIDX [>outfile] && goto label ##
:: ## contents                                         ##
:: ## contents                                         ##
:: ## contents                                         ##
:: ## etc.                                             ##
:: ## :label                                           ##
:: ##                                                  ##
:: ## Notes:                                           ##
:: ## Variables to be evaluated within the heredoc     ##
:: ## should be called in the delayed expansion style  ##
:: ## (!var! rather than %var%, for instance).         ##
:: ##                                                  ##
:: ## Literal exclamation marks (!) and carats (^)     ##
:: ## must be escaped with a carat (^).                ##
:: ######################################################



:--------------------------------------------
: calling heredoc with results sent to stdout
:--------------------------------------------

call :heredoc stickman && goto next1

\o/
 | This is the "stickman" heredoc, echoed to stdout.
/ \
:next1



:-----------------------------------------------------------------
: calling heredoc containing vars with results sent to a text file
:-----------------------------------------------------------------

set bodyText=Hello world!
set lipsum=Lorem ipsum dolor sit amet, consectetur adipiscing elit.

call :heredoc html >out.txt && goto next2
<html lang="en">
    <body>
        <h3>!bodyText!</h3>
        <p>!lipsum!</p>
    </body>
</html>

Thus endeth the heredoc.  :)
:next2



echo;
echo Does the redirect to a file work?  Press any key to type out.txt and find out.
echo;

pause>NUL
type out.txt
del out.txt

:: End of main script
goto :EOF

:: ########################################
:: ## Here's the heredoc processing code ##
:: ########################################
:heredoc <uniqueIDX>
setlocal enabledelayedexpansion
set go=
for /f "delims=" %%A in ('findstr /n "^" "%~f0"') do (
    set "line=%%A" && set "line=!line:*:=!"
    if defined go (if #!line:~1!==#!go::=! (goto :EOF) else echo(!line!)
    if "!line:~0,13!"=="call :heredoc" (
        for /f "tokens=3 delims=>^ " %%i in ("!line!") do (
            if #%%i==#%1 (
                for /f "tokens=2 delims=&" %%I in ("!line!") do (
                    for /f "tokens=2" %%x in ("%%I") do set "go=%%x"
                )
            )
        )
    )
)
goto :EOF

出力例：

C:\Users\oithelp\Desktop>heredoc

\o/
 | This is the "stickman" heredoc, echoed to stdout.
/ \

Does the redirect to a file work?  Press any key to type out.txt and find out.

<html lang="en">
    <body>
        <h3>Hello world!</h3>
        <p>Lorem ipsum dolor sit amet, consectetur adipiscing elit.</p>
    </body>
</html>

Thus endeth the heredoc.  :)
29
rojo

はい、可能性は非常に高いです。 ^は文字通りのエスケープ文字であり、改行の前に置くだけです。この例では、ファイルに正しく出力されるように、追加の改行も挿入します。

@echo off
echo foo ^

this is ^

a multiline ^

echo > out.txt

出力：

E:\>type out.txt
foo
 this is
 a multiline
 echo

E:\>
19
esac
@echo off
 for /f "delims=:" %%a in (
     'findstr -n "^___" %0') do set "Line=%%a"

 (for /f "skip=%Line% tokens=* eol=_" %%a in (
       'type %0') do echo(%%a) > out.html
:: out.html
pause
goto: EOF



___DATA___
<!Doctype html>
<html>
  <head>
   title></title>
  </head>
  <body>
    <svg width="900" height="600">
        <text x="230" 
              y="150"
              font-size="100"
              fill="blue"
              stroke="gray"
              stroke-width="1">
                  Hello World              
        </text>
    </svg>
  </body>
</html>
9
walid2mi

DosTipsで、siberia-manは 誤ったGOTOステートメントの驚くべき動作 のデモンストレーションを(goto) 2>nulの形式で投稿しました。その後、Aaciniとjebは、奇妙な行動に関するいくつかの興味深い発見を記録しました。基本的にはEXIT /Bのように動作しますが、CALLedルーチン内の連結されたコマンドを親の呼び出し元のコンテキストで実行できる点が異なります。

これは、重要なポイントのほとんどを示す簡単なスクリプトです。

@echo off
setlocal enableDelayedExpansion
set "var=Parent Value"
(
  call :test
  echo This and the following line are not executed
  exit /b
)
:break
echo How did I get here^^!^^!^^!^^!
exit /b

:test
setlocal disableDelayedExpansion
set "var=Child Value"
(goto) 2>nul & echo var=!var! & goto :break
echo This line is not executed

:break
echo This line is not executed

-出力-

var=Parent Value
How did I get here!!!!

この驚くべき振る舞いにより、unixで利用できる多くのオプションを備えたヒアドキュメントのエレガントなバッチエミュレーションを書くことができました。 PrintHere.batを、PATH内にリストされているフォルダーに配置する必要があるスタンドアロンユーティリティとして実装しました。次に、任意のバッチスクリプトでユーティリティを簡単に呼び出してヒアドキュメント機能を取得できます。

使用法の一般的な構文は次のとおりです。

call PrintHere :Label
Here doc text goes here
:Label

どうすればこれを実現できますか？...私のPrintHereユーティリティは(GOTO) 2>nulトリックを2回使用します。

  • 初めて(GOTO) 2>nulを使用して呼び出し元に戻り、呼び出し元のスクリプトへのフルパスを取得して、PrintHereがどのファイルから読み取るかを認識できるようにします。次に、PrintHereにもう一度電話します。

  • 2回目は、(GOTO) 2>nulを使用して呼び出し元に戻り、終了ラベルをGOTOして、ヒアドキュメントテキストが実行されないようにします。

注-以下のスクリプトには、タブの定義の:startラベルのすぐ下にタブ文字（0x09）が含まれています。一部のブラウザでは、タブの表示とコピーが難しい場合があります。別の方法として、 DropboxからPrintHere.bat.txtをダウンロード 、名前をPrintHere.batに変更することもできます。

私は最初に投稿しました DosTipsのPrintHere.bat 、ここで将来の開発を追跡できます。

PrintHere.bat

@echo off & setlocal disableDelayedExpansion & goto :start
::PrintHere.bat version 1.1 by Dave Benham
:::
:::call PrintHere [/E] [/- "TrimList"] :Label ["%~f0"]
:::call PrintHere [/E] [/- "TrimList"] :Label "%~f0" | someCommand & goto :Label
:::PrintHere /?
:::PrintHere /V
:::
:::  PrintHere.bat provides functionality similar to the unix here doc feature.
:::  It prints all content between the CALL PrintHere :Label line and the
:::  terminating :Label. The :Label must be a valid label supported by GOTO, with
:::  the additional constraint that it not contain *. Lines are printed verbatim,
:::  with the following exceptions and limitations:
:::
:::    - Lines are lmited to 1021 bytes long
:::    - Trailing control characters are stripped from each line
:::
:::  The code should look something like the following:
:::
:::     call PrintHere :Label
:::         Spacing    and blank lines are preserved
:::
:::     Special characters like & < > | ^ ! % are printed normally
:::     :Label
:::
:::  If the /E option is used, then variables between exclamation points are
:::  expanded, and ! and ^ literals must be escaped as ^! and ^^. The limitations
:::  are different when /E is used:
:::
:::    - Lines are limited to ~8191 bytes long
:::    - All characters are preserved, except !variables! are expanded and ^! and
:::      ^^ are transformed into ! and ^
:::
:::  Here is an example using /E:
:::
:::     call PrintHere /E :SubstituteExample
:::       Hello !username!^!
:::     :SubstituteExample
:::
:::  If the /- "TrimList" option is used, then leading "TrimList" characters
:::  are trimmed from the output. The trim characters are case sensitive, and
:::  cannot include a quote. If "TrimList" includes a space, then it must
:::  be the last character in the list.
:::
:::  Multiple PrintHere blocks may be defined within one script, but each
:::  :Label must be unique within the file.
:::
:::  PrintHere must not be used within a parenthesized code block.
:::
:::  Scripts that use PrintHere must use \r\n for line termination, and all lines
:::  output by PrintHere will be terminated by \r\n.
:::
:::  All redirection associated with a PrintHere must appear at the end of the
:::  command. Also, the CALL can include path information:
:::
:::     call "c:\utilities\PrintHere.bat" :MyBlock>test.txt
:::       This line is written to test.txt
:::     :MyBlock
:::
:::  PrintHere may be used with a pipe, but only on the left side, and only
:::  if the source script is included as a 2nd argument, and the right side must
:::  explicitly and unconditionally GOTO the terminating :Label.
:::
:::     call PrintHere :PipedBlock "%~f0" | more & goto :PipedBlock
:::       text goes here
:::     :PipedBlock
:::
:::  Commands concatenated after PrintHere are ignored. For example:
:::
:::     call PrintHere :ignoreConcatenatedCommands & echo This ECHO is ignored
:::       text goes here
:::     :ignoreConcatenatedCommands
:::
:::  PrintHere uses FINDSTR to locate the text block by looking for the
:::  CALL PRINTHERE :LABEL line. The search string length is severely limited
:::  on XP. To minimize the risk of PrintHere failure when running on XP, it is
:::  recommended that PrintHere.bat be placed in a folder included within PATH
:::  so that the utility can be called without path information.
:::
:::  PrintHere /? prints out this documentation.
:::
:::  PrintHere /V prints out the version information
:::
:::  PrintHere.bat was written by Dave Benham. Devlopment history may be traced at:
:::    http://www.dostips.com/forum/viewtopic.php?f=3&t=6537
:::

:start
set "tab=   "   NOTE: This value must be a single tab (0x09), not one or more spaces
set "sp=[ %tab%=,;]"
set "sp+=%sp%%sp%*"
set "opt="
set "/E="
set "/-="

:getOptions
if "%~1" equ "" call :exitErr Invalid call to PrintHere - Missing :Label argument
if "%~1" equ "/?" (
  for /f "tokens=* delims=:" %%L in ('findstr "^:::" "%~f0"') do echo(%%L
  exit /b 0
)
if /i "%~1" equ "/V" (
  for /f "tokens=* delims=:" %%L in ('findstr /rc:"^::PrintHere\.bat version" "%~f0"') do echo(%%L
  exit /b 0
)
if /i %1 equ /E (
  set "/E=1"
  set "opt=%sp+%.*"
  shift /1
  goto :getOptions
)
if /i %1 equ /- (
  set "/-=%~2"
  set "opt=%sp+%.*"
  shift /1
  shift /1
  goto :getOptions
)
echo %1|findstr "^:[^:]" >nul || call :exitErr Invalid PrintHere :Label
if "%~2" equ "" (
  (goto) 2>nul
  setlocal enableDelayedExpansion
  if "!!" equ "" (
    endlocal
    call %0 %* "%%~f0"
  ) else (
    >&2 echo ERROR: PrintHere must be used within a batch script.
    (call)
  )
)
set ^"call=%0^"
set ^"label=%1^"
set "src=%~2"
setlocal enableDelayedExpansion
set "call=!call:\=[\\]!"
set "label=!label:\=[\\]!"
for %%C in (. [ $ ^^ ^") do (
  set "call=!call:%%C=\%%C!"
  set "label=!label:%%C=\%%C!"
)
set "search=!sp!*call!sp+!!call!!opt!!sp+!!label!"
set "cnt="
for /f "delims=:" %%N in ('findstr /brinc:"!search!$" /c:"!search![<>|&!sp:~1!" "!src!"') do if not defined skip set "skip=%%N"
if not defined skip call :exitErr Unable to locate CALL PrintHere %1
for /f "delims=:" %%N in ('findstr /brinc:"!sp!*!label!$" /c:"!sp!*!label!!sp!" "!src!"') do if %%N gtr %skip% if not defined cnt set /a cnt=%%N-skip-1
if not defined cnt call :exitErr PrintHere end label %1 not found
if defined /E (
  for /f "skip=%skip% delims=" %%L in ('findstr /n "^^" "!src!"') do (
    if !cnt! leq 0 goto :break
    set "ln=%%L"
    if not defined /- (echo(!ln:*:=!) else for /f "tokens=1* delims=%/-%" %%A in (^""%/-%!ln:*:=!") do (
      setlocal disableDelayedExpansion
      echo(%%B
      endlocal
    )
    set /a cnt-=1
  )
) else (
  for /l %%N in (1 1 %skip%) do set /p "ln="
  for /l %%N in (1 1 %cnt%) do (
    set "ln="
    set /p "ln="
    if not defined /- (echo(!ln!) else for /f "tokens=1* delims=%/-%" %%A in (^""%/-%!ln!") do (
      setlocal disableDelayedExpansion
      echo(%%B
      endlocal
    )
  )
) <"!src!"
:break
(goto) 2>nul & goto %~1


:exitErr
>&2 echo ERROR: %*
(goto) 2>nul & exit /b 1

完全なドキュメントはスクリプトに埋め込まれています。以下は、使用法のいくつかのデモンストレーションです。

逐語的な出力

@echo off
call PrintHere :verbatim
    Hello !username!^!
    It is !time! on !date!.
:verbatim

-出力-

    Hello !username!^!
    It is !time! on !date!.


変数の展開（遅延展開を有効にする必要はありません）

@echo off
call PrintHere /E :Expand
    Hello !username!^!
    It is !time! on !date!.
:Expand

- 出力 - 

    Hello Dave!
    It is 20:08:15.35 on Fri 07/03/2015.


変数を展開し、先頭のスペースを削除します

@echo off
call PrintHere /E /- " " :Expand
    Hello !username!^!
    It is !time! on !date!.
:Expand

- 出力 - 

Hello Dave!
It is 20:10:46.09 on Fri 07/03/2015.


出力をファイルにリダイレクトできます

@echo off
call PrintHere :label >helloWorld.bat
  @echo Hello world!
:label


出力を入力としてリダイレクトすることはできませんが、パイプすることはできます。残念ながら、構文はそれほど洗練されていません。 パイプの両側が新しいCMD.EXEプロセスで実行される したがって、(GOTO) 2>nulはマスタースクリプトではなく、子cmdプロセスに戻ります。 。

@echo off
call PrintHere :label "%~f0" | findstr "^" & goto :label
  Text content goes here
:label
6
dbenham

パラメータ付きのマクロ を使用すると、より簡単な方法で「ヒアドキュメント」を記述できます。

@echo off

rem Definition of heredoc macro
setlocal DisableDelayedExpansion
set LF=^


::Above 2 blank lines are required - do not remove
set ^"\n=^^^%LF%%LF%^%LF%%LF%^^"
set heredoc=for %%n in (1 2) do if %%n==2 (%\n%
       for /F "tokens=1,2" %%a in ("!argv!") do (%\n%
          if "%%b" equ "" (call :heredoc %%a) else call :heredoc %%a^>%%b%\n%
          endlocal ^& goto %%a%\n%
       )%\n%
    ) else setlocal EnableDelayedExpansion ^& set argv=


rem Heredoc syntax:
rem
rem %%heredoc%% :uniqueLabel [outfile]
rem contents
rem contents
rem ...
rem :uniqueLabel
rem
rem Same notes of rojo's answer apply

rem Example borrowed from rojo's answer:

set bodyText=Hello world!
set lipsum=Lorem ipsum dolor sit amet, consectetur adipiscing elit.

%heredoc% :endHtml out.txt
<html lang="en">
    <body>
        <h3>!bodyText!</h3>
        <p>!lipsum!</p>
    </body>
</html>
:endHtml

echo File created:
type out.txt
del out.txt
goto :EOF


rem Definition of heredoc subroutine

:heredoc label
set "skip="
for /F "delims=:" %%a in ('findstr /N "%1" "%~F0"') do (
   if not defined skip (set skip=%%a) else set /A lines=%%a-skip-1
)
for /F "skip=%skip% delims=" %%a in ('findstr /N "^" "%~F0"') do (
   set "line=%%a"
   echo(!line:*:=!
   set /A lines-=1
   if !lines! == 0 exit /B
)
exit /B
5
Aacini

@jeb

setlocal EnableDelayedExpansion
set LF=^


REM Two empty lines are required

別のバリアント：

@echo off

:)
setlocal enabledelayedexpansion
>nul,(pause&set /p LF=&pause&set /p LF=)<%0
set LF=!LF:~0,1!

echo 1!LF!2!LF!3

pause
3
walid2mi

https://stackoverflow.com/a/15032476/3627676 のrojoの投稿を参照してください

確かに、彼の解決策は私がしばらくの間探しているものです（もちろん、私はこれに似たものを実装しようとすることができますが、怠惰は進歩を動かします:)）。追加したいのは、元のコードのマイナーな改善です。ファイルへのリダイレクトを行末に書いておくといいと思いました。この場合、ヒアドキュメントのスターターラインはより厳密になり、分析はより簡単になります。

@echo off

set "hello=Hello world!"
set "lorem=Lorem ipsum dolor sit amet, consectetur adipiscing elit."

call :heredoc HTML & goto :HTML
<html>
<title>!hello!</title>
<body>
<p>Variables in heredoc should be surrounded by the exclamation mark (^!).</p>
<p>!lorem!</p>
<p>Exclamation mark (^!) and caret (^^) MUST be escaped with a caret (^^).</p>
</body>
</html>
:HTML

goto :EOF

:: https://stackoverflow.com/a/15032476/3627676
:heredoc LABEL
setlocal enabledelayedexpansion
set go=
for /f "delims=" %%A in ( '
    findstr /n "^" "%~f0"
' ) do (
    set "line=%%A"
    set "line=!line:*:=!"

    if defined go (
        if /i "!line!" == "!go!" goto :EOF
        echo:!line!
    ) else (
        rem delims are ( ) > & | TAB , ; = SPACE
        for /f "tokens=1-3 delims=()>&| ,;= " %%i in ( "!line!" ) do (
            if /i "%%i %%j %%k" == "call :heredoc %1" (
                set "go=%%k"
                if not "!go:~0,1!" == ":" set "go=:!go!"
            )
        )
    )
)
goto :EOF

このコードで何を示唆していますか？考えてみましょう。

Rojoのコードは非常に厳格です。

  • callと:heredocの間の文字列に複数の空白文字を使用することはできません
  • call :heredocは行の端に固定されています（行の先頭に空白は使用できません）
  • ファイルへのリダイレクトは行内のどこかで許可されています（あまり役に立ちません）-

私が提案していること：

  • それほど厳密ではありません（区切り文字として複数の空白）
  • ファイルへのリダイレクトは行末でのみ許可されます（角かっこは許可され、必要です）
  • 行の端にスティッキーコードはありません

更新1：ヒアドキュメントの開始のチェックと実行の改善：

  • 重要なコマンドはcall :heredoc LABELまたはcall :heredoc :LABELのみです。したがって、ヒアドキュメントのコンテンツを印刷した後、別のラベルにジャンプしたり、スクリプトを終了したり、exit /bを実行したりすることができます。
  • 未使用の不要なコマンドgoto：next2を削除しました

アップデート2：

  • 内部forの区切り文字は()>&|TAB,;=SPACE
  • スイッチ/Iがifに追加されました

アップデート3：

次のリンクから、スタンドアロンスクリプトのフルバージョンを見つけることができます（スクリプトへの埋め込みが可能です） https://github.com/ildar-shaimordanov/tea-set/blob/master/bin/heredoc。バット

3
jsxt

私が最高だと思うephemientpostを拡張すると、次のようになります。

(
    @echo.line1
    @echo.line2 %time% %os%
    @echo.
    @echo.line4
) | more

Ephemientの投稿では、彼は最初にリダイレクトしました。これはニーススタイルですが、最後にリダイレクトすることもできます。

(
    @echo.line1
    @echo.line2 %time% %os%
    @echo.
    @echo.line4
) >C:\Temp\test.txt

「@echo」に注意してください。出力と「@echo」に含まれることはありません。それ自体で空白行が表示されます。

2
Michael Erickson

FOR/Fループを使用して引用符で囲まれたテキストのブロックを作成できるため、_<>|&_のような特殊文字をエスケープする必要はなく、_%_のみをエスケープする必要があります。
これは、html出力を作成する場合のように役立つ場合があります。

_@echo off
setlocal EnableDelayedExpansion
set LF=^


REM Two empty lines are required
set ^"NL=^^^%LF%%LF%^%LF%%LF%^^"

for /F "tokens=* delims=_" %%a in (^"%NL%
___"One<>&|"%NL%
___"two 100%%"%NL%
___%NL%
___"three "quoted" "%NL%
___"four"%NL%
") DO (
   @echo(%%~a
)
_

出力

_One<>&|
two 100%

three "quoted"
four
_

コードを説明しようと思います。 LF変数には1つの改行文字が含まれ、NL変数には_^<LF><LF>^_が含まれます。
これをパーセント展開とともに使用して、行末に1つの改行文字と1つのキャレットを配置できます。

通常、FOR/Fは、引用されたテキストを複数のトークンに分割しますが、1回だけです。
改行文字を挿入すると、FORループも複数の行に分割されます。
最初と最後の行の引用符は、FORループの正しい構文を作成するためだけのものです。

最初の文字が前の行の複数行キャレットからエスケープされるため、任意の行の先頭には___があり、引用符が最初の文字である場合、エスケープ機能が失われます。
スペースまたはコンマがXPで問題を引き起こすため、___ delimsが使用されます（そうでない場合、XP-Bugスプリアスはガベージファイル名にアクセスしようとします）。

ラインエンドのキャレットもXP-Bugに対してのみです。

XP-Bugは、引用符で囲まれたテキストに引用符で囲まれていない_,;=<space>_文字が含まれている場合に有効になります

_for /f "tokens=*" %%a in ("a","b","c") do echo %%a
_
2
jeb
@echo off
cls
title Drop Bomb
echo/
echo/ creating...
::                                   Creating a batchfile from within a batchfile.
echo @echo off > boom.bat
echo cls      >> boom.bat
echo color F0 >> boom.bat
echo echo/    >> boom.bat
echo echo --- B-O-O-M !!! --- >> boom.bat
echo echo/    >> boom.bat
echo pause    >> boom.bat
echo exit     >> boom.bat
::                                     Now lets set it off
start boom.bat
title That hurt my ears.
cls
echo/
echo - now look what you've done!
pause
2
InterociterOperator

これは、ephemientの優れたソリューションのバリエーションです。これにより、実際にテキストファイルを作成して入力し、プログラムにリダイレクトすることなく、複数の行を別のプログラムにパイプ処理できます。

(@echo.bla
@echo.bla
) | yourprog.exe

簡単で実用的な例として、yourprog.exeをmoreに置き換えることができます。

(@echo.bla
@echo.bla
) | more

出力：

bla
bla
1
B. Reynolds

Microsoft NMakemakefileでは、スレッドの所有者が要求したとおり、true NIXヒアドキュメントを使用できます。たとえば、これはファイルを作成するための明示的なルールですDeploy.sed：

Deploy.sed:
    type << >$@
; -*-ini-generic-*-
;
; Deploy.sed -- Self-Extracting Directives
;

[Version]
Class=IEXPRESS
SEDVersion=3
    .
    .
[Strings]
InstallPrompt=Install $(NAME)-$(VERSION).xll to your personal XLSTART directory?
DisplayLicense=H:\prj\prog\XLL\$(NAME)\README.txt
    .
    .
<<

clean:
    -erase /Q Deploy.sed

ここで、<<は、ルールの実行時にNMakeがオンザフライで作成する一時ファイル名に展開されます。つまり、Deploy.sedが存在しない場合です。良い点は、NMake変数も展開されることです（ここでは、変数[〜＃〜] name [〜＃〜]および[〜＃〜]バージョン[〜＃〜]）。これをmakefileとして保存します。 makefileのディレクトリにあるDOSボックスを開き、次を使用します。

> nmake Deploy.sed

ファイルを作成するには、次のようにします。

> nmake clean

それを削除します。 NMakeは、Expressエディションを含む、Visual Studio C++のすべてのバージョンの一部です。

1
Andreas Spindler

このコードを試してください。 （下部のJScriptコードは「out.html」をディスクに書き込みます）

@if(0)==(0) echo on
cscript.exe //nologo //E:JScript "%~f0" source1 out.html
start out.html
goto :EOF

[source1]
<!DOCTYPE html>
<html>
  <head>
   title></title>
  </head>
  <body>
    <svg width="900" height="600">
        <text x="230" 
              y="150"
              font-size="100"
              fill="blue"
              stroke="gray"
              stroke-width="1">
                  Hello World              
        </text>
    </svg>
  </body>
</html>
[/source1]

@end

if (WScript.Arguments.length != 2) WScript.Quit();
var tagName = WScript.Arguments(0);
var path    = WScript.Arguments(1);
var startTag = "[" + tagName + "]"
var endTag   = "[/" + tagName + "]"
var fso = new ActiveXObject("Scripting.FileSystemObject");
var file1 = fso.OpenTextFile(WScript.ScriptFullName);
var txt = "";
var found = false;
while (!file1.AtEndOfStream) {
  var line = file1.ReadLine();
  if (!found) {
    if (line.lastIndexOf(startTag, 0) === 0) found = true;
  } else {
    if (line.lastIndexOf(endTag, 0) === 0) break;
    txt += line + "\n";
  }
}
file1.Close();
var file2 = fso.CreateTextFile(path, true, false);
file2.Write(txt);
file2.Close();
0
javacommons

OPが望んでいたのは非常に具体的なもの（出力を含むテキストファイルの作成）であり、受け入れられた回答はそれを完全に実行しますが、提示されたソリューションはその特定のコンテキスト外ではうまく機能しません。たとえば、複数行の入力をコマンドに渡したい場合、( echo )構文を使用できません。これが私のために働いた結果です。

以下で構成される「echolines.pl」という名前のPerlスクリプトがあるとします（「実際の」プログラムをシミュレートするため）。

use strict;
use warnings;

while (<>) {
        chomp;
        print qq(<$_>\n);
}

および「testme.bat」という名前のバッチファイルには、次のものが含まれています。

@echo off

set FOO=foo
set BAR=bar
set BAZ=baz

echo %FOO%^
&echo %BAR%^
&echo %BAZ%|Perl echolines.pl

それを実行すると、期待される出力が生成されます。

C:\>testme
<foo>
<bar>
<baz>

空白に注意して、空白がなくてもすべてが正しく機能するようにする必要があります。具体的には、各行の終わりはキャレット（^）の後に改行を続ける必要があり、後続の行はアンパサンド（＆）ですぐに開始する必要があり、最後の行は送信される最後のアイテムの直後にパイプを開始する必要があります。これを怠ると、パラメーターが欠落したり、パラメーターの前後に余分な空白が生じたりします。

0
Joe Casadonte