web-dev-qa-db-ja.com

ダイアログを開いてファイルパスを選択するVBScript

現在、次のようにvbscriptでファイルを開いています。

strFile = "C:\Users\test\file.txt"
Set objFile = objFSO.OpenTextFile(strFile)

これを変更して、ユーザーがファイルを選択/ナビゲートできるようにし、そのファイルをスクリプトで使用します。この機能を追加するにはどうすればよいですか？ VBScriptでどのように完了するかわからないだけで、ファイルダイアログをロードする方法/ファイルをユーザーに要求する方法などを検索しようとしました。

vbavbscriptfilepath
8
StuartM

私が興味深いと思った別の解決策があります MS TechNet より少ないカスタマイズですが、あなたが達成したいものを得ます。選択したファイルの完全パスを返します。

Set wShell=CreateObject("WScript.Shell")
Set oExec=wShell.Exec("mshta.exe ""about:<input type=file id=FILE><script>FILE.click();new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).WriteLine(FILE.value);close();resizeTo(0,0);</script>""")
sFileSelected = oExec.StdOut.ReadLine
wscript.echo sFileSelected
25
PatricK

どうぞ：

http://www.robvanderwoude.com/vbstech_ui_fileopen.php

strFile = GetFileName("C:\Users\test\", "Text files|*.txt")
Set objFile = objFSO.OpenTextFile(strFile)

Function GetFileName( myDir, myFilter )
  ' Written by Rob van der Woude
  ' http://www.robvanderwoude.com

  ' Standard Housekeeping
  Dim objDialog

  ' Create a dialog object
  Set objDialog = CreateObject( "UserAccounts.CommonDialog" )

  ' Check arguments and use defaults when necessary
  If myDir = "" Then
    ' Default initial folder is "My Documents"
    objDialog.InitialDir = CreateObject( "WScript.Shell" ).SpecialFolders( "MyDocuments" )
  Else
    ' Use the specified initial folder
    objDialog.InitialDir = myDir
  End If
  If myFilter = "" Then
    ' Default file filter is "All files"
    objDialog.Filter = "All files|*.*"
  Else
    ' Use the specified file filter
    objDialog.Filter = myFilter
  End If

  ' Open the dialog and return the selected file name
  If objDialog.ShowOpen Then
    GetFileName = objDialog.FileName
  Else
    GetFileName = ""
  End If
End Function
3
Nathan Rice

VBSEditプログラムは、COMライブラリVBSEdit Toolkitをインストールします。これにより、[ファイルを開く]ダイアログが可能になります。

VBSEditヘルプから：

Dialog boxes 
OpenFileDialog method
Prompt the user to open a file
toolkit.OpenFileDialog ([initialFolder,[filters,[multiselect,[title]]]]) 

'Opens a single file
Set toolkit = CreateObject("VbsEdit.Toolkit")
files=toolkit.OpenFileDialog("c:\scripts\","Text Files (*.txt)|*.txt",False,"Open a text file")
If UBound(files)>=0 Then
  WScript.Echo files(0)
Else
  Wscript.Quit
End If

'Opens multiple files
Set toolkit = CreateObject("VbsEdit.Toolkit")
files=toolkit.OpenFileDialog("c:\scripts\","Text Files (*.txt)|*.txt",True,"Open a text file")
If UBound(files)>=0 Then
  For Each filepath In files
    WScript.Echo filepath
  Next
Else
  Wscript.Quit
End If



SaveFileDialog method
Prompt the user to save a file
toolkit.SaveFileDialog ([initialFolder,[initialFilename,[filters,[title]]]]) 

Set toolkit = CreateObject("VbsEdit.Toolkit")
filepath = toolkit.SaveFileDialog("c:\scripts","test.txt","Text Files (*.txt)|*.txt")

If Not(IsNull(filepath)) Then
  Set objFSO = CreateObject("Scripting.FileSystemObject")
  Set objFile = objFSO.CreateTextFile(filepath,True)
  objFile.WriteLine Date
  objFile.Close
Else
  Wscript.Quit
End If



SelectFolder method
Prompt the user to select a folder
toolkit.SelectFolder ([initialDir,[title]]) 

Set toolkit = CreateObject("VbsEdit.Toolkit")
myfolder=toolkit.SelectFolder("c:\scripts\","Please select a folder")

If Not(IsNull(myfolder)) Then
  WScript.Echo myfolder
Else
  Wscript.Quit
End If

…

（実際には、VBSEditツールキットがなくても、Shell.ApplicationオブジェクトのBrowseForFolderメソッドを使用して、フォルダー選択ダイアログを開くことができます。）

0
Hermolaou