web-dev-qa-db-ja.com

MS Accessフォームとクラス/モジュールをテキストファイルに再帰的にエクスポートしますか?

クラス、モジュール、フォームからすべてのVBAコードをうまくエクスポートする古いメッセージボード上のコードを見つけました(以下を参照)。

Option Explicit
Option Compare Database
Function SaveToFile()                  'Save the code for all modules to files in currentDatabaseDir\Code

Dim Name As String
Dim WasOpen As Boolean
Dim Last As Integer
Dim I As Integer
Dim TopDir As String, Path As String, FileName As String
Dim F As Long                          'File for saving code
Dim LineCount As Long                  'Line count of current module

I = InStrRev(CurrentDb.Name, "\")
TopDir = VBA.Left(CurrentDb.Name, I - 1)
Path = TopDir & "\" & "Code"           'Path where the files will be written

If (Dir(Path, vbDirectory) = "") Then
  MkDir Path                           'Ensure this exists
End If

'--- SAVE THE STANDARD MODULES CODE ---

Last = Application.CurrentProject.AllModules.Count - 1

For I = 0 To Last
  Name = CurrentProject.AllModules(I).Name
  WasOpen = True                       'Assume already open

  If Not CurrentProject.AllModules(I).IsLoaded Then
    WasOpen = False                    'Not currently open
    DoCmd.OpenModule Name              'So open it
  End If

  LineCount = Access.Modules(Name).CountOfLines
  FileName = Path & "\" & Name & ".vba"

  If (Dir(FileName) <> "") Then
    Kill FileName                      'Delete previous version
  End If

  'Save current version
  F = FreeFile
  Open FileName For Output Access Write As #F
  Print #F, Access.Modules(Name).Lines(1, LineCount)
  Close #F

  If Not WasOpen Then
    DoCmd.Close acModule, Name         'It wasn't open, so close it again
  End If
Next

'--- SAVE FORMS MODULES CODE ---

Last = Application.CurrentProject.AllForms.Count - 1

For I = 0 To Last
  Name = CurrentProject.AllForms(I).Name
  WasOpen = True

  If Not CurrentProject.AllForms(I).IsLoaded Then
    WasOpen = False
    DoCmd.OpenForm Name, acDesign
  End If

  LineCount = Access.Forms(Name).Module.CountOfLines
  FileName = Path & "\" & Name & ".vba"

  If (Dir(FileName) <> "") Then
    Kill FileName
  End If

  F = FreeFile
  Open FileName For Output Access Write As #F
  Print #F, Access.Forms(Name).Module.Lines(1, LineCount)
  Close #F

  If Not WasOpen Then
    DoCmd.Close acForm, Name
  End If
Next
MsgBox "Created source files in " & Path
End Function

ただし、110ミリ秒のアクセス*.mdbがあり、vbaをgrepに適したテキストファイルにエクスポートする必要があるため、このコードでは問題は解決しません。

私が興味を持っている110個のファイルへのパスはすでにテーブルに格納されており、私のコードはすでにこの情報を(他のフィルタリングとともに)再帰的に取得しています...したがって、再帰的な部分は完了です。

これらのファイルのほとんどは、シングルアクセスユーザーセキュリティファイル.mdwによって開かれ、私はそれらを開くいくつかの方法を試しました。 ADOそしてADOXは、これらのディレクトリでリンクされたテーブルを検索していたときにうまく機能しました...しかし、上記のコードには データのエクスポート元のデータベース内にある 、そして、すべてのmdbsを開き、それぞれでエクスポートを実行する個別のデータベースからこれを実行できるようにしたいと思います。

これに対する私の試みの1つは、PrivDBEngineクラスを使用してデータベースに外部から接続することでしたが、上記のエクスポートコードで必要なApplicationオブジェクトにアクセスできません。

Private Sub exportToFile(db_path As String, db_id As String, loginInfo As AuthInfoz, errFile As Variant)

    Dim pdbeNew As PrivDBEngine
    Dim db As DAO.Database
    Dim ws As DAO.Workspace
    Dim rst As DAO.Recordset

    Dim cn As ADODB.Connection ' ADODB.Connection
    Dim rs As ADODB.Recordset ' ADODB.Recordset
    Dim strConnect As String
    Dim blnReturn As Boolean

    Dim Doc              As Document
    Dim mdl              As Module
    Dim lngCount         As Long
    Dim strForm          As String
    Dim strOneLine       As String
    Dim sPtr             As Integer

    Set fso = CreateObject("Scripting.FileSystemObject")
    Set exportFile = fso.CreateTextFile("E:\Tickets\CSN1006218\vbacode\" & db_id & ".txt", ForAppending)

    ' Export stuff...

    On Error GoTo errorOut

    Set pdbeNew = New PrivDBEngine
    With pdbeNew
        .SystemDB = loginInfo.workgroup
        .DefaultUser = loginInfo.username
        .DefaultPassword = loginInfo.password
    End With


    Set ws = pdbeNew.Workspaces(0)


    Set db = ws.OpenDatabase(db_path)

    For Each Doc In db.Containers("Modules").Documents
        DoCmd.OpenModule Doc.Name
        Set mdl = Modules(Doc.Name)

        exportFile.WriteLine ("---------------------")
        exportFile.WriteLine ("Module Name: " & Doc.Name)
        exportFile.WriteLine ("Module Type: " & mdl.Type)
        exportFile.WriteLine ("---------------------")

        lngCount = lngCount + mdl.CountOfLines

        'For i = 1 To lngCount
        '    strOneLine = mdl.Lines(i, 1)
        '    exportFile.WriteLine (strOneLine)
        'Next i

        Set mdl = Nothing
        DoCmd.Close acModule, Doc.Name
    Next Doc

Close_n_exit:

    If Not (db Is Nothing) Then
        Call wk.Close
        Set wk = Nothing
        Call db.Close
    End If



    Call exportFile.Close
    Set exportFile = Nothing
    Set fso = Nothing

    Exit Sub

errorOut:
    Debug.Print "----------------"
    Debug.Print "BEGIN: Err"
    If err.Number <> 0 Then
        Msg = "Error # " & Str(err.Number) & " was generated by " _
         & err.Source & Chr(13) & "Error Line: " & Erl & Chr(13) & err.Description
        'MsgBox Msg, , "Error", err.HelpFile, err.HelpContext
        Debug.Print Msg
    End If
    Resume Close_n_exit

End Sub

とにかくapplicationからPrivDBEngineオブジェクトにアクセスする方法はありますか? grepを必要とするモジュールがたくさんあります。

17
leeand00

このコードを試すこともできます。アイテムのファイルタイプ(.bas、.cls、.frm)を保持します。参照/チェックを忘れないでくださいMicrosoft Visual Basic For Applications拡張性ライブラリ in VBE>ツール>参照 ==

Public Sub ExportAllCode()

    Dim c As VBComponent
    Dim Sfx As String

    For Each c In Application.VBE.VBProjects(1).VBComponents
        Select Case c.Type
            Case vbext_ct_ClassModule, vbext_ct_Document
                Sfx = ".cls"
            Case vbext_ct_MSForm
                Sfx = ".frm"
            Case vbext_ct_StdModule
                Sfx = ".bas"
            Case Else
                Sfx = ""
        End Select

        If Sfx <> "" Then
            c.Export _
                Filename:=CurrentProject.Path & "\" & _
                c.Name & Sfx
        End If
    Next c

End Sub
26

Access.Applicationオブジェクトを使用できます。

また、データベースを開くときに複数の確認ダイアログが表示されないようにするには、[ツール]、[マクロ]、[セキュリティ]でセキュリティレベルを変更するだけです。

また、ユーザー/パスワードで複数のデータベースを開くには、ワークグループ(ツール/セキュリティ/ワークグループ管理者)に参加し、目的のユーザー/パスワード(SaveToFile関数を使用してデータベースから)でログインしてから、コードを実行します。後で、デフォルトのワークグループに参加することを忘れないでください(存在しないワークグループに参加しようとすると、アクセスがデフォルトに戻ります)。

Option Explicit
Option Compare Database


'Save the code for all modules to files in currentDatabaseDir\Code
Public Function SaveToFile()

   On Error GoTo SaveToFile_Err

   Dim Name As String
   Dim WasOpen As Boolean
   Dim Last As Integer
   Dim i As Integer
   Dim TopDir As String, Path As String, FileName As String
   Dim F As Long                          'File for saving code
   Dim LineCount As Long                  'Line count of current module

   Dim oApp As New Access.Application

   ' Open remote database
   oApp.OpenCurrentDatabase ("D:\Access\myDatabase.mdb"), False


   i = InStrRev(oApp.CurrentDb.Name, "\")
   TopDir = VBA.Left(oApp.CurrentDb.Name, i - 1)
   Path = TopDir & "\" & "Code"           'Path where the files will be written

   If (Dir(Path, vbDirectory) = "") Then
      MkDir Path                           'Ensure this exists
   End If

   '--- SAVE THE STANDARD MODULES CODE ---

   Last = oApp.CurrentProject.AllModules.Count - 1

   For i = 0 To Last
      Name = oApp.CurrentProject.AllModules(i).Name
      WasOpen = True                       'Assume already open

         If Not oApp.CurrentProject.AllModules(i).IsLoaded Then
            WasOpen = False                    'Not currently open
            oApp.DoCmd.OpenModule Name              'So open it
         End If

      LineCount = oApp.Modules(Name).CountOfLines
      FileName = Path & "\" & Name & ".vba"

      If (Dir(FileName) <> "") Then
        Kill FileName                      'Delete previous version
      End If

      'Save current version
      F = FreeFile
      Open FileName For Output Access Write As #F
      Print #F, oApp.Modules(Name).Lines(1, LineCount)
      Close #F

      If Not WasOpen Then
         oApp.DoCmd.Close acModule, Name         'It wasn't open, so close it again
      End If
   Next

   '--- SAVE FORMS MODULES CODE ---

   Last = oApp.CurrentProject.AllForms.Count - 1

   For i = 0 To Last
      Name = oApp.CurrentProject.AllForms(i).Name
      WasOpen = True

      If Not oApp.CurrentProject.AllForms(i).IsLoaded Then
         WasOpen = False
         oApp.DoCmd.OpenForm Name, acDesign
      End If

      LineCount = oApp.Forms(Name).Module.CountOfLines
      FileName = Path & "\" & Name & ".vba"

      If (Dir(FileName) <> "") Then
         Kill FileName
      End If

      F = FreeFile
      Open FileName For Output Access Write As #F
      Print #F, oApp.Forms(Name).Module.Lines(1, LineCount)
      Close #F

      If Not WasOpen Then
         oApp.DoCmd.Close acForm, Name
      End If
   Next

   '--- SAVE REPORTS MODULES CODE ---

   Last = oApp.CurrentProject.AllReports.Count - 1

   For i = 0 To Last
      Name = oApp.CurrentProject.AllReports(i).Name
      WasOpen = True

      If Not oApp.CurrentProject.AllReports(i).IsLoaded Then
         WasOpen = False
         oApp.DoCmd.OpenReport Name, acDesign
      End If

      LineCount = oApp.Reports(Name).Module.CountOfLines
      FileName = Path & "\" & Name & ".vba"

      If (Dir(FileName) <> "") Then
         Kill FileName
      End If

      F = FreeFile
      Open FileName For Output Access Write As #F
      Print #F, oApp.Reports(Name).Module.Lines(1, LineCount)
      Close #F

      If Not WasOpen Then
         oApp.DoCmd.Close acReport, Name
      End If
   Next

   MsgBox "Created source files in " & Path

   ' Reset the security level
   Application.AutomationSecurity = msoAutomationSecurityByUI

SaveToFile_Exit:

   If Not oApp.CurrentDb Is Nothing Then oApp.CloseCurrentDatabase
   If Not oApp Is Nothing Then Set oApp = Nothing
   Exit function

SaveToFile_Err:

   MsgBox ("Error " & Err.Number & vbCrLf & Err.Description)
   Resume SaveToFile_Exit

End Function

レポートモジュールのコードを追加しました。時間があれば、コードをリファクタリングしようとします。

これは大きな貢献だと思います。共有していただきありがとうございます。

よろしく

=================編集==================

しばらくして、データベース全体(テーブルとクエリを含む)をエクスポートする方法を見つけ、Gitのバージョン管理に使用しました。

もちろん、本当に大きなテーブルがある場合、本当に必要なのはバックアップです。これは、開発目的でのみ、初期状態のテーブルで使用します。テーブルの多くは空です。

         Option Compare Database
         Option Explicit

  Private Const VB_MODULE               As Integer = 1
  Private Const VB_CLASS                As Integer = 2
  Private Const VB_FORM                 As Integer = 100
  Private Const EXT_TABLE               As String = ".tbl"
  Private Const EXT_QUERY               As String = ".qry"
  Private Const EXT_MODULE              As String = ".bas"
  Private Const EXT_CLASS               As String = ".cls"
  Private Const EXT_FORM                As String = ".frm"
  Private Const CODE_FLD                As String = "code"

  Private Const mblnSave                As Boolean = True               ' False: just generate the script
'
'

Public Sub saveAllAsText()

            Dim oTable                  As TableDef
            Dim oQuery                  As QueryDef
            Dim oCont                   As Container
            Dim oForm                   As Document
            Dim oModule                 As Object
            Dim FSO                     As Object

            Dim strPath                 As String
            Dim strName                 As String
            Dim strFileName             As String

'**
    On Error GoTo errHandler

    strPath = CurrentProject.path
    Set FSO = CreateObject("Scripting.FileSystemObject")
    strPath = addFolder(FSO, strPath, Application.CurrentProject.name & "_" & CODE_FLD)
    strPath = addFolder(FSO, strPath, Format(Date, "yyyy.mm.dd"))


    For Each oTable In CurrentDb.TableDefs
        strName = oTable.name
        If left(strName, 4) <> "MSys" Then
            strFileName = strPath & "\" & strName & EXT_TABLE
            If mblnSave Then Application.ExportXML acExportTable, strName, strFileName, strFileName & ".XSD", strFileName & ".XSL", , acUTF8, acEmbedSchema + acExportAllTableAndFieldProperties
            Debug.Print "Application.ImportXML """ & strFileName & """, acStructureAndData"
        End If
    Next

    For Each oQuery In CurrentDb.QueryDefs
        strName = oQuery.name
        If left(strName, 1) <> "~" Then
            strFileName = strPath & "\" & strName & EXT_QUERY
            If mblnSave Then Application.SaveAsText acQuery, strName, strFileName
            Debug.Print "Application.LoadFromText acQuery, """ & strName & """, """ & strFileName & """"
        End If
    Next

    Set oCont = CurrentDb.Containers("Forms")
    For Each oForm In oCont.Documents
        strName = oForm.name
        strFileName = strPath & "\" & strName & EXT_FORM
        If mblnSave Then Application.SaveAsText acForm, strName, strFileName
        Debug.Print "Application.LoadFromText acForm, """ & strName & """, """ & strFileName & """"
    Next

    strPath = addFolder(FSO, strPath, "modules")
    For Each oModule In Application.VBE.ActiveVBProject.VBComponents
        strName = oModule.name
        strFileName = strPath & "\" & strName
        Select Case oModule.Type
            Case VB_MODULE
                If mblnSave Then oModule.Export strFileName & EXT_MODULE
                Debug.Print "Application.VBE.ActiveVBProject.VBComponents.Import """ & strFileName & EXT_MODULE; """"
            Case VB_CLASS
                If mblnSave Then oModule.Export strFileName & EXT_CLASS
                Debug.Print "Application.VBE.ActiveVBProject.VBComponents.Import """ & strFileName & EXT_CLASS; """"
            Case VB_FORM
                ' Do not export form modules (already exported the complete forms)
            Case Else
                Debug.Print "Unknown module type: " & oModule.Type, oModule.name
        End Select
    Next

    If mblnSave Then MsgBox "Files saved in  " & strPath, vbOKOnly, "Export Complete"

Exit Sub

errHandler:
    MsgBox "Error " & Err.Number & ": " & Err.Description & vbCrLf
    Stop: Resume

End Sub
'

'
' Create a folder when necessary. Append the folder name to the given path.
'
Private Function addFolder(ByRef FSO As Object, ByVal strPath As String, ByVal strAdd As String) As String
    addFolder = strPath & "\" & strAdd
    If Not FSO.FolderExists(addFolder) Then MkDir addFolder
End Function
'
11
Clon

MS Excelの場合と同様に、Application.VBE.VBProjects(1).VBComponentsでループを使用し、Exportメソッドを使用してモジュール/クラス/フォームをエクスポートすることもできます。

Const VB_MODULE = 1
Const VB_CLASS = 2
Const VB_FORM = 100
Const EXT_MODULE = ".bas"
Const EXT_CLASS = ".cls"
Const EXT_FORM = ".frm"
Const CODE_FLD = "Code"

Sub ExportAllCode()

Dim fileName As String
Dim exportPath As String
Dim ext As String
Dim FSO As Object

Set FSO = CreateObject("Scripting.FileSystemObject")
' Set export path and ensure its existence
exportPath = CurrentProject.path & "\" & CODE_FLD
If Not FSO.FolderExists(exportPath) Then
    MkDir exportPath
End If

' The loop over all modules/classes/forms
For Each c In Application.VBE.VBProjects(1).VBComponents
    ' Get the filename extension from type
    ext = vbExtFromType(c.Type)
    If ext <> "" Then
        fileName = c.name & ext
        debugPrint "Exporting " & c.name & " to file " & fileName
        ' THE export
        c.Export exportPath & "\" & fileName
    Else
        debugPrint "Unknown VBComponent type: " & c.Type
    End If
Next c

End Sub

' Helper function that translates VBComponent types into file extensions
' Returns an empty string for unknown types
Function vbExtFromType(ByVal ctype As Integer) As String
    Select Case ctype
        Case VB_MODULE
            vbExtFromType = EXT_MODULE
        Case VB_CLASS
            vbExtFromType = EXT_CLASS
        Case VB_FORM
            vbExtFromType = EXT_FORM
    End Select
End Function

実行にかかる時間はほんの一瞬です。

乾杯

5
sebastian

素敵な答えクロン。

スタートアップフォームおよび/またはAutoExecマクロ以上のMDBを開こうとしている場合、わずかな違いが常に確実に機能するとは限りません。

別のウェブサイトでこの回答を見てください: スタートアップフォーム/マクロをバイパス そして議論のほぼ最後までスクロールすると、スタートアップフォームの設定が一時的に削除され、AutoExecマクロがデータベースに抽出されますTempAutoExecマクロ(何もしない)で上書きする前に、いくつかの作業を行います(行間 'コマンドバーapp.CloseCurrentDatabase)その後、すべてを再度修正します。

2
dmc2005

IDKは、これまで誰もこれを提案しなかった理由ですが、これに使用する小さなコードを次に示します。非常にシンプルでわかりやすい

Public Sub VBAExportModule()
    On Error GoTo Errg
    Dim rs As DAO.Recordset
    Set rs = CurrentDb.OpenRecordset("SELECT MSysObjects.Name FROM MSysObjects WHERE Type=-32761", dbOpenDynaset, dbSeeChanges)

    Do Until rs.EOF
        Application.SaveAsText acModule, rs("Name"), "C:\" & rs("Name") & ".txt"
        rs.MoveNext
    Loop

Cleanup:
    If Not rs Is Nothing Then rs.Close
    Set rs = Nothing
    Exit Sub
Errg:
    GoTo Cleanup
End Sub
2
Doug Coats

もう1つの方法は、最も使用されるコードを1つの外部master.mdbに保持し、それを任意の数の* .mdbsトラフモジュール->ツール->参照->参照-> ...\master.mdbに結合することです。

古い97Accessの唯一の問題は、destination.mdbで直接デバッグ、編集、保存できますが、すべての新しいでは、MA 2000以降、[保存]オプションがなくなり、保存されていないコードを閉じる際の警告が表示されます。

0
MartiniB