web-dev-qa-db-ja.com

VBAを使用してtxtファイルを作成して書く方法

入力に基づいて手動で追加または変更されたファイルがあります。そのファイルでは内容のほとんどが反復的なので、16進値だけが変化しているので、私はそれをツール生成ファイルにしたいです。

その。txtファイルに出力されるcコードを書きたいのです。

VBAを使用して。txtファイルを作成するためのコマンドは何ですか。

vbatext-files
101
danny

FSOを使用してファイルを作成して書き込みます。

Dim fso as Object
Set fso = CreateObject("Scripting.FileSystemObject")
Dim oFile as Object
Set oFile = FSO.CreateTextFile(strPath)
oFile.WriteLine "test" 
oFile.Close
Set fso = Nothing
Set oFile = Nothing

こちらのドキュメントを参照してください。

154
Ben
Open ThisWorkbook.Path & "\template.txt" For Output As #1
Print #1, strContent
Close #1

詳しくは：

28
Bhanu Sinha

冗長性をあまり持たない簡単な方法です。

    Dim fso As Object
    Set fso = CreateObject("Scripting.FileSystemObject")

    Dim Fileout As Object
    Set Fileout = fso.CreateTextFile("C:\your_path\vba.txt", True, True)
    Fileout.Write "your string goes here"
    Fileout.Close
28
pelos

ベンの答えを詳しく述べると ：

Microsoft Scripting Runtimeへの参照を追加して、変数fsoを正しく入力すると、自動補完を利用することができます（Intellisense） FileSystemObjectの優れた機能。

これが完全なサンプルモジュールです。

Option Explicit

' Go to Tools -> References... and check "Microsoft Scripting Runtime" to be able to use
' the FileSystemObject which has many useful features for handling files and folders
Public Sub SaveTextToFile()

    Dim filePath As String
    filePath = "C:\temp\MyTestFile.txt"

    ' The advantage of correctly typing fso as FileSystemObject is to make autocompletion
    ' (Intellisense) work, which helps you avoid typos and lets you discover other useful
    ' methods of the FileSystemObject
    Dim fso As FileSystemObject
    Set fso = New FileSystemObject
    Dim fileStream As TextStream

    ' Here the actual file is created and opened for write access
    Set fileStream = fso.CreateTextFile(filePath)

    ' Write something to the file
    fileStream.WriteLine "something"

    ' Close it, so it is not locked anymore
    fileStream.Close

    ' Here is another great method of the FileSystemObject that checks if a file exists
    If fso.FileExists(filePath) Then
        MsgBox "Yay! The file was created! :D"
    End If

    ' Explicitly setting objects to Nothing should not be necessary in most cases, but if
    ' you're writing macros for Microsoft Access, you may want to uncomment the following
    ' two lines (see https://stackoverflow.com/a/517202/2822719 for details):
    'Set fileStream = Nothing
    'Set fso = Nothing

End Sub
19
Marcus Mangelsdorf