web-dev-qa-db-ja.com

VBScriptのクリップボードを使用する

VBScript を使用してクリップボードにテキストを配置する方法を探しています。問題のVBScriptは、ログインスクリプトの一部として展開されます。クリーンなWindows XPシステムでは利用できないものは使用しないようにしたいと思います。

編集:これが何のためにあるのかについての質問に答えて。

組織内のユーザーに、添付ファイルを常に電子メールで送信するのではなく、ファイルサーバーを使用してドキュメントを転送するように勧めたいと考えました。これに対する最大の障壁の1つは、ファイル/フォルダーへの正しいネットワークパスが何であるかが常に人々に明らかであるとは限らないことです。クイックスクリプトを開発し、それをWindowsのコンテキストメニューに添付して、ユーザーが任意のファイル/フォルダーを右クリックし、組織内の誰かに電子メールで送信できるURLを取得できるようにしました。

ダイアログボックスに表示されているURLもクリップボードに配置したい。

GetNetworkPath

17
Zoredache

Microsoftは、VBScriptがクリップボードに直接アクセスする方法を提供していません。 'clipboard'on this サイトを検索すると、次のように表示されます。

Visual Basic for Applicationsは、Screen、Printer、App、Debug、Err、およびClipboardオブジェクトをサポートしていますが、VBScriptはErrオブジェクトのみをサポートしています。したがって、VBScriptでは、マウスポインタやクリップボードなどの便利なオブジェクトにアクセスできません。ただし、Errオブジェクトを使用して、アプリケーションにランタイムエラー処理を提供することはできます。

したがって、メモ帳を間接的に使用することは、おそらくVBScriptだけで実行できる最善の方法です。

4
tloach

私の意見では完璧ではないが、迷惑なセキュリティ警告がないことがわかった別の解決策は、w2k3サーバーからclip.exeを使用することです。

Set WshShell = WScript.CreateObject("WScript.Shell")
WshShell.Run "cmd.exe /c echo hello world | clip", 0, TRUE

http://www.petri.co.il/quickly_copy_error_and_display_messages.htm

以下の質問による複数行の文字列の例

Dim string
String = "text here" &chr(13)& "more text here"
Set WshShell = WScript.CreateObject("WScript.Shell")
WshShell.Run "cmd.exe /c echo " & String & " | clip", 0, TRUE
27
Zoredache

Microsoftのclip.exeを使用することは、クリーンなWindows XPシステムソリューションを使用することに最も近いです。ただし、使用するためにCMD.EXEを呼び出してホストする必要はありません。呼び出すことができます。直接、スクリプトコードで入力ストリームに書き込みます。入力ストリームを閉じると、clip.exeはコンテンツを直接クリップボードに書き込みます。

Set WshShell = CreateObject("WScript.Shell")
Set oExec = WshShell.Exec("clip")
Set oIn = oExec.stdIn
oIn.WriteLine "Something One"
oIn.WriteLine "Something Two"
oIn.WriteLine "Something Three"
oIn.Close

スクリプトが処理を続行する前にクリップが終了するのを待つ必要がある場合は、追加します

' loop until we're finished working.
Do While oExec.Status = 0
    WScript.Sleep 100
Loop

そして、オブジェクトを解放することを忘れないでください

Set oIn = Nothing
Set oExec = Nothing
10
klaatu

私がこれまでに見つけた最も近い解決策は、IEを使用してクリップボードにあるものを取得および設定する方法です。この解決策の問題は、ユーザーがセキュリティ警告を受け取ることです。私は移動したくなります」 about:blank 'をローカルコンピュータのセキュリティゾーンに移動して警告を受け取らないようにしますが、そのセキュリティへの影響がどうなるかはわかりません。

Set objIE = CreateObject("InternetExplorer.Application")
objIE.Navigate("about:blank")
objIE.document.parentwindow.clipboardData.SetData "text", "Hello This Is A Test"
objIE.Quit

http://www.Microsoft.com/technet/scriptcenter/resources/qanda/dec04/hey1215.mspx

10
Zoredache

Internet Explorerとクリップボードへのアクセスに関連するセキュリティ警告を回避するために、Wordアプリケーションオブジェクトとそのメソッドを使用してデータをクリップボードに配置することをお勧めします。もちろん、これはMS Wordがインストールされているマシンでのみ使用できますが、最近ではほとんどのマシンで使用できます。 (*「クリーンな」システムで何かを要求したにもかかわらず:) *)

' Set what you want to put in the clipboard '
strMessage = "Imagine that, it works!"

' Declare an object for the Word application '
Set objWord = CreateObject("Word.Application")

' Using the object '
With objWord
   .Visible = False         ' Don't show Word '
   .Documents.Add           ' Create a document '
   .Selection.TypeText strMessage   ' Put text into it '
   .Selection.WholeStory        ' Select everything in the doc '
   .Selection.Copy          ' Copy contents to clipboard '
   .Quit False          ' Close Word, don't save ' 
End With

MS Wordアプリケーションオブジェクトとそのメソッドの詳細については、次を参照してください。 http://msdn.Microsoft.com/en-us/library/aa221371(office.11​​).aspx

6
unrealtrip

「clip」コマンドを使用する別のバージョンは、文字列の最後にキャリッジリターン、ラインフィードを追加しないようにするものです。

strA= "some character string"

Set objShell = WScript.CreateObject("WScript.Shell")
objShell.Run "cmd /C echo . | set /p x=" & strA & "| c:\clip.exe", 2

s = "String: """ & strA & """ is on the clipboard."
Wscript.Echo s

私はこれをXPでのみテストしました。 clip.exeは http://www.petri.co.il/downloads/clip.Zip からダウンロードされ、C:\に配置されました。

5
Peter Talbot

Vbscript/cmdで複数行の情報をクリップボードにコピーする方法を見つけました。

シーケンス:

  • vBSを使用して、クリップボードにコピーする必要がある最終的な「フォーマットされた文字列」を生成します
  • 「フォーマットされた文字列」を使用して(txt)ファイルを生成します
  • cmdからtypeコマンドを使用して、パイプでクリップする情報を貼り付けます

スクリプトの例:

Function CopyToClipboard( sInputString )

    Dim oShell: Set oShell = CreateObject("WScript.Shell")
    Dim sTempFolder: sTempFolder = oShell.ExpandEnvironmentStrings("%TEMP%")
    Dim sFullFilePath: sFullFilePath = sTempFolder & "\" & "temp_file.txt"

    Const iForWriting = 2, bCreateFile = True
    Dim oFSO: Set oFSO = CreateObject("Scripting.FileSystemObject")
    With oFSO.OpenTextFile(sFullFilePath, iForWriting, bCreateFile)
        .Write sInputString
        .Close
    End With

    Const iHideWindow = 0, bWaitOnReturnTrue = True
    Dim sCommand: sCommand = "CMD /C TYPE " & sFullFilePath & "|CLIP"
    oShell.Run sCommand, iHideWindow, bWaitOnReturnTrue

    Set oShell = Nothing
    Set oFSO = Nothing

End Function

Sub Main

    Call CopyToClipboard( "Text1" & vbNewLine & "Text2" )

End Sub

Call Main
4
n3rd4i

セキュリティ警告なし、完全な許可とアクセスの取得:

'create a clipboard thing
 Dim ClipBoard
 Set Clipboard = New cClipBoard

 ClipBoard.Clear  
 ClipBoard.Data = "Test"

Class cClipBoard
        Private objHTML

                Private Sub Class_Initialize
                        Set objHTML = CreateObject("htmlfile")
                End Sub

                Public Sub Clear()
                        objHTML.ParentWindow.ClipboardData.ClearData()
                End Sub

                Public Property Let Data(Value)
                        objHTML.ParentWindow.ClipboardData.SetData "Text" , Value
                End Property

                Public Property Get Data()
                        Data = objHTML.ParentWindow.ClipboardData.GetData("Text")
                End Property

                Private Sub Class_Terminate
                        Set objHTML = Nothing
                End Sub

End Class

使用例。

' Create scripting object
Dim WShell, lRunUninstall
Set WShell = CreateObject("WScript.Shell")
WShell.sendkeys "^c"
WScript.Sleep 250
bWindowFound = WShell.AppActivate("Microsoft Excel")
 WShell.sendkeys ClipBoard.Data
4
swyx

これがvbsに変換されたSrikanthの方法です

function SetClipBoard(sTxt)
    Set oIe = WScript.CreateObject("InternetExplorer.Application")
    oIe.silent = true
    oIe.Navigate("about:blank")
    do while oIe.ReadyState <> 4
        WScript.Sleep 20
    loop

    do while oIe.document.readyState <> "complete"
        WScript.Sleep 20
    loop

    oIe.document.body.innerHTML = "<textarea id=txtArea wrap=off></textarea>"
    set oTb = oIe.document.getElementById("txtArea")
    oTb.value = sTxt
    oTb.select
    set oTb = nothing
    oIe.ExecWB 12,0
    oIe.Quit
    Set oIe = nothing
End function


function GetClipBoard()
    set oIe = WScript.CreateObject("InternetExplorer.Application")
    oIe.silent = true
    oIe.Navigate("about:blank")
    do while oIe.ReadyState <> 4
        WScript.Sleep 20
    loop

    do while oIe.document.readyState <> "complete"
        WScript.Sleep 20
    loop 

    oIe.document.body.innerHTML = "<textarea id=txtArea wrap=off></textarea>"
    set oTb = oIe.document.getElementById("txtArea")
    oTb.focus   
    oIe.ExecWB 13,0
    GetClipBoard = oTb.value
    oTb.select
    set oTb = nothing
    oIe.Quit
    Set oIe = nothing
End function
2
Nive Auverleih

最も簡単な方法は、組み込みのmshta.exe機能を使用することです。

sText = "Text Content"
CreateObject("WScript.Shell").Run "mshta.exe ""javascript:clipboardData.setData('text','" & Replace(Replace(sText, "\", "\\"), "'", "\'") & "');close();""", 0, True

二重引用符char"を含む文字列をクリップボードに入れるには、次のコードを使用します。

sText = "Text Content and double quote "" char"
CreateObject("WScript.Shell").Run "mshta.exe ""javascript:clipboardData.setData('text','" & Replace(Replace(Replace(sText, "\", "\\"), """", """"""), "'", "\'") & "'.replace('""""',String.fromCharCode(34)));close();""", 0, True
2
omegastripes

IEを使用しながら、セキュリティ警告を回避する別の方法を考案しました...

ちなみに、この関数はJavaScriptですが、VBScriptに簡単に変換できます。

function CopyText(sTxt) {
    var oIe = WScript.CreateObject('InternetExplorer.Application');
    oIe.silent = true;
    oIe.Navigate('about:blank');
    while(oIe.ReadyState!=4) WScript.Sleep(20);
    while(oIe.document.readyState!='complete') WSript.Sleep(20);
    oIe.document.body.innerHTML = "<textarea id=txtArea wrap=off></textarea>";
    var oTb = oIe.document.getElementById('txtArea');
    oTb.value = sTxt;
    oTb.select();
    oTb = null;
    oIe.ExecWB(12,0);
    oIe.Quit();
    oIe = null;
}
2
Srikanth P

クラスClipBoardでは、ClearサブもLetDataサブも機能しません。つまり、Windows Clipboardには影響しません。実際、皮肉なことに、機能する唯一のサブは、例に含めていないサブ、つまりGetDataです。 (私はこのコードをかなりの回数テストしました。)

しかし、それはあなたのせいではありません。 ClipboardData.SetDataを使用してデータをクリップボードにコピーしようとしましたが、不可能です。少なくとも「htmlfile」オブジェクトを作成することによってではありません。いくつかのケースで見たように、「InternetExplorer.Application」のインスタンスを作成することで機能するかもしれませんが、試したことはありません。このような単純なタスク用のアプリケーションインスタンスを作成するのは嫌いです。

アルキス

1
Alkis

この投稿 を見てください。クリップボードからreadへのハッキーなアプローチについて説明していますが、Ctrlを変更するなど、クリップボードへの書き込みにも適用できると思います。 + VからCtrl + A、次にCtrl + C。

1
GreenGiant

テキストだけの場合は、テキストファイルを作成して、必要なときにコンテンツを読み込むだけでは不十分ですか?

別の代替手段であり、明らかに応急修理は、SendKeys()メソッドを使用することです。

0
Jeffery Hicks

行末でのセキュリティ警告やキャリッジリターンはありません

' value to put in Clipboard
mavaleur = "YEAH"

' current Dir
path = WScript.ScriptFullName
GetPath = Left(path, InStrRev(path, "\"))

' Put the value in a file
Set objFSO=CreateObject("Scripting.FileSystemObject")
outFile=GetPath & "fichier.valeur"
Set objFile = objFSO.CreateTextFile(outFile,True)
objFile.Write mavaleur
objFile.Close

' Put the file in the Clipboard
Set WshShell = WScript.CreateObject("WScript.Shell")
WshShell.Run "cmd.exe /c clip < " & outFile, 0, TRUE

' Erase the file
Set objFSO = CreateObject("Scripting.FileSystemObject")
objFSO.DeleteFile outFile
0
cmoiquoi