web-dev-qa-db-ja.com

ラップトップが最後にWindows 10から取り外された時期を知るにはどうすればよいですか？

私のラップトップが外されている時間を知る必要があります。 cmdまたは何らかのツールを使用してこれを行う方法はありますか？

windows-10laptopbattery
10
answerSeeker

ラップトップが取り外されている時間を知る必要があります

ラップトップが取り外されている場合、Windowsはイベントをログに記録しません。

ただし、以下のバッチファイルのようなものを使用して、カスタムイベントを作成できます。

Battery.cmd

このバッチファイルは、ラップトップが現在主電源またはバッテリー電源のどちらにあるかを監視します。

メインが外れ、ラップトップがバッテリーの使用を開始すると、ユーザー定義のイベントが作成されます。

@echo off
setlocal EnableDelayedExpansion
:start
rem get the battery status, 1 = battery discharging 2 = on mains
rem use findstr to strip blank lines from wmic output

for /f "usebackq skip=1" %%i in (`wmic path win32_battery get batterystatus ^| findstr /r /v "^$"`) do (
  set _status=%%i
  if [!_status!] equ [1] (
    rem on battery
    rem create a custom event in the application event log
    rem requires administrator privileges 
    eventcreate /l APPLICATION /t WARNING /ID 999 /D "Mains has been disconnected"
    goto :done
    ) else (
    rem on mains
    rem wait for 10 minutes then try again
    timeout /t 600 /nobreak > nul
    goto :start
    )
  )
:done
endlocal

ノート：

  • EventcreateコマンドはWindowsで機能しますXP Windows 10まで）、機能するには管理者権限が必要です
  • 主電源が切断されると、999という説明とともにID Mains has been disconnectedのイベントがAPPLICATIONイベントログに生成されます
  • 状況に応じて、eventcreateコマンドを変更します。
  • 状況に応じて、timeout遅延を変更します。

出力例

Battery.cmdを実行して主電源を切断すると、次の出力が生成されます。

> battery

SUCCESS: An event of type 'WARNING' was created in the 'APPLICATION' log with 'EventCreate' as the source.

>

そして、これがイベントログの新しいエントリです。

enter image description here

参考文献

4
DavidPostill

この情報を含むバッテリレポートを生成できます。これは1回限りのチェックには適していますが、継続的な繰り返しチェックには適していません。

プロセスは簡単です。

  1. 管理者としてコマンドプロンプトを開きます。
  2. powercfg /batteryreport /output "C:\batteryreport.html"を押してEnterキーを押します。
  3. Webブラウザーを使用してレポートファイルを開きます。

レポートには、コンピューターの電源状態とその状態の間の電源の履歴が含まれます。

注：この情報は、簡単なGoogle検索と、たくさんの写真が掲載されているこの役立つドキュメントから取得しました： http://www.windowscentral.com/generate-battery-report- windows-1 ビルド1607（記念日の更新）を実行するWindows 10タブレットで自分でテストしました

9
music2myear