web-dev-qa-db-ja.com

コマンドラインからInternet Explorerをデフォルトのブラウザーとして設定する

コマンドラインから起動するデフォルトのブラウザーとしてInternet Explorerを設定することは可能ですか？

Internet Explorerでのみ実行されるウェブアプリケーションがありますが、Firefoxがデフォルトのブラウザーである場合、それは機能しません。ユーザーはドメイン環境にあり、私はこの方法でバッチからアプリケーションを起動しようとしていますが：

start "C:\Program Files\Internet Explorer\iexplore.exe" http://server_ip/home_page

ブラウザを手動で変更しない限り、アプリケーションは起動しません。

windowsbrowserinternet-explorercmd.exe
10
nick rulez

このコマンドは、デフォルトのブラウザーとしてIEを設定します。

shmgrate.exe OcinstallreinstallIE

このポリシー は、デフォルトのブラウザを決定する人々を止めるべきです。

10
slotishtype

あなたはこれを試すことができます、それはうまくいきます

start "" "C:\Program Files\Internet Explorer\iexplore.exe" http://server_ip/home_page

コマンドのエラーは、startが最初に引用された文字列がアプリケーションのタイトルであることを期待することでした。この場合、空のままにすることができます。

設定用iexplorer.exeシステムのデフォルトのWebブラウザーとして、次のようにassocおよびftypeコマンドを使用して、拡張子をファイルタイプに関連付け、ファイルタイプを実行可能ファイルに関連付けることができます。

assoc .html=htmlfile
ftype htmlfile="C:\Program Files\Internet Explorer\iexplore.exe" %1

%1はここでの引数です。つまり、プログラムに入力として送信できるURLまたはファイルです。

3
easl

以下の2行をbatファイルに追加できます。

reg add "HKCU\Software\Microsoft\Internet Explorer\Main" /f /v "Check_Associations" /d "yes" /t REG_SZ

reg add "HKCU\Software\Microsoft\Windows\Shell\Associations\UrlAssociations\http\UserChoice" /f /v "ProgId" /d "IE.HTTP" /t REG_SZ

上記の2つのコマンドラインはレジストリ値を変更することを目的としているため、バットを実行した後、再起動/ログオフして再度ログアウトします。

詳細については、こちらをご覧ください

（修正）-Internet Explorerをデフォルトのブラウザとして設定できません！ http://www.windowstechinfo.com/2016/03/fixed-cant-set-internet-Explorer-as-the-default-browser.html

1
Aravinda

Windows Vista以降、IE 7+

次のバッチスクリプトは、デフォルトプログラムのコントロールパネルアプレットからクリックこのプログラムをデフォルトとして設定をシミュレートします。 Vista/7およびIE 7/IE 11.でテスト済み。

@echo off
setlocal enabledelayedexpansion

REM -- check XHTML support (IE 9+)
set xhtml=0
for /f %%G in ('"reg query "HKCR\IE.AssocFile.XHT" /ve 2>&1 | findstr /c:".XHT" "') do set xhtml=1

REM -- reset file extensions
set exts=HTM,HTML
if %xhtml% == 1 (set exts=%exts%,XHT,XHTML)

for %%G in (%exts%) do (
set ext=%%G
set ext=!ext:~0,3!
reg add "HKCU\Software\Classes\.%%G" /ve /t REG_SZ /d "IE.AssocFile.!ext!" /f >nul
)

set exts=%exts%,MHT,MHTML,URL
set acl=%temp%\acl_%random%%random%.txt

for %%G in (%exts%) do (
set key=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.%%G\UserChoice
echo !key! [1 7 17]>"%acl%"
regini "%acl%" >nul
set ext=%%G
set ext=!ext:~0,3!
reg add "!key!" /v "Progid" /t REG_SZ /d "IE.AssocFile.!ext!" /f >nul
)
del "%acl%" 2>nul

REM -- reset MIME associations
for %%G in (message/rfc822,text/html) do (
set key=HKCU\Software\Microsoft\Windows\Shell\Associations\MIMEAssociations\%%G\UserChoice
reg add "!key!" /v "Progid" /t REG_SZ /d "IE.%%G" /f >nul
)

REM -- reset URL protocols
for %%A in (FTP,HTTP,HTTPS) do (
set key=HKCU\Software\Microsoft\Windows\Shell\Associations\UrlAssociations\%%A\UserChoice
reg add "!key!" /v "Progid" /t REG_SZ /d "IE.%%A" /f >nul
for %%B in (DefaultIcon,Shell) do (
set key=HKCU\Software\Classes\%%A
reg delete "!key!\%%B" /f >nul 2>&1
reg copy "HKCR\IE.%%A\%%B" "!key!\%%B" /s /f >nul
reg add "!key!" /v "EditFlags" /t REG_DWORD /d 2 /f >nul
reg add "!key!" /v "URL Protocol" /t REG_SZ /d "" /f >nul
))

REM -- reset the start menu Internet link (Vista and earlier)
reg add "HKCU\Software\Clients\StartMenuInternet" /ve /t REG_SZ /d "IEXPLORE.EXE" /f

REM -- reset cached icons
if %xhtml% == 1 (
ie4uinit -cleariconcache
) else (
taskkill /im Explorer.exe /f >nul
start Explorer
)

pause
exit /b

備考

どのWebブラウザアプリケーションも、スタートメニューにインターネットクライアントとして表示されるように登録できます。この可視性は、アプリケーションの file および protocol タイプの適切な登録と相まって、アプリケーションのデフォルトのブラウザーステータスを提供します。デフォルトのWebブラウザーは、システムのどこからでも任意のURLを起動するために使用されます。

注Windows 7以降では、既存の[スタートメニューリンク]の登録は無視されます。この登録はWindows 7で廃止されました。

ソース： Windowsスタートメニューを使用してインターネットブラウザまたは電子メールクライアントを登録する方法

ファイルとプロトコルの関連付けの階層的なレジストリ構造は、マシンレベルのデフォルトよりもユーザーごとのデフォルトを優先します。

ソース： デフォルトプログラム

1
and31415

コマンドラインからデフォルトのブラウザーを設定する方法はわかりませんが、グループポリシーを使用してドメインに設定して適用できます。

ここにあなたが始めるための何かがあります：

http://technet.Microsoft.com/en-us/library/hh147307%28WS.10%29.aspx

0
Joe Internet

Windows 8（IE 10+）の場合、簡単なVBSスクリプトです。

Dim URL 
Dim IE 
Set IE = CreateObject("internetexplorer.application")
URL = "res://ieframe.dll/defaultbrowser.htm" 
IE.Visible = True
IE.Navigate URL


 Do While IE.Busy
    WScript.Sleep 100
 Loop

IE.Document.getElementById("changeDefaultButton").Click

IE変更用のページIEがデフォルトとして開始され、受け入れのためのボタンのクリックをシミュレートします。

0
Blaato

コマンドまたはバッチファイルを機能させるには、startをドロップするだけです。

"C:\Program Files\Internet Explorer\iexplore.exe" http://server_ip/home_page
0
Brian