web-dev-qa-db-ja.com

コマンドラインからWindows Updateをインストールする方法

コマンドラインからWindows更新プログラムをインストールすることはできますか？グラフィカルな更新ツールはWindows 7ではうまく機能していないようです。動作する場合もあれば、機能しない場合もあります。問題は、詳細リストを表示するためにクリックしても更新が表示されないことです。デフォルトでオフになっていないアップデートがあると、インストールできません...

それで、それらをインストールする他の方法はありますか？

windowswindows-7windows-update
17
Svish

Windows 7については不明ですが、XP/Vistaでは、次のコマンドを実行してアップデートを検出してダウンロードできます。

wuauclt /detectnow /reportnow

うまく動作しない場合は、 WSUS Wiki を確認してください。

それ以外の場合は、必要な更新がある場合は、MicrosoftのWebサイトからダウンロードしてください。インストールを妨げる問題が発生した場合は、Windows Updateのログの扱いに問題があるため、これが最も良い方法です。

12
duffbeer703

スクリプトを使用して、更新の確認、ダウンロード、および同期インストールを行うことができます。 Windowsコアサーバーの手動パッチには、 this vbscript の修正バージョンをよく使用します。

Set updateSession = CreateObject("Microsoft.Update.Session")
updateSession.ClientApplicationID = "MSDN Sample Script"

Set updateSearcher = updateSession.CreateUpdateSearcher()

WScript.Echo "Searching for updates..." & vbCRLF

Set searchResult = _
updateSearcher.Search("IsInstalled=0 and Type='Software' and IsHidden=0")

WScript.Echo "List of applicable items on the machine:"

For I = 0 To searchResult.Updates.Count-1
    Set update = searchResult.Updates.Item(I)
    WScript.Echo I + 1 & "> " & update.Title
Next

If searchResult.Updates.Count = 0 Then
    WScript.Echo "There are no applicable updates."
    WScript.Quit
End If

WScript.Echo vbCRLF & "Creating collection of updates to download:"

Set updatesToDownload = CreateObject("Microsoft.Update.UpdateColl")

For I = 0 to searchResult.Updates.Count-1
    Set update = searchResult.Updates.Item(I)
    addThisUpdate = false
    If update.InstallationBehavior.CanRequestUserInput = true Then
        WScript.Echo I + 1 & "> skipping: " & update.Title & _
        " because it requires user input"
    Else
        If update.EulaAccepted = false Then
            WScript.Echo I + 1 & "> note: " & update.Title & _
            " has a license agreement that must be accepted:"
            WScript.Echo update.EulaText
            WScript.Echo "Do you accept this license agreement? (Y/N)"
            strInput = WScript.StdIn.Readline
            WScript.Echo 
            If (strInput = "Y" or strInput = "y") Then
                update.AcceptEula()
                addThisUpdate = true
            Else
                WScript.Echo I + 1 & "> skipping: " & update.Title & _
                " because the license agreement was declined"
            End If
        Else
            addThisUpdate = true
        End If
    End If
    If addThisUpdate = true Then
        WScript.Echo I + 1 & "> adding: " & update.Title 
        updatesToDownload.Add(update)
    End If
Next

If updatesToDownload.Count = 0 Then
    WScript.Echo "All applicable updates were skipped."
    WScript.Quit
End If

WScript.Echo vbCRLF & "Downloading updates..."

Set downloader = updateSession.CreateUpdateDownloader() 
downloader.Updates = updatesToDownload
downloader.Download()

Set updatesToInstall = CreateObject("Microsoft.Update.UpdateColl")

rebootMayBeRequired = false

WScript.Echo vbCRLF & "Successfully downloaded updates:"

For I = 0 To searchResult.Updates.Count-1
    set update = searchResult.Updates.Item(I)
    If update.IsDownloaded = true Then
        WScript.Echo I + 1 & "> " & update.Title 
        updatesToInstall.Add(update) 
        If update.InstallationBehavior.RebootBehavior > 0 Then
            rebootMayBeRequired = true
        End If
    End If
Next

If updatesToInstall.Count = 0 Then
    WScript.Echo "No updates were successfully downloaded."
    WScript.Quit
End If

If rebootMayBeRequired = true Then
    WScript.Echo vbCRLF & "These updates may require a reboot."
End If

WScript.Echo  vbCRLF & "Would you like to install updates now? (Y/N)"
strInput = WScript.StdIn.Readline
WScript.Echo 

If (strInput = "Y" or strInput = "y") Then
    WScript.Echo "Installing updates..."
    Set installer = updateSession.CreateUpdateInstaller()
    installer.Updates = updatesToInstall
    Set installationResult = installer.Install()

    'Output results of install
    WScript.Echo "Installation Result: " & _
    installationResult.ResultCode 
    WScript.Echo "Reboot Required: " & _ 
    installationResult.RebootRequired & vbCRLF 
    WScript.Echo "Listing of updates installed " & _
    "and individual installation results:" 

    For I = 0 to updatesToInstall.Count - 1
        WScript.Echo I + 1 & "> " & _
        updatesToInstall.Item(i).Title & _
        ": " & installationResult.GetUpdateResult(i).ResultCode   
    Next
End If

それはそれの魅力のように動作するようですが、もちろんWindows 7でテストしていません。必要に応じて、特定のアップデートを対象とする別の記事へのリンクもあります。

同様のエクスペリエンスを公開する Powershellモジュール もあります。

簡単に調べたところ、 このサードパーティのアプリケーション も見つかりましたが、これも更新APIを使用していますが、いくつかのオプションがあります（サードパーティのコードを信頼する必要があります）。

4
Oskar Duveborn

コマンドラインからのWindows Update：

www.sysadminsoftware.com/udc.html

ツール（Updates Deployment Commander）は、あなたが望んでいることだけを実行できます。パラメータを渡して、特定のパッチを回避したり、特定の更新を対象としたり、完了してからN分後に再起動したり、CSVでレポートを作成したりすることもできます。いくつかのGUIユーティリティも付属しています。

2
sysadmin

特に新規インストール後のWindowsオペレーティングシステムにパッチを適用する必要がある場合は、 Offline Updater を真剣に検討してください。

スクリプトを使用して、提案するすべてのパッチ（適切な場合はWin2000、Win XP、Win 2003、Vista、Win2008、Win2012 32および64ビット）、多言語、サービスパック、.NETフレームワーク、Officeパッチ（XP、2000 、2003、2007）。

それらをすべてダウンロードしたら、火曜日にすべてのパッチを更新し、変更のみを取得します。それはカタルージュを取得しますが、彼らは毎日より長くなっています（OS/Office revごとに現在多くのメガ）。

ローカルマシン上のファイルをダウンロードしたら、それらのCD/DVDイメージを作成するスクリプトがあります（必要に応じて、OSごとのDVDイメージを自動的に作成します）。

私がすることは、書き込み保護タブを尊重するSDカードリーダーで、4GBのSDメモリカードを使用することです。以前は2GBのカードを使用していましたが、Win XPとほとんどのOfficeがそれでビルドできるようになったため、4GBのカードに移行しました。

したがって、マシンをトラブルシューティングするとき、以前は書き込み可能だったこのデバイスを、ウイルスに感染している可能性のある信頼できないマシンに挿入すると信頼できます（私はそれについて何も知らないため、感染していると思います）、デバイスが書き込み保護されていることを知っています。

したがって、最初のステップとして最新のパッチを適用できます。

自動実行を使用するか、デバイスで実行可能ファイル（キー、外部HD、CD、DVD、作成した場所）を起動すると、ローカルマシンのWindows Updateサービスを使用してすべての更新を適用するスクリプトが開始されますが、代わりにワイヤーを介してそれらをダウンロードするのは、ローカルコピーを使用するだけです。

したがって、WinXPマシンを最新のSPおよびパッチに更新するのに1時間以上かかる可能性がありますが、途中のネットワークトラフィックはゼロであり、イーサネットケーブルを完全に取り外して行うことができます。 。

驚くほど便利なツール！

パッチCDを事前に作成していたAutoUpdateの人たちのように、CDイメージを配布したMicrosoftを攻撃するべきではありません。このツールはスクリプトを更新するため、ライセンスを取得したWindowsワークステーションにすべてのパッチを入手する必要があります。

2
geoffc

現在 answerduffbeer7 にコメントを追加することはできません。そのため、ここで別の回答として：

インターネットアーカイブにアーカイブされているWSUSwikiへのリンクの最後の「適切な」バージョンは this です。元の回答で与えられたオプションは、この FAQエントリ で説明されています。

1
Olaf Mandel