web-dev-qa-db-ja.com

コマンドラインでXLSをCSVに変換する

WindowsコマンドラインでXLSファイルをCSVファイルに変換するにはどうすればよいですか。

マシンにはMicrosoft Office 2000がインストールされています。 Microsoft Officeを使用できない場合は、OpenOfficeをインストールできます。

92
Joel

メモ帳を開き、XlsToCsv.vbsというファイルを作成して、これを次の場所に貼り付けます。

if WScript.Arguments.Count < 2 Then
    WScript.Echo "Error! Please specify the source path and the destination. Usage: XlsToCsv SourcePath.xls Destination.csv"
    Wscript.Quit
End If
Dim oExcel
Set oExcel = CreateObject("Excel.Application")
Dim oBook
Set oBook = oExcel.Workbooks.Open(Wscript.Arguments.Item(0))
oBook.SaveAs WScript.Arguments.Item(1), 6
oBook.Close False
oExcel.Quit
WScript.Echo "Done"

次に、コマンドラインから、.vbsファイルを保存したフォルダーに移動して実行します。

XlsToCsv.vbs [sourcexlsFile].xls [destinationcsvfile].csv

ただし、使用しているマシンにExcelをインストールする必要があります。

110
ScottF

絶対ファイルパスを必要としないScottF回答のわずかに変更されたバージョン:

if WScript.Arguments.Count < 2 Then
    WScript.Echo "Please specify the source and the destination files. Usage: ExcelToCsv <xls/xlsx source file> <csv destination file>"
    Wscript.Quit
End If

csv_format = 6

Set objFSO = CreateObject("Scripting.FileSystemObject")

src_file = objFSO.GetAbsolutePathName(Wscript.Arguments.Item(0))
dest_file = objFSO.GetAbsolutePathName(WScript.Arguments.Item(1))

Dim oExcel
Set oExcel = CreateObject("Excel.Application")

Dim oBook
Set oBook = oExcel.Workbooks.Open(src_file)

oBook.SaveAs dest_file, csv_format

oBook.Close False
oExcel.Quit

このスクリプトはxlsに限定されないため、スクリプトの名前をExcelToCsvに変更しました。期待どおり、xlsxは問題なく動作します。

Office 2010でテスト済み。

69
plang

ScottFのgroovy VBスクリプトの小さな拡張:このバッチファイルは、ディレクトリ内の.xlsxファイルをループし、*。csvファイルにダンプします。

FOR /f "delims=" %%i IN ('DIR *.xlsx /b') DO ExcelToCSV.vbs "%%i" "%%i.csv"

注:拡張子.xlsxを.xlsに、スクリプト名ExcelToCSVをXlsToCsvに変更できます。

22
user565869

PowerShellでどうですか?

コードはこのように見えるはずですが、テストされていません

$xlCSV = 6
$Excel = New-Object -Com Excel.Application 
$Excel.visible = $False 
$Excel.displayalerts=$False 
$WorkBook = $Excel.Workbooks.Open("YOUDOC.XLS") 
$Workbook.SaveAs("YOURDOC.csv",$xlCSV) 
$Excel.quit()

使用方法を説明する投稿があります

Windows PowerShellを使用してMicrosoft Excelを自動化するにはどうすればよいですか

16
YOU

これは、ウィンドウからドラッグアンドドロップされる複数のファイルを処理するバージョンです。上記の作品に基づく

Christian Lemer
plang
ScottF

メモ帳を開き、XlsToCsv.vbsというファイルを作成して、これを次の場所に貼り付けます。

'* Usage: Drop .xl* files on me to export each sheet as CSV

'* Global Settings and Variables
Dim gSkip
Set args = Wscript.Arguments

For Each sFilename In args
    iErr = ExportExcelFileToCSV(sFilename)
    ' 0 for normal success
    ' 404 for file not found
    ' 10 for file skipped (or user abort if script returns 10)
Next

WScript.Quit(0)

Function ExportExcelFileToCSV(sFilename)
    '* Settings
    Dim oExcel, oFSO, oExcelFile
    Set oExcel = CreateObject("Excel.Application")
    Set oFSO = CreateObject("Scripting.FileSystemObject")
    iCSV_Format = 6

    '* Set Up
    sExtension = oFSO.GetExtensionName(sFilename)
    if sExtension = "" then
        ExportExcelFileToCSV = 404
        Exit Function
    end if
    sTest = Mid(sExtension,1,2) '* first 2 letters of the extension, vb's missing a Like operator
    if not (sTest =  "xl") then
        if (PromptForSkip(sFilename,oExcel)) then
            ExportExcelFileToCSV = 10
            Exit Function
        end if
    End If
    sAbsoluteSource = oFSO.GetAbsolutePathName(sFilename)
    sAbsoluteDestination = Replace(sAbsoluteSource,sExtension,"{sheet}.csv")

    '* Do Work
    Set oExcelFile = oExcel.Workbooks.Open(sAbsoluteSource)
    For Each oSheet in oExcelFile.Sheets
        sThisDestination = Replace(sAbsoluteDestination,"{sheet}",oSheet.Name)
        oExcelFile.Sheets(oSheet.Name).Select
        oExcelFile.SaveAs sThisDestination, iCSV_Format
    Next

    '* Take Down
    oExcelFile.Close False
    oExcel.Quit

    ExportExcelFileToCSV = 0
    Exit Function
End Function

Function PromptForSkip(sFilename,oExcel)
    if not (VarType(gSkip) = vbEmpty) then
        PromptForSkip = gSkip
        Exit Function
    end if

    Dim oFSO
    Set oFSO = CreateObject("Scripting.FileSystemObject")

    sPrompt = vbCRLF & _
        "A filename was received that doesn't appear to be an Excel Document." & vbCRLF & _
        "Do you want to skip this and all other unrecognized files?  (Will only Prompt this once)" & vbCRLF & _
        "" & vbCRLF & _
        "Yes    - Will skip all further files that don't have a .xl* extension" & vbCRLF & _
        "No     - Will pass the file to Excel regardless of extension" & vbCRLF & _
        "Cancel - Abort any further conversions and exit this script" & vbCRLF & _
        "" & vbCRLF & _
        "The unrecognized file was:" & vbCRLF & _
        sFilename & vbCRLF & _
        "" & vbCRLF & _
        "The path returned by the system was:" & vbCRLF & _
        oFSO.GetAbsolutePathName(sFilename) & vbCRLF

    sTitle = "Unrecognized File Type Encountered"

    sResponse =  MsgBox (sPrompt,vbYesNoCancel,sTitle)
    Select Case sResponse
    Case vbYes
        gSkip = True
    Case vbNo
        gSkip = False
    Case vbCancel
        oExcel.Quit
        WScript.Quit(10)    '*  10 Is the error code I use to indicate there was a user abort (1 because wasn't successful, + 0 because the user chose to exit)
    End Select

    PromptForSkip = gSkip
    Exit Function
End Function
7
Chris Rudd

異なるワークシートからいくつかのCVSを抽出する必要があったので、ここにワークシート名を指定できるようにするplangコードの修正バージョンがあります。

if WScript.Arguments.Count < 3 Then
    WScript.Echo "Please specify the sheet, the source, the destination files. Usage: ExcelToCsv <sheetName> <xls/xlsx source file> <csv destination file>"
    Wscript.Quit
End If

csv_format = 6

Set objFSO = CreateObject("Scripting.FileSystemObject")

src_file = objFSO.GetAbsolutePathName(Wscript.Arguments.Item(1))
dest_file = objFSO.GetAbsolutePathName(WScript.Arguments.Item(2))

Dim oExcel
Set oExcel = CreateObject("Excel.Application")

Dim oBook
Set oBook = oExcel.Workbooks.Open(src_file)

oBook.Sheets(WScript.Arguments.Item(0)).Select
oBook.SaveAs dest_file, csv_format

oBook.Close False
oExcel.Quit
7
Christian Lemer

独自に書いてみませんか?

あなたのプロファイルから、少なくともC#/。NETの経験があることがわかります。 Windowsコンソールアプリケーションを作成し、無料のExcelリーダーを使用してExcelファイルを読み取ります。 Excelデータリーダー CodePlexから問題なく使用できます(1つ良いことは、このリーダーにはExcelをインストールする必要がないことです)。コマンドラインからコンソールアプリケーションを呼び出すことができます。

ここで投稿が行き詰まっていて、助けが得られると確信しています。

5
Jay Riggs

Alacon- Alasql データベース用のコマンドラインユーティリティで実行できます。 Node.jsで動作するため、 Node.js をインストールしてから Alasql パッケージをインストールする必要があります。

ExcelファイルをCVS(ot TSV)に変換するには、次のように入力できます。

> node alacon "SELECT * INTO CSV('mydata.csv', {headers:true}) FROM XLS('mydata.xls', {headers:true})"

デフォルトでは、Alasqlは「Sheet1」からデータを変換しますが、パラメーターを使用してデータを変更できます。

{headers:false, sheetid: 'Sheet2', range: 'A1:C100'}

Alaconは、他の種類の変換(CSV、TSV、TXT、XLSX、XLS)およびSQL言語の構築をサポートしています(例については ser Manual を参照)。

3
agershun

Jon of All Tradesが提供するものに基づいて、次の(〜n)は厄介な二重拡張の問題を削除しました:FOR /f "delims=" %%i IN ('DIR *.xlsx /b') DO ExcelToCSV.vbs "%%i" "%%~ni.csv"

2
Charles Crous

ScottF VBソリューションを試して、動作するようにしました。ただし、マルチタブ(ワークブック)Excelファイルを単一の.csvファイルに変換したいと考えました。

これは機能せず、1つのタブ(Excelで開いたときに強調表示されているタブ)のみがコピーされました。

マルチタブExcelファイルを単一の.csvファイルに変換できるスクリプトを知っている人はいますか?

1
user1132593

WindowsにはExcel OLEDBデータプロバイダーが組み込まれています。これを使用して、ADO.NETを介してExcelシートを「照会」し、結果をCSVファイルに書き込むことができます。少量のコーディングが必要ですが、マシンに何もインストールする必要はありません。

1
Tim Robinson

これらの答えはすべて、スクリプトに1つ以上のファイルをドロップすることで(またはコマンドライン経由で)XLS *ファイルを自動的にCSV およびその逆に変換する次のスクリプトを作成するのに役立ちました。ジャンキーなフォーマットについておologiesび申し上げます。

' https://stackoverflow.com/questions/1858195/convert-xls-to-csv-on-command-line
' https://Gist.github.com/tonyerskine/77250575b166bec997f33a679a0dfbe4

' https://stackoverflow.com/a/36804963/1037948
'* Global Settings and Variables
Set args = Wscript.Arguments

For Each sFilename In args
    iErr = ConvertExcelFormat(sFilename)
    ' 0 for normal success
    ' 404 for file not found
    ' 10 for file skipped (or user abort if script returns 10)
Next

WScript.Quit(0)

Function ConvertExcelFormat(srcFile)

    if IsEmpty(srcFile) OR srcFile = "" Then
        WScript.Echo "Error! Please specify at least one source path. Usage: " & WScript.ScriptName & " SourcePath.xls*|csv"
        ConvertExcelFormat = -1
        Exit Function
        'Wscript.Quit
    End If

    Set objFSO = CreateObject("Scripting.FileSystemObject")

    srcExt = objFSO.GetExtensionName(srcFile)

    ' the 6 is the constant for 'CSV' format, 51 is for 'xlsx'
    ' https://msdn.Microsoft.com/en-us/vba/Excel-vba/articles/xlfileformat-enumeration-Excel
    ' https://www.rondebruin.nl/mac/mac020.htm
    Dim outputFormat, srcDest

    If LCase(Mid(srcExt, 1, 2)) = "xl" Then
        outputFormat = 6
        srcDest = "csv"
    Else
        outputFormat = 51
        srcDest = "xlsx"
    End If

    'srcFile = objFSO.GetAbsolutePathName(Wscript.Arguments.Item(0))
    srcFile = objFSO.GetAbsolutePathName(srcFile)
    destFile = Replace(srcFile, srcExt, srcDest)

    Dim oExcel
    Set oExcel = CreateObject("Excel.Application")
    Dim oBook
    Set oBook = oExcel.Workbooks.Open(srcFile)
    ' preserve formatting? https://stackoverflow.com/a/8658845/1037948
    'oBook.Application.Columns("A:J").NumberFormat = "@"
    oBook.SaveAs destFile, outputFormat
    oBook.Close False
    oExcel.Quit
    WScript.Echo "Conversion complete of '" & srcFile & "' to '" & objFSO.GetFileName(destFile) & "'"

End Function
0
drzaus

スコットFの答えは、インターネットで見つけた最高のものです。私は自分のニーズを満たすために彼のコードを追加しました。追加した:

エラー時の次の再開 <-上部のバッチ処理で欠落しているxlsファイルを説明します。 oBook.Application.Columns( "A:J")。NumberFormat = "@" <-SaveAs行の前に、データがテキストとして保存されていることを確認し、Excelが先行ゼロを削除して削除しないようにします。私のデータの数値文字列のコンマ、すなわち(1,200から1200)。列の範囲は、ニーズに合わせて調整する必要があります(A:J)。

また、Echoの「完了」を削除して、非対話型にしました。

次に、タスクを介して1時間ごとに自動化されたデータを処理するために、スクリプトをcmdバッチファイルに追加しました。

0
Jeffrey O