XSLTで改行を<br/>に変換する方法は？

Question

重複の可能性：
XSLT xsl：textで改行を解釈しますか？

XSLTで改行を<br/>に変換する方法は？

私はこれを持っています：

<text>
some text with 
new lines
</text>

私はこれが欲しい：

<p> some text with <br /> new lines </p>

Answer 1

この変換：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="t">
  <p>
    <xsl:apply-templates/>
  </p>
 </xsl:template>

 <xsl:template match="text()" name="insertBreaks">
   <xsl:param name="pText" select="."/>

   <xsl:choose>
     <xsl:when test="not(contains($pText, '&#xA;'))">
       <xsl:copy-of select="$pText"/>
     </xsl:when>
     <xsl:otherwise>
       <xsl:value-of select="substring-before($pText, '&#xA;')"/>
       <br />
       <xsl:call-template name="insertBreaks">
         <xsl:with-param name="pText" select=
           "substring-after($pText, '&#xA;')"/>
       </xsl:call-template>
     </xsl:otherwise>
   </xsl:choose>
 </xsl:template>
</xsl:stylesheet>

このXMLドキュメントに適用する場合：

<t>Line1
Line2
Line3
</t>

必要な正しい結果を生成します：

<p>Line1<br />Line2<br />Line3<br /></p>