web-dev-qa-db-ja.com

テストが次で始まる場合のXSL

このXMLを考えると

<dc:date>info:eu-repo/date/embargoEnd/2013-06-12</dc:date>
<dc:date>2012-07-04</dc:date>

文字列の年のみを出力するには、XSLが必要ですで始まらないinfo:eu-repo。私はこの方法を試していますが、うまくいきません。 for-each？

<xsl:if test="not(starts-with('dc:date', 'info:eu-repo'))">
                <xsl:for-each select="dc:date">
                    <publicationYear>
                        <xsl:variable name="date" select="."/>
                        <xsl:value-of select="substring($date, 0, 5)"/>
                    </publicationYear>
                </xsl:for-each>
</xsl:if>
xsltxpathxpath-2.0
9
robert laing

あなたは必要ないでしょうね'あなたのstart-withクエリを使用して、日付を少しずつ繰り返し処理することができます。

    <xsl:for-each select="dc:date">
         <xsl:variable name="date" select="."/>
         <xsl:if test="not(starts-with($date, 'info:eu-repo'))">
                <publicationYear>
                    <xsl:value-of select="substring($date, 0, 5)"/>
                </publicationYear>
        </xsl:if>
    </xsl:for-each>
19
DRCB

使用（提供されたXMLフラグメントが現在のノードの子である要素であり、目的のプロパティを持つ要素が1つしかないと仮定）：

substring-before(*[not(starts-with(., 'info:eu-repo'))], '-')

XSLT-ベースの検証：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="/*">
     <xsl:copy-of select=
     "substring-before(*[not(starts-with(., 'info:eu-repo'))], '-') "/>
 </xsl:template>
</xsl:stylesheet>

この変換が次のXMLドキュメントに適用される場合（単一の最上位要素にラップされた提供されたフラグメントと宣言された名前空間）：

<t xmlns:dc="some:dc">
    <dc:date>info:eu-repo/date/embargoEnd/2013-06-12</dc:date>
    <dc:date>2012-07-04</dc:date>
</t>

XPath式は最上位要素から評価され、この評価の結果が出力にコピーされます：

2012

II。目的のプロパティを持つ複数の要素：

この場合、単一のXPath 1.0式で目的のデータを生成することはできません。

このXSLT変換：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="*[not(starts-with(., 'info:eu-repo'))]/text()">
     <xsl:copy-of select="substring-before(., '-') "/>
==============  
 </xsl:template>
 <xsl:template match="text()"/>
</xsl:stylesheet>

このXMLドキュメントに適用された場合：

<t xmlns:dc="some:dc">
    <dc:date>info:eu-repo/date/embargoEnd/2013-06-12</dc:date>
    <dc:date>2012-07-04</dc:date>
    <dc:date>info:eu-repo/date/embargoEnd/2013-06-12</dc:date>
    <dc:date>2011-07-05</dc:date>
</t>

必要な正しい結果が生成されます：

2012
==============  
 2011
==============

III。XPath 2.0ワンライナー

*[not(starts-with(., 'info:eu-repo'))]/substring-before(., '-')

このXPath 2.0式が最後のXMLドキュメントの一番上の要素（上記に最も近い）で評価されると、必要な年が生成されます：

2012 2011

XSLT 2.0-ベースの検証：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="/*">
  <xsl:sequence select=
   "*[not(starts-with(., 'info:eu-repo'))]/substring-before(., '-')"/>
 </xsl:template>
</xsl:stylesheet>

この変換が最後のXMLドキュメントに適用されると、XPath式が評価され、この評価の結果が出力にコピーされます：

2012 2011

IV。最も一般的で難しいケース：

それでは、次のXMLドキュメントを見てみましょう。

<t xmlns:dc="some:dc">
    <dc:date>info:eu-repo/date/embargoEnd/2013-06-12</dc:date>
    <dc:date>2012-07-04</dc:date>
    <dc:date>info:eu-repo/date/embargoEnd/2013-06-12</dc:date>
    <dc:date>2011-07-05</dc:date>
    <dc:date>*/date/embargoEnd/2014-06-12</dc:date>
</t>

それでも、文字列値が「info：eu-repo」で始まらないすべてのdc:date要素の年の部分を取得したいと考えています。ただし、上記の最後のdc:date要素では、これまでのソリューションはどれも正しく機能しません。

驚くべきことに、必要なデータは1つのXPAth 2.0式で引き続き生成できます：

for $s in
      *[not(starts-with(., 'info:eu-repo'))]/tokenize(.,'/')[last()]
     return
       substring-before($s, '-')

この式が上記のXMLドキュメントの最上位要素から評価されると、必要な正しい結果が生成されます：

2012 2011 2014

これはXSLT 2.0に基づく検証です：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="/*">
  <xsl:sequence select=
   "for $s in
      *[not(starts-with(., 'info:eu-repo'))]/tokenize(.,'/')[last()]
     return
       substring-before($s, '-')
   "/>
 </xsl:template>
</xsl:stylesheet>
1
Dimitre Novatchev

template-matchを使用して、必要なものを取得することもできます。次に例を示します。

<xsl:template match="date[not(starts-with(.,'info:eu-repo'))]">
    <xsl:value-of select="."/>
</xsl:template>

私はこの入力XMLを持っています：

<?xml version="1.0" encoding="UTF-8"?>
<list>
<date>info:eu-repo/date/embargoEnd/2013-06-12</date>
<date>2012-07-04</date>
</list>

このXSLTをそれに適用します。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
version="1.0">
<xsl:template match="text() | @*"/>

<xsl:template match="/">
    <xsl:apply-templates />
</xsl:template> 

<xsl:template match="date[not(starts-with(.,'info:eu-repo'))]">
    <xsl:value-of select="."/>
</xsl:template>

</xsl:stylesheet>

そして私はこの出力を取得します：

<?xml version="1.0" encoding="UTF-8"?>2012-07-04

よろしく、ピーター

1
Peter