web-dev-qa-db-ja.com

XSLTで文字列がnullか空かを確認する

_ xsl _ を使用して、値がnullか空かどうかを確認する方法を教えてください。

たとえば、categoryNameが空の場合私は選択時構文を使っています。

例えば：

<xsl:choose>
    <xsl:when test="categoryName !=null">
        <xsl:value-of select="categoryName " />
    </xsl:when>
    <xsl:otherwise>
        <xsl:value-of select="other" />
    </xsl:otherwise>
</xsl:choose>
xsltnullxslt-1.0xslt-2.0
307
raklos
test="categoryName != ''"

編集 ：私の意見では、これは疑似コードや私自身のXSLTの初期の経験を含め、質問から推測される「[null]または空ではない」という最もありそうな解釈をカバーしています。すなわち、「次のJavaと同等のものは何ですか？」

!(categoryName == null || categoryName.equals(""))

例えばnullとemptyを明確に識別するための詳細については、 johnveyの答え= および/または XSLT 'fiddle' を参照してください。これにはMichael Kayのコメントのオプションも含まれます） 6番目の可能な解釈として。

308
steamer25

他に情報がない場合は、次のXMLを想定します。

<group>
    <item>
        <id>item 1</id>
        <CategoryName>blue</CategoryName>
    </item>
    <item>
        <id>item 2</id>
        <CategoryName></CategoryName>
    </item>
    <item>
        <id>item 3</id>
    </item>
    ...
</group>

サンプルユースケースは次のようになります。

<xsl:for-each select="/group/item">
    <xsl:if test="CategoryName">
        <!-- will be instantiated for item #1 and item #2 -->
    </xsl:if>
    <xsl:if test="not(CategoryName)">
        <!-- will be instantiated for item #3 -->
    </xsl:if>
    <xsl:if test="CategoryName != ''">
        <!-- will be instantiated for item #1 -->
    </xsl:if>
    <xsl:if test="CategoryName = ''">
        <!-- will be instantiated for item #2 -->
    </xsl:if>
</xsl:for-each>
260
johnvey

From空の要素：

特定のノードの値が空かどうかをテストする

それはあなたが何を意味しているかによって異なります。

  • 子ノードを含みません：not(node())
  • テキストコンテンツを含みません：not(string(.))
  • 空白以外のテキストを含みません：not(normalize-space(.))
  • コメント以外には何も含まれていません：not(node()[not(self::comment())])
63
Chris Doggett

どうですか？

test="not(normalize-space(categoryName)='')"
20
helcim

最初の2つはnull値を扱い、次の2つは空の文字列を扱います。

<xsl:if test="USER/FIRSTNAME">
    USERNAME is not null
</xsl:if>
<xsl:if test="not(USER/FIRSTNAME)">
    USERNAME is null
 </xsl:if>
 <xsl:if test="USER/FIRSTNAME=''">
     USERNAME is empty string
 </xsl:if>
 <xsl:if test="USER/FIRSTNAME!=''">
     USERNAME is not empty string
 </xsl:if>
9
Aleksandar Borkovac

場合によっては、値が特にnullであることを知りたいことがあります。これは、.NETオブジェクトからシリアル化されたXMLを使用する場合に特に必要です。受け入れられた答えがこれのために働く間、それはまたストリングが空白または空、すなわち ''であるとき同じ結果を返すので、あなたは区別することができません。

<group>
    <item>
        <id>item 1</id>
        <CategoryName xsi:nil="true" />
    </item>
</group>

だからあなたは単に属性をテストすることができます。

<xsl:if test="CategoryName/@xsi:nil='true'">
   Hello World.
</xsl:if>

正確な状態を知る必要がある場合があり、CategoryNameがインスタンス化されているかどうかを簡単に確認できないことがあります。Javascriptとは異なります。

<xsl:if test="CategoryName">
   Hello World.
</xsl:if>

Null要素の場合はtrueを返します。

5
DustJones

私はこの質問が古くなっているのを知っています、しかしすべての答えの間で、私はXSLT開発におけるこのユースケースのための共通のアプローチであるものを逃します。

私は、OPから欠けているコードがこのように見えることを想像しています：

<xsl:template match="category">
    <xsl:choose>
        <xsl:when test="categoryName !=null">
            <xsl:value-of select="categoryName " />
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="other" />
        </xsl:otherwise>
    </xsl:choose>
</category>

そして、入力は次のようになります。

<categories>
    <category>
       <categoryName>Books</categoryName>
    </category>
    <category>
       <categoryName>Magazines</categoryName>
       <categoryName>Periodicals</categoryName>
       <categoryName>Journals</categoryName>
    </category>
    <category>
        <categoryName><!-- please fill in category --></categoryName>
    </category>
    <category>
        <categoryName />
    </category>
    <category />
</categories>

つまり、ゼロ、空、単一、または複数のcategoryName要素が存在できると想定します。 xsl:choose-styleコンストラクトを使用して、つまり命令的にこれらのすべてのケースに対処することは急速に面倒になります（要素が異なるレベルにある可能性がある場合でもなおさらです！） XSLTの典型的なプログラミングイディオムはテンプレート（つまりXSLTのT）を使用することです。これは宣言型プログラミングであり、必須ではありません（プロセッサに何をすべきかを指示せず、特定の条件が満たされたら出力したいことを指示します）。このユースケースでは、次のようになります。

<!-- positive test, any category with a valid categoryName -->
<xsl:template match="category[categoryName[text()]]">
    <xsl:apply-templates />
</xsl:template>

<!-- any other category (without categoryName, "null", with comments etc) -->
<xsl:template match="category">
    <xsl:text>Category: Other</xsl:text>
</xsl:template>

<!-- matching the categoryName itself for easy handling of multiple names -->
<xsl:template match="categoryName">
    <xsl:text>Category: </xsl:text>
    <xsl:value-of select="." />
</xsl:template>

上記の最初のものが優先順位が高い（述語を持つ）ため、これは（どのXSLTバージョンでも）機能します。 「フォールスルー」マッチングテンプレート、2番目のテンプレートは、無効なものをすべてキャッチします。次に3番目のものは適切な方法でcategoryName値を出力するようにします。

このシナリオでは、特に指定しない限り、プロセッサがすべての子を自動的に処理するため、categoriesまたはcategoryを明示的に一致させる必要はありません（この例では、2番目と3番目のテンプレートは子をさらに処理しません）。それらの中にxsl:apply-templatesはありません。

このアプローチは、複数のカテゴリを自動的に処理し、別の一致するテンプレートを追加するだけで他の要素や例外に拡張できるため、命令型アプローチよりも拡張が容易です。 if-branchesなしのプログラミング 。

注：XMLにはnullのようなものはありません。 xsi：nil がありますが、これはめったに使用されません。特に、何らかのスキーマのない型なしシナリオではめったに使用されません。

4
Abel

要素がXMLに存在しない可能性がある場合は、要素が存在することとstring-lengthがゼロより大きいことの両方をテストします。

<xsl:choose>
    <xsl:when test="categoryName and string-length(categoryName) &gt; 0">
        <xsl:value-of select="categoryName " />
    </xsl:when>
    <xsl:otherwise>
        <xsl:value-of select="other" />
    </xsl:otherwise>
</xsl:choose>
4
Marie Taylor

Xpath以下のように、入力xmlで利用可能な値がノードにない場合、

<node>
    <ErrorCode/>
</node>

string（）関数は空の値に変換します。だからこれはうまくいきます：

string(/Node/ErrorCode) =''
3
Sanjeev Singh

XSLで値がnullか空かを確認する方法はありますか。

たとえば、categoryNameが空の場合

これはおそらく最も単純なXPath式 です（受け入れられた答えの中の1つは反対のテストを提供し、否定されるならばより長いでしょう）：

not(string(categoryName))

説明 ：

上記のnot()関数への引数は、コンテキスト項目のcategoryName child（ "null"）がまったくない場合、または（単独の）categoryName childが文字列値 - 空の文字列を持つ場合にfalse()です。

私は選択時構文を使っています。

例えば：

<xsl:choose>
    <xsl:when test="categoryName !=null">
        <xsl:value-of select="categoryName " />
    </xsl:when>
    <xsl:otherwise>
        <xsl:value-of select="other" />
    </xsl:otherwise>
</xsl:choose>

XSLT 2.0では、 ：を使用します。

<xsl:copy-of select="concat(categoryName,  $vOther[not(string(current()/categoryName))])"/>

これは完全な例です ：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
     <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:variable name="vOther" select="'Other'"/>

 <xsl:template match="/">
  <xsl:copy-of select="concat(categoryName,$vOther[not(string(current()/categoryName))])"/>
 </xsl:template>
</xsl:stylesheet>

この変換が次のXML文書に適用される場合： 

<categoryName>X</categoryName>

欲しい、正しい結果が得られる ：

X

このXML文書に適用した場合 ：

<categoryName></categoryName>

またはこれで：

<categoryName/>

またはこれで

<somethingElse>Y</somethingElse>

正しい結果が生成されます ：

Other

同様に、 XSLT 1.0 変換を使用してください。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:variable name="vOther" select="'Other'"/>

  <xsl:template match="/">
    <xsl:copy-of select=
    "concat(categoryName,  substring($vOther, 1 div not(string(categoryName))))"/>
  </xsl:template>
</xsl:stylesheet>

注意してください ：条件はまったく使用されません。このNice Pluralsightコースでは、条件付き構成要素を避けることの重要性について学んでください。

" .NETにおける戦術的デザインパターン：制御フロー "

3
Dimitre Novatchev

このようなものは私のために働く：

<xsl:choose>
  <xsl:when test="string(number(categoryName)) = 'NaN'"> - </xsl:when> 
  <xsl:otherwise> 
    <xsl:number value="categoryName" />
  </xsl:otherwise>
</xsl:choose>

またはその逆です。

<xsl:choose>
  <xsl:when test="string(number(categoryName)) != 'NaN'">
    <xsl:number value="categoryName" />
  </xsl:when> 
  <xsl:otherwise> - </xsl:otherwise>
</xsl:choose>

注：NULL値をチェックしたりNULL値を処理したりしない場合、IE7はNaNの代わりに-2147483648を返します。

2
HSol

私の経験では、最善の方法は次のとおりです。

<xsl:when test="not(string(categoryName))">
    <xsl:value-of select="other" />
</xsl:when>
<otherwise>
    <xsl:value-of select="categoryName" />
</otherwise>
0
dr_leevsey

単純なcategoryName/text（）を使用してください。このようなテストは<categoryName/>および<categoryName></categoryName>でも正常に機能します。

<xsl:choose>
    <xsl:when test="categoryName/text()">
        <xsl:value-of select="categoryName" />
    </xsl:when>
    <xsl:otherwise>
        <xsl:value-of select="other" />
    </xsl:otherwise>
</xsl:choose>
0
Jaroslav Kubacek

何度もフィールドがnullではなく、単に空になっているので、実際には文字列の長さをテストするだけの方が良いことがわかりました。

<xsl：when test = "文字列の長さ（テストするフィールド）<1">

0
Pedro Pereira