web-dev-qa-db-ja.com

このyaccファイルでshift / reduceの競合を見つける方法は？

次のファイルでyaccを使用しようとすると、エラーの競合が発生します。1shift/reduce競合を見つけて修正するにはどうすればよいですか？

/* C-Minus BNF Grammar */

%token ELSE
%token IF
%token INT
%token RETURN
%token VOID
%token WHILE

%token ID
%token NUM

%token LTE
%token GTE
%token EQUAL
%token NOTEQUAL
%%

program : declaration_list ;

declaration_list : declaration_list declaration | declaration ;

declaration : var_declaration | fun_declaration ;

var_declaration : type_specifier ID ';'
                | type_specifier ID '[' NUM ']' ';' ;

type_specifier : INT | VOID ;

fun_declaration : type_specifier ID '(' params ')' compound_stmt ;

params : param_list | VOID ;

param_list : param_list ',' param
           | param ;

param : type_specifier ID | type_specifier ID '[' ']' ;

compound_stmt : '{' local_declarations statement_list '}' ;

local_declarations : local_declarations var_declaration
                   | /* empty */ ;

statement_list : statement_list statement
               | /* empty */ ;

statement : expression_stmt
          | compound_stmt
          | selection_stmt
          | iteration_stmt
          | return_stmt ;

expression_stmt : expression ';'
                | ';' ;

selection_stmt : IF '(' expression ')' statement
               | IF '(' expression ')' statement ELSE statement ;

iteration_stmt : WHILE '(' expression ')' statement ;

return_stmt : RETURN ';' | RETURN expression ';' ;

expression : var '=' expression | simple_expression ;

var : ID | ID '[' expression ']' ;

simple_expression : additive_expression relop additive_expression
                  | additive_expression ;

relop : LTE | '<' | '>' | GTE | EQUAL | NOTEQUAL ;

additive_expression : additive_expression addop term | term ;

addop : '+' | '-' ;

term : term mulop factor | factor ;

mulop : '*' | '/' ;

factor : '(' expression ')' | var | call | NUM ;

call : ID '(' args ')' ;

args : arg_list | /* empty */ ;

arg_list : arg_list ',' expression | expression ;
yacc
19
neuromancer

Mientefuegoが指摘したように、文法には古典的な「ぶら下がり」の問題があります。競合の原因となるルールに優先順位を割り当てることで、問題を克服できます。

競合の原因となるルールは次のとおりです。

selection_stmt : IF '(' expression ')' statement
               | IF '(' expression ')' statement ELSE statement ;

まず、ELSEとLOWER_THAN_ELSE（疑似トークン）を非連想にすることから始めます。

%nonassoc LOWER_THAN_ELSE
%nonassoc ELSE

これにより、LOWER_THAN_ELSEが最初に宣言されるという理由だけで、ELSEがLOWER_THAN_ELSEよりも優先されます。

次に、競合するルールで、シフトアクションまたはリデュースアクションのいずれかに優先順位を割り当てる必要があります。

selection_stmt : IF '(' expression ')' statement    %prec LOWER_THAN_ELSE ;
               | IF '(' expression ')' statement ELSE statement ;

ここでは、シフトが優先されます。上記の修正を組み込み、完全な文法を以下にリストしました。

/* C-Minus BNF Grammar */

%token ELSE
%token IF
%token INT
%token RETURN
%token VOID
%token WHILE

%token ID
%token NUM

%token LTE
%token GTE
%token EQUAL
%token NOTEQUAL

%nonassoc LOWER_THAN_ELSE
%nonassoc ELSE
%%

program : declaration_list ;

declaration_list : declaration_list declaration | declaration ;

declaration : var_declaration | fun_declaration ;

var_declaration : type_specifier ID ';'
                | type_specifier ID '[' NUM ']' ';' ;

type_specifier : INT | VOID ;

fun_declaration : type_specifier ID '(' params ')' compound_stmt ;

params : param_list | VOID ;

param_list : param_list ',' param
           | param ;

param : type_specifier ID | type_specifier ID '[' ']' ;

compound_stmt : '{' local_declarations statement_list '}' ;

local_declarations : local_declarations var_declaration
                   | /* empty */ ;

statement_list : statement_list statement
               | /* empty */ ;

statement : expression_stmt
          | compound_stmt
          | selection_stmt
          | iteration_stmt
          | return_stmt ;

expression_stmt : expression ';'
                | ';' ;

selection_stmt : IF '(' expression ')' statement    %prec LOWER_THAN_ELSE ;
               | IF '(' expression ')' statement ELSE statement ;

iteration_stmt : WHILE '(' expression ')' statement ;

return_stmt : RETURN ';' | RETURN expression ';' ;

expression : var '=' expression | simple_expression ;

var : ID | ID '[' expression ']' ;

simple_expression : additive_expression relop additive_expression
                  | additive_expression ;

relop : LTE | '<' | '>' | GTE | EQUAL | NOTEQUAL ;

additive_expression : additive_expression addop term | term ;

addop : '+' | '-' ;

term : term mulop factor | factor ;

mulop : '*' | '/' ;

factor : '(' expression ')' | var | call | NUM ;

call : ID '(' args ')' ;

args : arg_list | /* empty */ ;

arg_list : arg_list ',' expression | expression ;
20
ardsrk

yacc -v <filename>を試してみてください。詳細の出力が生成されます。

私はここでテストしました、そしてあなたの文法記述は古典的な「ぶら下がっている他の」問題で失敗します。

このウィキペディアの記事 を見てください。

6
user211430

ええと、この問題の正解は通常次のとおりです：何もしない。

Shift/reduceの競合は、あいまいな文法で予期されるです。それらはエラーではなく、競合です。

競合は、reduceよりもshiftを優先することで解決されます。これは、正規のぶら下がりelse問題を解決するために発生します。

また、bisonには％expectnステートメントも含まれているため、正確にnがある場合でもS/R競合の警告は表示されません。 ）競合。

4
DigitalRoss

まず、 yaccからのステートマシン出力 を取得します。シフトまたは縮小できる状態は、シフト/縮小の競合を表します。 1つを見つけてから、文法を書き直して競合を解決します。

0
Yuval F

This 記事は、ardsrkによって投稿されたものに代わる解決策を提供します。

0
Tomato