web-dev-qa-db-ja.com

OpenGL Phongシェーダーがフラットシェーダーのように動作するのはなぜですか？

私は過去2週間、OpenGLを学習してきましたが、Phongシェーダーの実装で問題が発生しました。 smooth修飾子を使用しているにもかかわらず、頂点間の補間を行わないようです。ここで何か不足していますか？クレジットの期限が到来する場所でクレジットを付与するために、頂点シェーダーとフラグメントシェーダーのコードは OpenGL SuperBible 第5エディションから大幅に増加しています。この本を強くお勧めします！

頂点シェーダー：

#version 330
in vec4 vVertex;
in vec3 vNormal;
uniform mat4 mvpMatrix;  // mvp = ModelViewProjection
uniform mat4 mvMatrix; // mv = ModelView
uniform mat3 normalMatrix;
uniform vec3 vLightPosition;
smooth out vec3 vVaryingNormal;
smooth out vec3 vVaryingLightDir;

void main(void) {
 vVaryingNormal = normalMatrix * vNormal;
 vec4 vPosition4 = mvMatrix * vVertex;
 vec3 vPosition3 = vPosition4.xyz / vPosition4.w;
 vVaryingLightDir = normalize(vLightPosition - vPosition3);
 gl_Position = mvpMatrix * vVertex;
}

フラグメントシェーダー：

#version 330
out vec4 vFragColor;
uniform vec4 ambientColor;
uniform vec4 diffuseColor;
uniform vec4 specularColor;
smooth in vec3 vVaryingNormal;
smooth in vec3 vVaryingLightDir;

void main(void) {
 float diff = max(0.0, dot(normalize(vVaryingNormal), normalize(vVaryingLightDir)));
 vFragColor = diff * diffuseColor;
 vFragColor += ambientColor;
 vec3 vReflection = normalize(reflect(-normalize(vVaryingLightDir),normalize(vVaryingNormal)));
 float spec = max(0.0, dot(normalize(vVaryingNormal), vReflection));

 if(diff != 0) {
   float fSpec = pow(spec, 32.0);
   vFragColor.rgb += vec3(fSpec, fSpec, fSpec);
 }

}

ウィキペディアからのこの（パブリックドメイン）画像は、取得している画像の種類と目的を正確に示しています。「フラット」画像を取得していますが、「フォン」画像が必要です。 

どんな助けでも大歓迎です。ありがとうございました！

編集：それが違いを生む場合、私はPyOpenGL 3.0.1とPython 2.6。

edit2：

解決

問題は私のジオメトリにあることがわかりました。コスは正しかった。 Blenderモデルでこの問題を抱えている他の誰にとっても、KosはEdit->Faces->Set Smoothトリックを行います。 Wings 3Dは「そのまま」機能することがわかりました。

openglglslshaderpyopengl
48
Jonba

うーん...法線をvarying変数として補間しているので、フラグメントシェーダーは正しいピクセルごとの法線を受け取る必要があります。

左側の画像のように結果が得られているという事実の唯一の説明（私は考えることができます）は特定の顔のすべてのフラグメントが最終的に同じ法線を受け取るです。次のようなフラグメントシェーダーで確認できます。

void main() {
   vFragColor = normalize(vVaryingNormal);
}

それが事実である場合、問題は残ります：なぜですか？頂点シェーダーは問題ありません。

多分あなたの何かに問題がありますgeometry？シェーダーに送信するデータは何ですか？面ごとの法線だけでなく、頂点ごとの法線を正しく計算しましたか？

normals

オレンジ色の線は対角面の法線、赤い線は水平面の法線です。

データが上記の画像のように見える場合、正しいシェーダーを使用してもフラットシェーディングが得られます。下の画像のように、頂点ごとの法線が正しいことを確認してください。 （球の計算は非常に簡単です。）

49
Kos

この回答への追加として、ここに法線を視覚化できる単純なジオメトリシェーダーがあります。属性の場所とマトリックスの送信方法に基づいて、必要に応じて付随する頂点シェーダーを変更します。

しかし、最初に、結果の例として、友人のスタンフォードバニーからの巨大なバニーの頭の写真！

normals for the Stanford bunny

メジャー警告：適切な法線マトリックスではなく、モデルビューマトリックスを使用して法線を変換するのをやめます。モデルビューに非均一なスケーリングが含まれている場合、これは正しく機能しません。また、法線の長さは正しくありませんが、方向を確認したいだけの場合は問題になりません。

頂点シェーダー：

#version 330

layout(location = 0) in vec4 position;
layout(location = 1) in vec4 normal;
layout(location = 2) in mat4 mv;

out Data
{
    vec4 position;
    vec4 normal;
    vec4 color;
    mat4 mvp;
} vdata;

uniform mat4 projection;

void main()
{
    vdata.mvp = projection * mv;
    vdata.position = position;
    vdata.normal = normal;
}

ジオメトリシェーダー：

#version 330
layout(triangles) in;
layout(line_strip, max_vertices = 6) out;

in Data
{
    vec4 position;
    vec4 normal;
    vec4 color;
    mat4 mvp;
} vdata[3];

out Data
{
    vec4 color;
} gdata;

void main()
{
    const vec4 green = vec4(0.0f, 1.0f, 0.0f, 1.0f);
    const vec4 blue = vec4(0.0f, 0.0f, 1.0f, 1.0f);

    for (int i = 0; i < 3; i++)
    {
        gl_Position = vdata[i].mvp * vdata[i].position;
        gdata.color = green;
        EmitVertex();

        gl_Position = vdata[i].mvp * (vdata[i].position + vdata[i].normal);
        gdata.color = blue;
        EmitVertex();

        EndPrimitive();
    }
}

フラグメントシェーダー：

#version 330

in Data
{
    vec4 color;
} gdata;

out vec4 outputColor;

void main()
{
    outputColor = gdata.color;
}
65
Nicolas Lefebvre