web-dev-qa-db-ja.com

xsltの同じノードで最大値を取得する方法

私は以下のようなxmlを持っています：

<Report xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema">
  <Name>HourlyReport</Name>
  <Id>8</Id>
  <TotalResults>1</TotalResults>
  <TotalPages>1</TotalPages>
  <Items>
    <Item>
      <Id>1</Id>
      <Hour0>23</Hour0>
      <Hour1>12</Hour1>
      <Hour2>7</Hour2>
      <Hour3>18</Hour3>
      <Hour4>32</Hour4>
      .
      .
      .
      <Hour20>28</Hour20>
      <Hour21>39</Hour21>
      <Hour22>51</Hour22>
      <Hour23>49</Hour23>
    </Item>
  </Items>
</Report>

xsltを使用して、上記のXMLから最大値が必要です。上記の場合、最大値は51です。どうすればそれを取得できますか？また、この最大値を任意のxslt変数で取得できるので、他の場所で使用できます。どうしようもない。 xsltバージョン1.0または2.0を使用できます。

xmlxsltxslt-1.0xslt-2.0
13
CodeGuru

XSLT 2.0を考えると、使用するだけで十分です。

<xsl:variable name="max" select="max(/Report/Items/Item/*[starts-with(local-name(), 'Hour')]/xs:integer(.)"/>

（スタイルシートでxmlns:xs="http://www.w3.org/2001/XMLSchema"を宣言する必要がある場合）。

XSLT 1.0では、次のように単純に並べ替えて最大値を取得します。

<xsl:variable name="max">
  <xsl:for-each select="/Report/Items/Item/*[starts-with(local-name(), 'Hour')]">
    <xsl:sort select="." data-type="number" order="descending"/>
    <xsl:if test="position() = 1"><xsl:value-of select="."/></xsl:if>
  </xsl:for-each>
</xsl:variable>
19
Martin Honnen

XSLT 2.0では、アイテムをコンテキストノードとして使用し、

max(*[starts-with(local-name(), 'Hour')])
3
Michael Kay

このXSL：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>
  <xsl:strip-space elements="*"/>

    <!-- Putting the maximum hour from the list into a variable. -->
    <xsl:variable name="max-hour">
      <xsl:call-template name="find-max">
        <!-- Select the list of hour elements you want to look at. -->
        <xsl:with-param name="hours" select="//*[contains(local-name(), 'Hour')]"/>
      </xsl:call-template>
    </xsl:variable>

  <xsl:template match="*">   
    <!-- Displaying the result you are after. -->
    <result>
      <xsl:value-of select="$max-hour"/>
    </result>
  </xsl:template>

  <!-- This template works recursively on the list of hours. -->
  <xsl:template name="find-max">
    <xsl:param name="hours"/>

    <!-- The value of the first hour in this list. -->
    <xsl:variable name="this-hour">
      <xsl:value-of select="$hours[position() = 1]"/>
    </xsl:variable>

    <xsl:choose>
      <xsl:when test="$hours">
        <!-- The maximum value of the remaining hours in this list. -->
        <xsl:variable name="other-hours">
          <xsl:call-template name="find-max">
            <xsl:with-param name="hours" select="$hours[position() != 1]"/>
          </xsl:call-template>
        </xsl:variable>

        <!-- Return the maximum of this hour and the remaining hours. -->
        <xsl:choose>
          <xsl:when test="$other-hours &gt; $this-hour">
            <xsl:value-of select="$other-hours"/>
          </xsl:when>
          <xsl:otherwise>
            <xsl:value-of select="$this-hour"/>
          </xsl:otherwise>
        </xsl:choose>
      </xsl:when>

      <!-- We've reached the last hour in the list. -->
      <xsl:otherwise/>
    </xsl:choose>

  </xsl:template>

</xsl:stylesheet>

次の出力が得られます。

<result>51</result>
3
Ben L

XSLT 1では、次の兄弟を使用できます

<xsl:value-of select="/Report/Items/Item/*[starts-with(name(), 'Hour')][not(.&lt;following-sibling::*[starts-with(name(), 'Hour')])]"/>
0
YellowDoc