web-dev-qa-db-ja.com

XSL-要素をコピーしますが、未使用の名前空間を削除します

次のように、属性にのみ使用される名前空間を宣言するXMLがあります。

<?xml version="1.0" encoding="UTF-8"?>
<a xmlns:x="http://tempuri.com">
    <b>
        <c x:att="true"/>
        <d>hello</d>
    </b>
</a>

XSLを使用して、選択したノードとその値のコピーを作成し、属性を削除したいと思います。したがって、私の望ましい出力は次のとおりです。

<?xml version="1.0" encoding="UTF-8"?>
<b>
    <c />
    <d>hello</d>
</b>

これをほぼ実行するXSLがいくつかありますが、出力の最上位要素に名前空間宣言を配置することを止められないようです。私のXSLは次のとおりです。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:template match="/">
        <xsl:apply-templates select="/a/b"/>
    </xsl:template>

    <xsl:template match="node()">
        <xsl:copy>
            <xsl:apply-templates select="node()"/>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

出力の最初の要素は、<b xmlns:x="http://tempuri.com">ではなく<b>です。 XSLで名前空間を宣言し、プレフィックスをexclude-result-prefixesリストに入れてみましたが、これは効果がないようです。私は何が間違っているのですか？

更新：XSLで名前空間を宣言し、extension-element-prefixes属性を使用することで機能することがわかりましたが、これは正しくないようです。これは使えると思いますが、なぜexclude-result-prefixesが機能しないのか知りたいです！

更新：実際、このextension-element-prefixesソリューションは、MSXMLではなくXMLSpyの組み込みXSLTエンジンでのみ機能するようです。

xsltxml-namespaces
18
Graham Clark
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
    xmlns:x="http://tempuri.com">
    <xsl:template match="/">
        <xsl:apply-templates select="/a/b"/>
    </xsl:template>

    <xsl:template match="*">
        <xsl:element name="{local-name(.)}">
            <xsl:apply-templates/>
        </xsl:element>
    </xsl:template>

    <xsl:template match="@*">
        <xsl:copy/>
    </xsl:template>

    <!-- This empty template is not needed.
Neither is the xmlns declaration above:
    <xsl:template match="@x:*"/> -->
</xsl:stylesheet>

説明を見つけました ここ 。

マイケルケイは書いた：
exclude-result-prefixesは、リテラルの結果要素によってスタイルシートからコピーされた名前空間にのみ影響し、ソースドキュメントからの名前空間のコピーには影響しません。

9
steamer25
<xsl:stylesheet 
  version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
  xmlns:x="http://tempuri.com"
  exclude-result-prefixes="x"
>

  <!-- the identity template copies everything 1:1 -->
  <xsl:template match="@* | node()">
     <xsl:copy>
      <xsl:apply-templates select="@* | node()" />
    </xsl:copy>
  </xsl:template>

  <!-- this template explicitly cares for namespace'd attributes -->
  <xsl:template match="@x:*">
    <xsl:attribute name="{local-name()}">
      <xsl:value-of select="." />
    </xsl:attribute>
  </xsl:template>

</xsl:stylesheet>
5
Tomalak

これを試してください（属性copy-namespaces='no'に注意してください）：

<xsl:template match="node()">
    <xsl:copy copy-namespaces="no">
            <xsl:apply-templates select="node()"/>
    </xsl:copy>
</xsl:template>
4
Alex

これにより、x名前空間が出力から削除されます。

<xsl:namespace-alias result-prefix="#default" stylesheet-prefix="x" />

デフォルトの名前空間を扱うときは、2つのことを忘れないでください。最初にスタイルシートタグ内の何かにマップし、次に名前空間エイリアスを使用して削除します。

2
Thomas