web-dev-qa-db-ja.com

現在ログインしているユーザー名を取得するにはどうすればよいですか？

Firemonkey Delphiプロジェクトで現在ログインしているユーザー名を取得するにはどうすればよいですか？私はWindowsとMacの両方をターゲットにしています。

私はXE2を持っていますが、必要に応じてアップグレードするので、どのバージョンのソリューションでも問題ないと思います。

delphifiremonkey
12
Marcus Adams

Windowsの場合は GetUserName WinAPi関数を使用でき、OSXの場合はNSUserNameおよび/またはNSFullUserNameメソッドを使用できます。

OSX用にこのサンプルを試してください

{$APPTYPE CONSOLE}

{$R *.res}

uses
  Macapi.CoreFoundation,
  Macapi.Foundation,
  System.SysUtils;

function NSUserName: Pointer; cdecl; external '/System/Library/Frameworks/Foundation.framework/Foundation' name _PU +'NSUserName';
function NSFullUserName: Pointer; cdecl; external '/System/Library/Frameworks/Foundation.framework/Foundation' name _PU + 'NSFullUserName';

begin
  try
    Writeln(Format('User Name      %s',[TNSString.Wrap(NSUserName).UTF8String]));
    Writeln(Format('Full User Name %s',[TNSString.Wrap(NSFullUserName).UTF8String]))
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.

Windowsの場合

{$APPTYPE CONSOLE}


uses
  Windows,
  SysUtils;

function WUserName: String;
var
  nSize: DWord;
begin
 nSize := 1024;
 SetLength(Result, nSize);
 if GetUserName(PChar(Result), nSize) then
   SetLength(Result, nSize-1)
 else
   RaiseLastOSError;
end;


begin
  try
   Writeln(WUserName);
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
  readln;
end.

単一のユニットにコンパイル：

uses
  {$IFDEF MACOS}
  MacApi.CoreFoundation, MacApi.Foundation,
  {$ENDIF}
  {$IFDEF MSWINDOWS}
  Windows,
  {$ENDIF}
  System.SysUtils;

{$IFDEF MACOS}
function NSUserName: Pointer; cdecl; external '/System/Library/Frameworks/Foundation.framework/Foundation' name '_NSUserName';
{$ENDIF}

function GetUserName: String;
{$IFDEF MSWINDOWS}
var
  nSize: DWord;
{$ENDIF}
begin
  {$IFDEF MACOS}
  Result := TNSString.Wrap(NSUserName).UTF8String;
  {$ENDIF}
  {$IFDEF MSWINDOWS}
  nSize := 1024;
  SetLength(Result, nSize);
  if Windows.GetUserName(PChar(Result), nSize) then
  begin
    SetLength(Result, nSize - 1)
  end
  else
  begin
    RaiseLastOSError;
  end
  {$ENDIF}
end;
20
RRUZ

もう1つの簡単な解決策は、次のように GetEnvironmentVariable 関数を使用して、環境変数を介してコンピューター名を取得することです。

Result := GetEnvironmentVariable('USERNAME');

追伸：このソリューションはWindowsとLinux向けですが、Delphiのソースコードがサポートされているかどうかを確認する必要があります。

7
mas_oz2k1